+dnl One of the tests uses xmllint.
+AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
+[AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
+ [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
+ test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
+ ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
+ [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
+
+AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
+
+# Support for GUI.
+AC_ARG_WITH([gui],
+ [AS_HELP_STRING([--without-gui],
+ [Don't build the PSPPIRE GUI (using GTK+)])],
+ [], [with_gui=yes])
+AM_CONDITIONAL([building_gui],
+ [test "$with_cairo" != no && test "$with_gui" != "no"])
+if test "$with_cairo" != no && test "$with_gui" != "no"; then
+ PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
+ [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
+ [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
+ [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
+ [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
+ [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
+ PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
+
+ PKG_CHECK_MODULES([LIBRSVG], [librsvg-2.0 >= 2.44],
+ [AC_DEFINE([HAVE_RSVG], 1, [Define to 1 if librsvg is available])],
+ [PSPP_OPTIONAL_PREREQ([librsvg >= 2.44 required for high dpi Copy and Paste])])
+
+ AC_ARG_VAR([GLIB_GENMARSHAL])
+ AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
+ if test "x$GLIB_GENMARSHAL" = x; then
+ PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
+ fi
+
+ AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
+ if test "x$GLIB_COMPILE_RESOURCES" = x; then
+ PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
+ fi
+
+fi
+
+gl_NEXT_HEADERS([gtk/gtk.h])
+
+dnl Checks needed for psql reader
+
+dnl The 8.x series postgres tarballs installs with a default prefix of
+dnl /usr/local/pgsql whereas, OSes (such as debian) install into /usr .
+
+dnl If the libpq.so file is in a non standard path, (one which the linker
+dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
+dnl However, if the system happens to have more than one version of other
+dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
+dnl /usr and /usr/local) then the wrong one may get linked.
+
+dnl To overcome this, we first check for libpq in the standard places, and
+dnl only set PG_LDFLAGS if it's not found.
+
+
+AC_ARG_WITH(
+ libpq,
+ [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
+AC_ARG_VAR([PG_CONFIG],
+ [Full pathname of the pg_config program shipped with Postgresql])
+AC_PATH_PROG([PG_CONFIG], [pg_config], [],
+ [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
+
+if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
+ AC_SUBST(PG_CONFIG)
+ PG_CFLAGS=-I`$PG_CONFIG --includedir`
+ AC_SUBST(PG_CFLAGS)
+
+ AC_CHECK_LIB([pq], [PQexec],
+ [:],
+ [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
+ AC_SUBST(PG_LDFLAGS)
+
+ PG_LIBS=-lpq
+ AC_SUBST(PG_LIBS)
+
+ PKG_CHECK_EXISTS(libssl,
+ AC_DEFINE([USE_SSL],1,
+ [Define to 1 if the openssl library is present.])
+ ,)
+
+ # Now verify that we can actually link against libpq. If we are
+ # cross-compiling and picked up a host libpq, or if libpq is just
+ # badly installed, this will fail.
+ AC_CACHE_CHECK(
+ [whether -lpq links successfully],
+ [pspp_cv_have_libpq],
+ [save_CPPFLAGS=$CPPFLAGS
+ save_LIBS=$LIBS
+ save_LDFLAGS=$LDFLAGS
+ CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
+ LIBS="$PG_LIBS $LIBS"
+ LDFLAGS="$PG_LDFLAGS $LDFLAGS"
+ AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM(
+ [#include <libpq-fe.h>
+ ], [PQfinish (0);])],
+ [pspp_cv_have_libpq=yes],
+ [pspp_cv_have_libpq=no])
+ CPPFLAGS=$save_CPPFLAGS
+ LIBS=$save_LIBS
+ LDFLAGS=$save_LDFLAGS])
+
+ if test $pspp_cv_have_libpq = yes; then
+ PSQL_SUPPORT=yes
+ AC_DEFINE([PSQL_SUPPORT], [1],
+ [Define to 1 if building in support for reading from postgres
+ databases.])
+ else
+ PSQL_SUPPORT=no
+ PG_CONFIG=
+ PG_CFLAGS=
+ PG_LDFLAGS=
+ PG_LIBS=