pintos-os.org Git - pintos-anon/blob - src/threads/loader.S

   1 /* This file is derived from source code used in MIT's 6.828
   2    course.  The original copyright notice is reproduced in full
   3    below. */
   4
   5 /*
   6  * Copyright (C) 1997 Massachusetts Institute of Technology
   7  *
   8  * This software is being provided by the copyright holders under the
   9  * following license. By obtaining, using and/or copying this software,
  10  * you agree that you have read, understood, and will comply with the
  11  * following terms and conditions:
  12  *
  13  * Permission to use, copy, modify, distribute, and sell this software
  14  * and its documentation for any purpose and without fee or royalty is
  15  * hereby granted, provided that the full text of this NOTICE appears on
  16  * ALL copies of the software and documentation or portions thereof,
  17  * including modifications, that you make.
  18  *
  19  * THIS SOFTWARE IS PROVIDED "AS IS," AND COPYRIGHT HOLDERS MAKE NO
  20  * REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED. BY WAY OF EXAMPLE,
  21  * BUT NOT LIMITATION, COPYRIGHT HOLDERS MAKE NO REPRESENTATIONS OR
  22  * WARRANTIES OF MERCHANTABILITY OR FITNESS FOR ANY PARTICULAR PURPOSE OR
  23  * THAT THE USE OF THE SOFTWARE OR DOCUMENTATION WILL NOT INFRINGE ANY
  24  * THIRD PARTY PATENTS, COPYRIGHTS, TRADEMARKS OR OTHER RIGHTS. COPYRIGHT
  25  * HOLDERS WILL BEAR NO LIABILITY FOR ANY USE OF THIS SOFTWARE OR
  26  * DOCUMENTATION.
  27  *
  28  * The name and trademarks of copyright holders may NOT be used in
  29  * advertising or publicity pertaining to the software without specific,
  30  * written prior permission. Title to copyright in this software and any
  31  * associated documentation will at all times remain with copyright
  32  * holders. See the file AUTHORS which should have accompanied this software
  33  * for a list of all copyright holders.
  34  *
  35  * This file may be derived from previously copyrighted software. This
  36  * copyright applies only to those changes made by the copyright
  37  * holders listed in the AUTHORS file. The rest of this file is covered by
  38  * the copyright notices, if any, listed below.
  39  */
  40
  41 #include "threads/loader.h"
  42 #include "threads/mmu.h"
  43
  44 #### Kernel loader.
  45
  46 #### This code should be stored in the first sector of the hard disk.
  47 #### When the BIOS runs, it loads this code at physical address
  48 #### 0x7c00-0x7e00 (512 bytes).  Then it jumps to the beginning of it,
  49 #### in real mode.  This code switches into protected mode (32-bit
  50 #### mode) so that all of memory can accessed, loads the kernel into
  51 #### memory, and jumps to the first byte of the kernel, where start.S
  52 #### is linked.
  53
  54 /* Flags in control register 0 */
  55 #define CR0_PE 0x00000001      /* Protection Enable. */
  56 #define CR0_EM 0x00000004      /* (Floating-point) Emulation. */
  57 #define CR0_PG 0x80000000      /* Paging. */
  58 #define CR0_WP 0x00010000      /* Write-Protect enable in kernel mode. */
  59
  60 # Code runs in real mode, which is a 16-bit segment.
  61
  62         .code16
  63
  64 # Disable interrupts.
  65 # String instructions go upward.
  66
  67         cli
  68         cld
  69
  70 # Set up segment registers and stack.
  71 # Stack grows downward starting from us.
  72
  73         subw %ax, %ax
  74         movw %ax, %es
  75         movw %ax, %ds
  76         movw %ax, %ss
  77         movw $0x7c00, %sp
  78
  79 #### Enable A20.  Address line 20 is tied to low when the machine
  80 #### boots, which prevents addressing memory about 1 MB.  This code
  81 #### fixes it.
  82
  83 # Poll status register while busy.
  84
  85 1:      inb $0x64, %al
  86         testb $0x2, %al
  87         jnz 1b
  88
  89 # Send command for writing output port.
  90
  91         movb $0xd1, %al
  92         outb %al, $0x64
  93
  94 # Poll status register while busy.
  95
  96 1:      inb $0x64, %al
  97         testb $0x2, %al
  98         jnz 1b
  99
 100 # Enable A20 line.
 101
 102         movb $0xdf, %al
 103         outb %al, $0x60
 104
 105 #### Get memory size, via interrupt 15h function 88h.  Returns CF
 106 #### clear if successful, with AX = (kB of physical memory) - 1024.
 107 #### This only works for memory sizes <= 65 MB, which should be fine
 108 #### for our purposes.
 109
 110         movb $0x88, %ah
 111         int $0x15
 112         jc panic                # Carry flag set on error
 113         addl $1024, %eax        # Total kB
 114         shrl $2, %eax           # Total 4 kB pages
 115         movl %eax, ram_pages
 116
 117 #### Create temporary page directory and page table and set page
 118 #### directory base register.
 119
 120 # Create page directory at 64 kB and fill with zeroes.
 121
 122         mov $0x1000, %ax
 123         mov %ax, %es
 124         subl %eax, %eax
 125         subl %edi, %edi
 126         movl $0x400, %ecx
 127         rep stosl
 128
 129 # Set PDEs for 0 and LOADER_PHYS_BASE to point to the page table.
 130
 131         movl $0x11000 | PG_U | PG_W | PG_P, %eax
 132         movl %eax, %es:0
 133         movl %eax, %es:LOADER_PHYS_BASE >> 20
 134
 135 # Initialize page table.
 136
 137         movl $PG_U | PG_W | PG_P, %eax
 138         movl $0x400, %ecx
 139 1:      stosl
 140         addl $0x1000, %eax
 141         loop 1b
 142
 143 # Set page directory base register.
 144
 145         movl $0x10000, %eax
 146         movl %eax, %cr3
 147
 148 #### Switch to protected mode.
 149
 150 # First we turn off interrupts because we don't set up an IDT.
 151
 152         cli
 153
 154 # Then we point the GDTR to our GDT.  Protected mode requires a GDT.
 155 # We need a data32 prefix to ensure that all 32 bits of the GDT
 156 # descriptor are loaded (default is to load only 24 bits).
 157
 158         data32 lgdt gdtdesc
 159
 160 # Then we turn on the following bits in CR0:
 161 #    PE (Protect Enable): this turns on protected mode.
 162 #    PG (Paging): turns on paging.
 163 #    WP (Write Protect): if unset, ring 0 code ignores
 164 #       write-protect bits in page tables (!).
 165 #    EM (Emulation): forces floating-point instructions to trap.
 166 #       We don't support floating point.
 167
 168         movl %cr0, %eax
 169         orl $CR0_PE | CR0_PG | CR0_WP | CR0_EM, %eax
 170         movl %eax, %cr0
 171
 172 # We're now in protected mode in a 16-bit segment.  The CPU still has
 173 # the real-mode code segment cached in %cs's segment descriptor.  We
 174 # need to reload %cs, and the easiest way is to use a far jump.
 175 # Because we're not in a 32-bit segment the data32 prefix is needed to
 176 # jump to a 32-bit offset.
 177
 178         data32 ljmp $SEL_KCSEG, $1f + LOADER_PHYS_BASE
 179
 180 # We're now in protected mode in a 32-bit segment.
 181
 182         .code32
 183
 184 # Reload all the other segment registers and the stack pointer to
 185 # point into our new GDT.
 186
 187 1:      movw $SEL_KDSEG, %ax
 188         movw %ax, %ds
 189         movw %ax, %es
 190         movw %ax, %fs
 191         movw %ax, %gs
 192         movw %ax, %ss
 193         movl $LOADER_PHYS_BASE + 0x20000, %esp
 194
 195 #### Load kernel starting at physical address LOADER_KERN_BASE by
 196 #### frobbing the IDE controller directly.
 197
 198         movl $1, %ebx
 199         movl $LOADER_KERN_BASE + LOADER_PHYS_BASE, %edi
 200 read_sector:
 201
 202 # Poll status register while controller busy.
 203
 204         movl $0x1f7, %edx
 205 1:      inb %dx, %al
 206         testb $0x80, %al
 207         jnz 1b
 208
 209 # Read a single sector.
 210
 211         movl $0x1f2, %edx
 212         movb $1, %al
 213         outb %al, %dx
 214
 215 # Sector number to write in low 28 bits.
 216 # LBA mode, device 0 in top 4 bits.
 217
 218         movl %ebx, %eax
 219         andl $0x0fffffff, %eax
 220         orl $0xe0000000, %eax
 221
 222 # Dump %eax to ports 0x1f3...0x1f6.
 223
 224         movl $4, %ecx
 225 1:      incw %dx
 226         outb %al, %dx
 227         shrl $8, %eax
 228         loop 1b
 229
 230 # READ command to command register.
 231
 232         incw %dx
 233         movb $0x20, %al
 234         outb %al, %dx
 235
 236 # Poll status register while controller busy.
 237
 238 1:      inb %dx, %al
 239         testb $0x80, %al
 240         jnz 1b
 241
 242 # Poll status register until data ready.
 243
 244 1:      inb %dx, %al
 245         testb $0x08, %al
 246         jz 1b
 247
 248 # Transfer sector.
 249
 250         movl $512 / 4, %ecx
 251         movl $0x1f0, %edx
 252         rep insl
 253
 254 # Next sector.
 255
 256         incl %ebx
 257         cmpl $KERNEL_LOAD_PAGES*8 + 1, %ebx
 258         jnz read_sector
 259
 260 #### Jump to kernel entry point.
 261
 262         movl $LOADER_PHYS_BASE + LOADER_KERN_BASE, %eax
 263         call *%eax
 264         jmp panic
 265
 266 #### GDT
 267
 268 gdt:
 269         .quad 0x0000000000000000        # null seg
 270         .quad 0x00cf9a000000ffff        # code seg
 271         .quad 0x00cf92000000ffff        # data seg
 272
 273 gdtdesc:
 274         .word   0x17                    # sizeof (gdt) - 1
 275         .long   gdt + LOADER_PHYS_BASE  # address gdt
 276
 277 #### Fatal error.
 278 #### Print panicmsg (with help from the BIOS) and spin.
 279
 280 panic:  .code16                 # We only panic in real mode.
 281         movw $panicmsg, %si
 282         movb $0xe, %ah
 283         subb %bh, %bh
 284 1:      lodsb
 285         test %al, %al
 286 2:      jz 2b                   # Spin.
 287         int $0x10
 288         jmp 1b
 289
 290 panicmsg:
 291         .ascii "Loader panic!\r\n"
 292         .byte 0
 293
 294 #### Memory size in 4 kB pages.
 295         .org LOADER_RAM_PAGES - LOADER_BASE
 296 ram_pages:
 297         .long 0
 298
 299 #### Command-line arguments inserted by another utility.
 300 #### The loader doesn't use these, but we note their
 301 #### location here for easy reference.
 302         .org LOADER_CMD_LINE - LOADER_BASE
 303 cmd_line:
 304         .fill 0x80, 1, 0
 305
 306 #### Boot-sector signature for BIOS inspection.
 307         .org LOADER_BIOS_SIG - LOADER_BASE
 308         .word 0xaa55