pintos-os.org Git - pintos-anon/blob - src/threads/kernel.lds.S

   1 #include "threads/loader.h"
   2
   3 OUTPUT_FORMAT("elf32-i386")
   4 OUTPUT_ARCH("i386")
   5 ENTRY(start)                    /* Kernel starts at "start" symbol. */
   6 SECTIONS
   7 {
   8   /* Specify the kernel base address. */
   9   _start = LOADER_PHYS_BASE + LOADER_KERN_BASE;
  10
  11   /* Make room for the ELF headers. */
  12   . = _start + SIZEOF_HEADERS;
  13
  14   /* Kernel starts with code, followed by read-only data and writable data. */
  15   .text : { *(.start) *(.text) } = 0x90
  16   .rodata : { *(.rodata) *(.rodata.*)
  17               . = ALIGN(0x1000);
  18               _end_kernel_text = .; }
  19   .data : { *(.data)
  20             _signature = .; LONG(0xaa55aa55) }
  21
  22   /* BSS (zero-initialized data) is after everything else. */
  23   _start_bss = .;
  24   .bss : { *(.bss) }
  25   _end_bss = .;
  26
  27   _end = .;
  28
  29   ASSERT (_end - _start <= 512K, "Kernel image is too big.")
  30 }