pintos-os.org Git - pintos-anon/blob - grading/threads/run-tests

   1 #! /usr/bin/perl
   2
   3 # Find the directory that contains the grading files.
   4 our ($GRADES_DIR);
   5
   6 # Add our Perl library directory to the include path.
   7 BEGIN {
   8     ($GRADES_DIR = $0) =~ s#/[^/]+$##;
   9     -d $GRADES_DIR or die "$GRADES_DIR: stat: $!\n";
  10     unshift @INC, "$GRADES_DIR/../lib";
  11 }
  12
  13 use warnings;
  14 use strict;
  15 use Pintos::Grading;
  16
  17 our ($hw) = "threads";
  18 our (@TESTS);           # Tests to run.
  19 our ($test);
  20 our (%details);
  21 our (%result);
  22 our ($action);
  23
  24 parse_cmd_line qw (alarm-single alarm-multiple alarm-zero alarm-negative
  25                    join-simple
  26                    join-quick join-multiple join-nested
  27                    join-dummy join-invalid join-no
  28                    priority-preempt priority-fifo priority-donate-one
  29                    priority-donate-multiple priority-donate-nest
  30                    mlfqs-on mlfqs-off);
  31
  32 clean_dir (), exit if $action eq 'clean';
  33
  34 extract_sources ();
  35 exit if $action eq 'extract';
  36
  37 build ();
  38 exit if $action eq 'build';
  39
  40 run_and_grade_tests ();
  41 if (defined ($result{'mlfqs-on'}) && defined ($result{'mlfqs-off'})) {
  42     grade_mlfqs_speedup ();
  43     grade_mlfqs_priority ();
  44 }
  45 write_grades ();
  46 write_details ();
  47 exit success () if $action eq 'test';
  48
  49 assemble_final_grade ();
  50 exit success () if $action eq 'assemble';
  51
  52 die "Don't know how to '$action'";
  53
  54 # Runs $test in directory output/$test.
  55 # Returns 'ok' if it went ok, otherwise an explanation.
  56 sub run_test {
  57     # Change constants.h if necessary.
  58     my ($defines) = $test ne 'mlfqs-on' ? "" : "#define MLFQS 1\n";
  59     if ($defines ne snarf ("pintos/src/constants.h")) {
  60         open (CONSTANTS, ">pintos/src/constants.h");
  61         print CONSTANTS $defines;
  62         close (CONSTANTS);
  63     }
  64
  65     # Changes devices/timer.c if necessary.
  66     my ($new_time_slice) = $test eq 'priority-fifo' ? 100 : 1;
  67     my (@timer) = snarf ("pintos/src/devices/timer.c");
  68     if (!grep (/^\#define TIME_SLICE $new_time_slice$/, @timer)) {
  69         @timer = grep (!/^\#define TIME_SLICE/, @timer);
  70         unshift (@timer, "#define TIME_SLICE $new_time_slice");
  71         open (TIMER, ">pintos/src/devices/timer.c");
  72         print TIMER map ("$_\n", @timer);
  73         close (TIMER);
  74     }
  75
  76     # Copy in the new test.c and delete enough files to ensure a full rebuild.
  77     my ($src) = "$GRADES_DIR/" . ($test !~ /^mlfqs/ ? "$test.c" : "mlfqs.c");
  78     -e $src or die "$src: stat: $!\n";
  79     xsystem ("cp $src pintos/src/threads/test.c", DIE => "cp failed\n");
  80     unlink ("pintos/src/threads/build/threads/test.o");
  81     unlink ("pintos/src/threads/build/kernel.o");
  82     unlink ("pintos/src/threads/build/kernel.bin");
  83     unlink ("pintos/src/threads/build/os.dsk");
  84
  85     # Build.
  86     if (xsystem ("cd pintos/src/threads && make",
  87                  LOG => "$test/make") ne 'ok') {
  88         $details{$test} = snarf ("output/$test/make.err");
  89         return "Compile error";
  90     }
  91
  92     # Copy out files for backtraces later.
  93     xsystem ("cp pintos/src/threads/build/kernel.o output/$test");
  94     xsystem ("cp pintos/src/threads/build/os.dsk output/$test");
  95
  96     # Run.
  97     my ($timeout) = $test !~ /^mlfqs/ ? 15 : 600;
  98     return run_pintos (["-v", "run", "-q"],
  99                        CHDIR => "pintos/src/threads/build",
 100                        LOG => "$test/run",
 101                        TIMEOUT => $timeout);
 102 }
 103 \f
 104 sub grade_alarm_single {
 105     verify_alarm (1, @_);
 106 }
 107
 108 sub grade_alarm_multiple {
 109     verify_alarm (7, @_);
 110 }
 111
 112 sub verify_alarm {
 113     my ($iterations, @output) = @_;
 114
 115     verify_common (@output);
 116
 117     my (@products);
 118     for (my ($i) = 0; $i < $iterations; $i++) {
 119         for (my ($t) = 0; $t < 5; $t++) {
 120             push (@products, ($i + 1) * ($t + 1) * 10);
 121         }
 122     }
 123     @products = sort {$a <=> $b} @products;
 124
 125     local ($_);
 126     foreach (@output) {
 127         die $_ if /out of order/i;
 128
 129         my ($p) = /product=(\d+)$/;
 130         next if !defined $p;
 131
 132         my ($q) = shift (@products);
 133         die "Too many wakeups.\n" if !defined $q;
 134         die "Out of order wakeups ($p vs. $q).\n" if $p != $q; # FIXME
 135     }
 136     die scalar (@products) . " fewer wakeups than expected.\n"
 137         if @products != 0;
 138 }
 139
 140 sub grade_alarm_zero {
 141     my (@output) = @_;
 142     verify_common (@output);
 143     die "Crashed in timer_sleep()\n" if !grep (/^Success\.$/, @output);
 144 }
 145
 146 sub grade_alarm_negative {
 147     my (@output) = @_;
 148     verify_common (@output);
 149     die "Crashed in timer_sleep()\n" if !grep (/^Success\.$/, @output);
 150 }
 151
 152 sub grade_join_invalid {
 153     my (@output) = @_;
 154     verify_common (@output);
 155     grep (/Testing invalid join/, @output) or die "Test didn't start\n";
 156     grep (/Invalid join test done/, @output) or die "Test didn't complete\n";
 157 }
 158
 159 sub grade_join_no {
 160     my (@output) = @_;
 161     verify_common (@output);
 162     grep (/Testing no join/, @output) or die "Test didn't start\n";
 163     grep (/No join test done/, @output) or die "Test didn't complete\n";
 164 }
 165
 166 sub grade_join_multiple {
 167     my (@output) = @_;
 168
 169     verify_common (@output);
 170     my (@t);
 171     $t[4] = $t[5] = $t[6] = -1;
 172     local ($_);
 173     foreach (@output) {
 174         my ($idx) = /^Thread (\d+)/ or next;
 175         my ($iter) = /iteration (\d+)$/;
 176         $iter = 5 if /done!$/;
 177         die "Malformed output\n" if !defined $iter;
 178         if ($idx == 6) {
 179             die "Thread 6 started before either other thread finished\n"
 180                 if $t[4] < 5 && $t[5] < 5;
 181             die "Thread 6 started before thread 4 finished\n"
 182                 if $t[4] < 5;
 183             die "Thread 6 started before thread 5 finished\n"
 184                 if $t[5] < 5;
 185         }
 186         die "Thread $idx out of order output\n" if $t[$idx] != $iter - 1;
 187         $t[$idx] = $iter;
 188     }
 189
 190     my ($err) = "";
 191     for my $idx (4, 5, 6) {
 192         if ($t[$idx] == -1) {
 193             $err .= "Thread $idx did not run at all\n";
 194         } elsif ($t[$idx] != 5) {
 195             $err .= "Thread $idx only completed $t[$idx] iterations\n";
 196         }
 197     }
 198     die $err if $err ne '';
 199 }
 200
 201 sub grade_priority_fifo {
 202     my (@output) = @_;
 203
 204     verify_common (@output);
 205     my ($thread_cnt) = 10;
 206     my ($iter_cnt) = 5;
 207     my (@order);
 208     my (@t) = (-1) x $thread_cnt;
 209     local ($_);
 210     foreach (@output) {
 211         my ($idx) = /^Thread (\d+)/ or next;
 212         my ($iter) = /iteration (\d+)$/;
 213         $iter = $iter_cnt if /done!$/;
 214         die "Malformed output\n" if !defined $iter;
 215         if (@order < $thread_cnt) {
 216             push (@order, $idx);
 217             die "Thread $idx repeated within first $thread_cnt iterations: "
 218                 . join (' ', @order) . ".\n"
 219                 if grep ($_ == $idx, @order) != 1;
 220         } else {
 221             die "Thread $idx ran when $order[0] should have.\n"
 222                 if $idx != $order[0];
 223             push (@order, shift @order);
 224         }
 225         die "Thread $idx out of order output.\n" if $t[$idx] != $iter - 1;
 226         $t[$idx] = $iter;
 227     }
 228
 229     my ($err) = "";
 230     for my $idx (0..$#t) {
 231         if ($t[$idx] == -1) {
 232             $err .= "Thread $idx did not run at all.\n";
 233         } elsif ($t[$idx] != $iter_cnt) {
 234             $err .= "Thread $idx only completed $t[$idx] iterations.\n";
 235         }
 236     }
 237     die $err if $err ne '';
 238 }
 239
 240 sub grade_mlfqs_on {
 241     my (@output) = @_;
 242     verify_common (@output);
 243     our (@mlfqs_on_stats) = mlfqs_stats (@output);
 244 }
 245
 246 sub grade_mlfqs_off {
 247     my (@output) = @_;
 248     verify_common (@output);
 249     our (@mlfqs_off_stats) = mlfqs_stats (@output);
 250 }
 251
 252 sub grade_mlfqs_speedup {
 253     our (@mlfqs_off_stats);
 254     our (@mlfqs_on_stats);
 255     eval {
 256         check_mlfqs ();
 257         my ($off_ticks) = $mlfqs_off_stats[1];
 258         my ($on_ticks) = $mlfqs_on_stats[1];
 259         die "$off_ticks ticks without MLFQS, $on_ticks with MLFQS\n"
 260             if $on_ticks >= $off_ticks;
 261         die "ok\n";
 262     };
 263     chomp $@;
 264     $result{'mlfqs-speedup'} = $@;
 265 }
 266
 267 sub grade_mlfqs_priority {
 268     our (@mlfqs_off_stats);
 269     our (@mlfqs_on_stats);
 270     eval {
 271         check_mlfqs () if !defined (@mlfqs_on_stats);
 272         for my $cat qw (CPU IO MIX) {
 273             die "Priority changed away from PRI_DEFAULT (29) without MLFQS\n"
 274                 if $mlfqs_off_stats[0]{$cat}{MIN} != 29
 275                 || $mlfqs_off_stats[0]{$cat}{MAX} != 29;
 276             die "Minimum priority never changed from PRI_DEFAULT (29) "
 277                 . "with MLFQS\n"
 278                 if $mlfqs_on_stats[0]{$cat}{MIN} == 29;
 279             die "Maximum priority never changed from PRI_DEFAULT (29) "
 280                 . "with MLFQS\n"
 281                 if $mlfqs_on_stats[0]{$cat}{MAX} == 29;
 282         }
 283         die "ok\n";
 284     };
 285     chomp $@;
 286     $result{'mlfqs-priority'} = $@;
 287 }
 288
 289 sub check_mlfqs {
 290     our (@mlfqs_off_stats);
 291     our (@mlfqs_on_stats);
 292     die "p1-4 didn't finish with MLFQS on or off\n"
 293         if !defined (@mlfqs_off_stats) && !defined (@mlfqs_on_stats);
 294     die "p1-4 didn't finish with MLFQS on\n"
 295         if !defined (@mlfqs_on_stats);
 296     die "p1-4 didn't finish with MLFQS off\n"
 297         if !defined (@mlfqs_off_stats);
 298 }
 299
 300 sub mlfqs_stats {
 301     my (@output) = @_;
 302     my (%stats) = (CPU => {}, IO => {}, MIX => {});
 303     my (%map) = ("CPU intensive" => 'CPU',
 304                  "IO intensive" => 'IO',
 305                  "Alternating IO/CPU" => 'MIX');
 306     my (%rmap) = reverse %map;
 307     my ($ticks);
 308     local ($_);
 309     foreach (@output) {
 310         $ticks = $1 if /Timer: (\d+) ticks/;
 311         my ($thread, $pri) = /^([A-Za-z\/ ]+): (\d+)$/ or next;
 312         my ($t) = $map{$thread} or next;
 313
 314         my ($s) = $stats{$t};
 315         $$s{N}++;
 316         $$s{SUM} += $pri;
 317         $$s{SUM2} += $pri * $pri;
 318         $$s{MIN} = $pri if !defined ($$s{MIN}) || $pri < $$s{MIN};
 319         $$s{MAX} = $pri if !defined ($$s{MAX}) || $pri > $$s{MAX};
 320     }
 321
 322     my (%expect_n) = (CPU => 5000, IO => 1000, MIX => 12000);
 323     for my $cat (values (%map)) {
 324         my ($s) = $stats{$cat};
 325         die "$rmap{$cat} printed $$s{N} times, not $expect_n{$cat}\n"
 326             if $$s{N} != $expect_n{$cat};
 327         die "$rmap{$cat} priority dropped to $$s{MIN}, below PRI_MIN (0)\n"
 328             if $$s{MIN} < 0;
 329         die "$rmap{$cat} priority rose to $$s{MAX}, above PRI_MAX (59)\n"
 330             if $$s{MAX} > 59;
 331         $$s{MEAN} = $$s{SUM} / $$s{N};
 332     }
 333
 334     return (\%stats, $ticks);
 335 }