+dnl Prerequisites.
+
+dnl Instead of giving an error about each prerequisite as we encounter it,
+dnl group them all together at the end of the run, to be user-friendly.
+AC_DEFUN([PSPP_REQUIRED_PREREQ], [pspp_required_prereqs="$pspp_required_prereqs
+ $1"])
+AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
+ $1"])
+AC_DEFUN([PSPP_CHECK_PREREQS],
+[
+ if test "$pspp_optional_prereqs" != ""; then
+ AC_MSG_WARN([The following optional prerequisites are not installed.
+You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
+fi
+ if test "$pspp_required_prereqs" != ""; then
+ AC_MSG_ERROR([The following required prerequisites are not installed.
+You must install them before PSPP can be built:$pspp_required_prereqs])
+fi
+])
+
+
+dnl Check that a new enough version of Perl is available.
+AC_DEFUN([PSPP_PERL],
+[
+ AC_PATH_PROG([PERL], perl, no)
+ AC_SUBST([PERL])dnl
+ if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
+ PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
+ fi
+])
+
+dnl Check that libplot is available.
+AC_DEFUN([PSPP_LIBPLOT],
+[
+ AC_ARG_WITH(
+ libplot,
+ [AS_HELP_STRING([--without-libplot],
+ [don't compile in support of charts (using libplot)])])
+
+ if test x"$with_libplot" != x"no" ; then
+ # Check whether we can link against libplot without any extra libraries.
+ AC_CHECK_LIB(plot, pl_newpl_r, [LIBPLOT_LIBS="-lplot"])
+
+ # Check whether we can link against libplot if we also link X.
+ if test x"$LIBPLOT_LIBS" = x""; then
+ AC_PATH_XTRA
+ extra_libs="-lXaw -lXmu -lXt $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS -lm"
+ AC_CHECK_LIB(plot, pl_newpl_r,
+ [LIBPLOT_LIBS="-lplot $extra_libs"
+ LDFLAGS="$LDFLAGS $X_LIBS"],,
+ [$extra_libs])
+ fi
+
+ # Still can't link?
+ if test x"$LIBPLOT_LIBS" = x""; then
+ PSPP_REQUIRED_PREREQ([libplot (or use --without-libplot)])
+ fi
+
+ # Set up to make everything work.
+ LIBS="$LIBPLOT_LIBS $LIBS"
+ AC_DEFINE(HAVE_LIBPLOT, 1,
+ [Define to 1 if you have the `libplot' library (-lplot).])
+ fi
+])
+
+dnl Check whether a C compiler option is accepted.