pintos-os.org Git - pintos-anon/blob - src/threads/switch.S

   1 #include "threads/switch.h"
   2
   3 #### struct thread *switch_threads (struct thread *cur, struct thread *next);
   4 ####
   5 #### Switches from CUR, which must be the running thread, to NEXT,
   6 #### which must also be running switch_threads(), returning CUR in
   7 #### NEXT's context.
   8 ####
   9 #### This function works by assuming that the thread we're switching
  10 #### into is also running switch_threads().  Thus, all it has to do is
  11 #### preserve a few registers on the stack, then switch stacks and
  12 #### restore the registers.  As part of switching stacks we record the
  13 #### current stack pointer in CUR's thread structure.
  14
  15         .intel_syntax noprefix
  16
  17 .globl switch_threads
  18 switch_threads:
  19         # Save caller's register state.
  20         #
  21         # Note that the SVR4 ABI allows us to destroy eax, ecx, edx,
  22         # but requires us to preserve ebx, ebp, esi, edi.  See
  23         # [SysV-ABI-386] pages 3-11 and 3-12 for details.
  24         #
  25         # This stack frame must match the one set up by thread_create().
  26         push ebx
  27         push ebp
  28         push esi
  29         push edi
  30
  31         # Get offsetof (struct thread, stack).
  32 .globl thread_stack_ofs
  33         mov edx, thread_stack_ofs
  34
  35         # Save current stack pointer to old thread's stack, if any.
  36         mov eax, SWITCH_CUR[esp]
  37         test eax, eax
  38         jz 1f
  39         mov [eax + edx], esp
  40 1:
  41
  42         # Restore stack pointer from new thread's stack.
  43         mov ecx, SWITCH_NEXT[esp]
  44         mov esp, [ecx + edx]
  45
  46         # Restore caller's register state.
  47         pop edi
  48         pop esi
  49         pop ebp
  50         pop ebx
  51         ret
  52
  53 .globl switch_entry
  54 switch_entry:
  55         # Discard switch_threads() arguments.
  56         add esp, 8
  57
  58         # Call schedule_tail(prev).
  59         push eax
  60 .globl schedule_tail
  61         call schedule_tail
  62         add esp, 4
  63
  64         # Start thread proper.
  65         ret