+dnl Avoid interference between zlib's crc32() function and gnulib's
+dnl crc32() function, which have different signatures. PSPP calls
+dnl only gnulib's crc32() directly, but it calls zlib's crc32()
+dnl indirectly through other zlib calls. If we don't rename gnulib's
+dnl crc32(), then zlib will call gnulib's version instead of its own,
+dnl causing failures. (This can happen even if zlib isn't detected
+dnl directly, because other libraries that PSPP uses, e.g. libpng,
+dnl sometimes use zlib themselves.)
+AC_DEFINE(
+ [crc32], [gl_crc32],
+ [Avoid making zlib call gnulib's crc32() instead of its own.])
+
+dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
+if test $HAVE_LIBXML2 = yes; then
+ GNM_READ_SUPPORT=yes
+ ODF_READ_SUPPORT=yes
+ AC_DEFINE(
+ [GNM_READ_SUPPORT], [1],
+ [Define to 1 if building in support for reading Gnumeric files.])
+ AC_DEFINE(
+ [ODF_READ_SUPPORT], [1],
+ [Define to 1 if building in support for reading OpenDocument files.])
+else
+ GNM_READ_SUPPORT=no
+ ODF_READ_SUPPORT=no
+fi
+AC_SUBST([GNM_READ_SUPPORT])
+AC_SUBST([ODF_READ_SUPPORT])
+
+dnl ODF support requires libxml2 (zlib is optional).
+if test $HAVE_LIBXML2 = yes; then
+ AC_DEFINE(
+ [ODF_WRITE_SUPPORT], [1],
+ [Define to 1 if building in support for writing OpenDocument files.])
+fi
+AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
+
+AC_ARG_WITH(
+ gui_tools,
+ [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools. For DEVELOPERS only! There is no reason why users will need this flag.])])
+if test x"$with_gui_tools" = x"yes" ; then
+ PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
+fi
+AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
+
+AC_ARG_WITH(
+ [perl-module],
+ [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
+ [case $with_perl_module in # (
+ yes|no) ;; # (
+ *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
+ esac
+ WITH_PERL_MODULE=$with_perl_module],
+ [if test x"$cross_compiling" != x"yes"; then
+ WITH_PERL_MODULE=yes
+ else
+ WITH_PERL_MODULE=no
+ fi])
+AC_SUBST([WITH_PERL_MODULE])
+AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
+
+AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
+PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
+ AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
+
+
+PSPP_GSL_NEEDS_FGNU89_INLINE
+
+PSPP_READLINE
+
+dnl Checks for header files.
+AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
+
+dnl Some systems don't have SIGWINCH
+AC_CHECK_DECLS([SIGWINCH], [], [],
+ [#include <signal.h>
+ /* NetBSD declares sys_siglist in unistd.h. */
+ #ifdef HAVE_UNISTD_H
+ # include <unistd.h>
+ #endif
+ ])