pintos-os.org Git - pintos-anon/blob - src/threads/switch.S

   1 #include "threads/switch.h"
   2
   3 #### struct thread *switch_threads (struct thread *cur, struct thread *next);
   4 ####
   5 #### Switches from CUR, which must be the running thread, to NEXT,
   6 #### which must also be running switch_threads(), returning CUR in
   7 #### NEXT's context.
   8 ####
   9 #### This function works by assuming that the thread we're switching
  10 #### into is also running switch_threads().  Thus, all it has to do is
  11 #### preserve a few registers on the stack, then switch stacks and
  12 #### restore the registers.  As part of switching stacks we record the
  13 #### current stack pointer in CUR's thread structure.
  14
  15 .globl switch_threads
  16 .func switch_threads
  17 switch_threads:
  18         # Save caller's register state.
  19         #
  20         # Note that the SVR4 ABI allows us to destroy %eax, %ecx, %edx,
  21         # but requires us to preserve %ebx, %ebp, %esi, %edi.  See
  22         # [SysV-ABI-386] pages 3-11 and 3-12 for details.
  23         #
  24         # This stack frame must match the one set up by thread_create().
  25         pushl %ebx
  26         pushl %ebp
  27         pushl %esi
  28         pushl %edi
  29
  30         # Get offsetof (struct thread, stack).
  31 .globl thread_stack_ofs
  32         mov thread_stack_ofs, %edx
  33
  34         # Save current stack pointer to old thread's stack, if any.
  35         movl SWITCH_CUR(%esp), %eax
  36         test %eax, %eax
  37         jz 1f
  38         movl %esp, (%eax,%edx,1)
  39 1:
  40
  41         # Restore stack pointer from new thread's stack.
  42         movl SWITCH_NEXT(%esp), %ecx
  43         movl (%ecx,%edx,1), %esp
  44
  45         # Restore caller's register state.
  46         popl %edi
  47         popl %esi
  48         popl %ebp
  49         popl %ebx
  50         ret
  51 .endfunc
  52
  53 .globl switch_entry
  54 .func switch_entry
  55 switch_entry:
  56         # Discard switch_threads() arguments.
  57         addl $8, %esp
  58
  59         # Call schedule_tail(prev).
  60         pushl %eax
  61 .globl schedule_tail
  62         call schedule_tail
  63         addl $4, %esp
  64
  65         # Start thread proper.
  66         ret
  67 .endfunc