+
+AC_ARG_WITH(
+ libpq,
+ [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
+
+if test x"$with_libpq" != x"no" ; then
+ AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
+
+ AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
+ if test x"$cross_compiling" != x"yes" ; then
+ AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
+ fi
+ if test -n "$PG_CONFIG" ; then
+ AC_SUBST(PG_CONFIG)
+ AC_DEFINE([PSQL_SUPPORT], 1,
+ [Define to 1 if building in support for reading from postgres databases.])
+ PG_CFLAGS=-I`$PG_CONFIG --includedir`
+ AC_SUBST(PG_CFLAGS)
+
+ if test "x$libpq_in_std_lib_path" != x"yes" ; then
+ PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
+ fi
+ AC_SUBST(PG_LDFLAGS)
+
+ PG_LIBS=-lpq
+ AC_SUBST(PG_LIBS)
+ PKG_CHECK_EXISTS(libssl,
+ AC_DEFINE([USE_SSL],1,
+ [Define to 1 if the openssl library is present.])
+ ,)
+ fi
+fi
+AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
+
+dnl Check for libxml2
+PKG_CHECK_MODULES(
+ [LIBXML2], [libxml-2.0],
+ [HAVE_LIBXML2=yes],
+ [HAVE_LIBXML2=no
+ PSPP_OPTIONAL_PREREQ([libxml2])])
+
+dnl Check for zlib.
+AC_SEARCH_LIBS(
+ [gzopen], [z],
+ [HAVE_ZLIB=yes],
+ [HAVE_ZLIB=no
+ PSPP_OPTIONAL_PREREQ([zlib])])
+AC_CHECK_HEADERS(
+ [zlib.h],
+ [],
+ [HAVE_ZLIB=no
+ PSPP_OPTIONAL_PREREQ([zlib])])
+
+dnl Avoid interference between zlib's crc32() function and gnulib's
+dnl crc32() function, which have different signatures. PSPP calls
+dnl only gnulib's crc32() directly, but it calls zlib's crc32()
+dnl indirectly through other zlib calls. If we don't rename gnulib's
+dnl crc32(), then zlib will call gnulib's version instead of its own,
+dnl causing failures. (This can happen even if zlib isn't detected
+dnl directly, because other libraries that PSPP uses, e.g. libpng,
+dnl sometimes use zlib themselves.)
+AC_DEFINE(
+ [crc32], [gl_crc32],
+ [Avoid making zlib call gnulib's crc32() instead of its own.])
+
+dnl Gnumeric support requires libxml2 and zlib.
+if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
+ GNM_SUPPORT=yes
+ AC_DEFINE(
+ [GNM_SUPPORT], [1],
+ [Define to 1 if building in support for reading Gnumeric files.])
+else
+ GNM_SUPPORT=no
+fi
+AM_CONDITIONAL([GNM_SUPPORT], [test $GNM_SUPPORT = yes])
+
+dnl ODT support requires libxml2.
+if test $HAVE_LIBXML2 = yes; then
+ AC_DEFINE(
+ [ODT_SUPPORT], [1],
+ [Define to 1 if building in support for writing ODT files.])
+fi
+AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
+
+AC_ARG_WITH(
+ gui_tools,
+ [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools. For DEVELOPERS only! There is no reason why users will need this flag.])])
+if test x"$with_gui_tools" = x"yes" ; then
+ PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
+fi
+AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
+
+if test x"$cross_compiling" != x"yes"; then
+ WITH_PERL_MODULE=yes
+else
+ WITH_PERL_MODULE=no
+fi
+AC_SUBST([WITH_PERL_MODULE])
+AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
+
+AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
+AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
+PSPP_GSL_NEEDS_FGNU89_INLINE
+
+dnl Recent versions of GNU ncurses install the curses header files into
+dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
+dnl enables us to discover where they are. Earlier versions don't have
+dnl this, so we can't rely on it. So if ncurses5-config is present,
+dnl we'll trust it to find the right information. Otherwise, we'll
+dnl try to discover it ourselves.
+dnl To confound things further, Cygwin has decided to rename ncurses5-config
+dnl to ncurses8-config !!!
+AC_ARG_WITH(
+ libncurses,
+ [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
+
+if test x"$with_libncurses" != x"no" ; then
+ if test x"$cross_compiling" != x"yes" ; then
+ AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
+ fi
+ if test x"$NCURSES_CONFIG" = x ; then
+ AC_SEARCH_LIBS([tgetent], [ncurses],
+ [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
+ else
+ old_cflags=$CFLAGS
+ CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
+ AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
+ CFLAGS=$old_cflags
+ if test x"$curses_available" = x"yes" ; then
+ NCURSES_LIBS=`$NCURSES_CONFIG --libs`
+ NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
+ AC_SUBST(NCURSES_CFLAGS)
+ AC_SUBST(NCURSES_LIBS)
+ fi
+ fi
+ if test x"$curses_available" = x"yes" ; then
+ AC_DEFINE([LIBNCURSES_USABLE], 1,
+ [Define to 1 if the libncurses is both present and usable.])
+ fi
+ AC_CHECK_HEADERS([termcap.h])
+fi