pintos-os.org Git - pintos-anon/blob - src/threads/loader.S

   1 /* This file is derived from source code used in MIT's 6.828
   2    course.  The original copyright notice is reproduced in full
   3    below. */
   4
   5 /*
   6  * Copyright (C) 1997 Massachusetts Institute of Technology
   7  *
   8  * This software is being provided by the copyright holders under the
   9  * following license. By obtaining, using and/or copying this software,
  10  * you agree that you have read, understood, and will comply with the
  11  * following terms and conditions:
  12  *
  13  * Permission to use, copy, modify, distribute, and sell this software
  14  * and its documentation for any purpose and without fee or royalty is
  15  * hereby granted, provided that the full text of this NOTICE appears on
  16  * ALL copies of the software and documentation or portions thereof,
  17  * including modifications, that you make.
  18  *
  19  * THIS SOFTWARE IS PROVIDED "AS IS," AND COPYRIGHT HOLDERS MAKE NO
  20  * REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED. BY WAY OF EXAMPLE,
  21  * BUT NOT LIMITATION, COPYRIGHT HOLDERS MAKE NO REPRESENTATIONS OR
  22  * WARRANTIES OF MERCHANTABILITY OR FITNESS FOR ANY PARTICULAR PURPOSE OR
  23  * THAT THE USE OF THE SOFTWARE OR DOCUMENTATION WILL NOT INFRINGE ANY
  24  * THIRD PARTY PATENTS, COPYRIGHTS, TRADEMARKS OR OTHER RIGHTS. COPYRIGHT
  25  * HOLDERS WILL BEAR NO LIABILITY FOR ANY USE OF THIS SOFTWARE OR
  26  * DOCUMENTATION.
  27  *
  28  * The name and trademarks of copyright holders may NOT be used in
  29  * advertising or publicity pertaining to the software without specific,
  30  * written prior permission. Title to copyright in this software and any
  31  * associated documentation will at all times remain with copyright
  32  * holders. See the file AUTHORS which should have accompanied this software
  33  * for a list of all copyright holders.
  34  *
  35  * This file may be derived from previously copyrighted software. This
  36  * copyright applies only to those changes made by the copyright
  37  * holders listed in the AUTHORS file. The rest of this file is covered by
  38  * the copyright notices, if any, listed below.
  39  */
  40
  41 #include "threads/loader.h"
  42
  43 #### Kernel loader.
  44
  45 #### This code should be stored in the first sector of the hard disk.
  46 #### When the BIOS runs, it loads this code at physical address
  47 #### 0x7c00-0x7e00 (512 bytes).  Then it jumps to the beginning of it,
  48 #### in real mode.  This code switches into protected mode (32-bit
  49 #### mode) so that all of memory can accessed, loads the kernel into
  50 #### memory, and jumps to the first byte of the kernel, where start.S
  51 #### is linked.
  52
  53 /* Flags in control register 0. */
  54 #define CR0_PE 0x00000001      /* Protection Enable. */
  55 #define CR0_EM 0x00000004      /* (Floating-point) Emulation. */
  56 #define CR0_PG 0x80000000      /* Paging. */
  57 #define CR0_WP 0x00010000      /* Write-Protect enable in kernel mode. */
  58
  59 # Code runs in real mode, which is a 16-bit segment.
  60
  61 .globl start
  62 start:
  63         .code16
  64
  65 # Disable interrupts.
  66 # String instructions go upward.
  67
  68         cli
  69         cld
  70
  71 # Set up data segments.
  72
  73         subw %ax, %ax
  74         movw %ax, %es
  75         movw %ax, %ds
  76
  77 # Set up stack segment.
  78 # Stack grows downward starting from us.
  79 # We don't ever use the stack, but we call into the BIOS,
  80 # which might.
  81
  82         movw %ax, %ss
  83         movw $0x7c00, %sp
  84
  85 #### Enable A20.  Address line 20 is tied to low when the machine
  86 #### boots, which prevents addressing memory about 1 MB.  This code
  87 #### fixes it.
  88
  89 # Poll status register while busy.
  90
  91 1:      inb $0x64, %al
  92         testb $0x2, %al
  93         jnz 1b
  94
  95 # Send command for writing output port.
  96
  97         movb $0xd1, %al
  98         outb %al, $0x64
  99
 100 # Poll status register while busy.
 101
 102 1:      inb $0x64, %al
 103         testb $0x2, %al
 104         jnz 1b
 105
 106 # Enable A20 line.
 107
 108         movb $0xdf, %al
 109         outb %al, $0x60
 110
 111 #### Get memory size, via interrupt 15h function 88h.  Returns CF
 112 #### clear if successful, with AX = (kB of physical memory) - 1024.
 113 #### This only works for memory sizes <= 65 MB, which should be fine
 114 #### for our purposes.  We cap memory at 64 MB because that's all we
 115 #### prepare page tables for, below.
 116
 117         movb $0x88, %ah
 118         int $0x15
 119         jc panic
 120         cli                     # BIOS might have enabled interrupts
 121         addl $1024, %eax        # Total kB memory
 122         cmp $0x10000, %eax      # Cap at 64 MB
 123         jbe 1f
 124         mov $0x10000, %eax
 125 1:      shrl $2, %eax           # Total 4 kB pages
 126         movl %eax, ram_pgs
 127
 128 #### Create temporary page directory and page table and set page
 129 #### directory base register.
 130
 131 # Create page directory at 64 kB and fill with zeroes.
 132         mov $0x1000, %ax
 133         mov %ax, %es
 134         subl %eax, %eax
 135         subl %edi, %edi
 136         movl $0x400, %ecx
 137         rep stosl
 138
 139 # Add PDEs to point to PTEs for the first 64 MB of RAM.
 140 # Also add identical PDEs starting at LOADER_PHYS_BASE.
 141 # See [IA32-v3a] section 3.7.6 "Page-Directory and Page-Table Entries"
 142 # for a description of the bits in %eax.
 143
 144
 145         movl $0x11007, %eax
 146         movl $0x11, %ecx
 147         subl %edi, %edi
 148 1:      movl %eax, %es:(%di)
 149         movl %eax, %es:LOADER_PHYS_BASE >> 20(%di)
 150         addw $4, %di
 151         addl $0x1000, %eax
 152         loop 1b
 153
 154 # Set up one-to-map linear to physical map for the first 64 MB of RAM.
 155 # See [IA32-v3a] section 3.7.6 "Page-Directory and Page-Table Entries"
 156 # for a description of the bits in %eax.
 157
 158         movw $0x1100, %ax
 159         movw %ax, %es
 160         movl $0x7, %eax
 161         movl $0x4000, %ecx
 162         subl %edi, %edi
 163 1:      movl %eax, %es:(%di)
 164         addw $4, %di
 165         addl $0x1000, %eax
 166         loop 1b
 167
 168 # Set page directory base register.
 169
 170         movl $0x10000, %eax
 171         movl %eax, %cr3
 172
 173 #### Switch to protected mode.
 174
 175 # Note that interrupts are still off.
 176
 177 # Point the GDTR to our GDT.  Protected mode requires a GDT.
 178 # We need a data32 prefix to ensure that all 32 bits of the GDT
 179 # descriptor are loaded (default is to load only 24 bits).
 180
 181         data32 lgdt gdtdesc
 182
 183 # Then we turn on the following bits in CR0:
 184 #    PE (Protect Enable): this turns on protected mode.
 185 #    PG (Paging): turns on paging.
 186 #    WP (Write Protect): if unset, ring 0 code ignores
 187 #       write-protect bits in page tables (!).
 188 #    EM (Emulation): forces floating-point instructions to trap.
 189 #       We don't support floating point.
 190
 191         movl %cr0, %eax
 192         orl $CR0_PE | CR0_PG | CR0_WP | CR0_EM, %eax
 193         movl %eax, %cr0
 194
 195 # We're now in protected mode in a 16-bit segment.  The CPU still has
 196 # the real-mode code segment cached in %cs's segment descriptor.  We
 197 # need to reload %cs, and the easiest way is to use a far jump.
 198 # Because we're not in a 32-bit segment the data32 prefix is needed to
 199 # jump to a 32-bit offset.
 200
 201         data32 ljmp $SEL_KCSEG, $1f + LOADER_PHYS_BASE
 202
 203 # We're now in protected mode in a 32-bit segment.
 204
 205         .code32
 206
 207 # Reload all the other segment registers and the stack pointer to
 208 # point into our new GDT.
 209
 210 1:      movw $SEL_KDSEG, %ax
 211         movw %ax, %ds
 212         movw %ax, %es
 213         movw %ax, %fs
 214         movw %ax, %gs
 215         movw %ax, %ss
 216         movl $LOADER_PHYS_BASE + 0x30000, %esp
 217
 218 #### Load kernel starting at physical address LOADER_KERN_BASE by
 219 #### frobbing the IDE controller directly.
 220
 221         movl $1, %ebx
 222         movl $LOADER_KERN_BASE + LOADER_PHYS_BASE, %edi
 223
 224 #### Disable interrupt delivery by IDE controller, because we will be
 225 #### polling for data.
 226 #### (If we don't do this, Bochs 2.2.6 will never deliver any IDE
 227 #### interrupt to us later after we reset the interrupt controller
 228 #### during boot, even if we also reset the IDE controller.)
 229
 230         movw $0x3f6, %dx
 231         movb $0x02, %al
 232         outb %al, %dx
 233
 234 read_sector:
 235
 236 # Poll status register while controller busy.
 237
 238         movl $0x1f7, %edx
 239 1:      inb %dx, %al
 240         testb $0x80, %al
 241         jnz 1b
 242
 243 # Read a single sector.
 244
 245         movl $0x1f2, %edx
 246         movb $1, %al
 247         outb %al, %dx
 248
 249 # Sector number to write in low 28 bits.
 250 # LBA mode, device 0 in top 4 bits.
 251
 252         movl %ebx, %eax
 253         andl $0x0fffffff, %eax
 254         orl $0xe0000000, %eax
 255
 256 # Dump %eax to ports 0x1f3...0x1f6.
 257
 258         movl $4, %ecx
 259 1:      incw %dx
 260         outb %al, %dx
 261         shrl $8, %eax
 262         loop 1b
 263
 264 # READ command to command register.
 265
 266         incw %dx
 267         movb $0x20, %al
 268         outb %al, %dx
 269
 270 # Poll status register while controller busy.
 271
 272 1:      inb %dx, %al
 273         testb $0x80, %al
 274         jnz 1b
 275
 276 # Poll status register until data ready.
 277
 278 1:      inb %dx, %al
 279         testb $0x08, %al
 280         jz 1b
 281
 282 # Transfer sector.
 283
 284         movl $256, %ecx
 285         movl $0x1f0, %edx
 286         rep insw
 287
 288 # Next sector.
 289
 290         incl %ebx
 291         cmpl $KERNEL_LOAD_PAGES*8 + 1, %ebx
 292         jnz read_sector
 293
 294 #### Jump to kernel entry point.
 295
 296         movl $LOADER_PHYS_BASE + LOADER_KERN_BASE, %eax
 297         call *%eax
 298         jmp panic
 299
 300 #### GDT
 301
 302 gdt:
 303         .quad 0x0000000000000000        # null seg
 304         .quad 0x00cf9a000000ffff        # code seg
 305         .quad 0x00cf92000000ffff        # data seg
 306
 307 gdtdesc:
 308         .word   0x17                    # sizeof (gdt) - 1
 309         .long   gdt + LOADER_PHYS_BASE  # address gdt
 310
 311 #### Fatal error.
 312 #### Print panic_message (with help from the BIOS) and spin.
 313
 314 panic:  .code16                 # We only panic in real mode.
 315         movw $panic_message, %si
 316         movb $0xe, %ah
 317         subb %bh, %bh
 318 1:      lodsb
 319         test %al, %al
 320 2:      jz 2b                   # Spin.
 321         int $0x10
 322         jmp 1b
 323
 324 panic_message:
 325         .ascii "Panic!"
 326         .byte 0
 327
 328 #### Physical memory size in 4 kB pages.
 329 #### This is initialized by the loader and read by the kernel.
 330         .org LOADER_RAM_PGS - LOADER_BASE
 331 ram_pgs:
 332         .long 0
 333
 334 #### Command-line arguments and their count.
 335 #### This is written by the `pintos' utility and read by the kernel.
 336 #### The loader itself does not do anything with the command line.
 337         .org LOADER_ARG_CNT - LOADER_BASE
 338 arg_cnt:
 339         .long 0
 340         .org LOADER_ARGS - LOADER_BASE
 341 args:
 342         .fill 0x80, 1, 0
 343
 344 #### Boot-sector signature.
 345 #### The BIOS checks that this is set properly.
 346         .org LOADER_SIG - LOADER_BASE
 347         .word 0xaa55