+dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
+AC_DEFUN([PSPP_LC_PAPER],
+[AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
+ pspp_cv_lc_paper=no
+ AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM(
+ [#include <locale.h>
+#include <langinfo.h>
+],
+ [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
+ [pspp_cv_lc_paper=yes])
+ ])
+ if test "$pspp_cv_lc_paper" = yes; then
+ AC_DEFINE([HAVE_LC_PAPER], 1, [Define if you have LC_PAPER.])
+ fi
+])
+
+
+# PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+# -------------------------------------------------------------
+# Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
+# into a program.
+#
+# Test that resulting file is executable; see the problem reported by mwoehlke
+# in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
+# But skip the test when cross-compiling, to prevent problems like the one
+# reported by Chris Johns in
+# <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
+#
+m4_define([PSPP_LINK2_IFELSE],
+[m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
+mv conftest.$ac_ext conftest1.$ac_ext
+m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
+mv conftest.$ac_ext conftest2.$ac_ext
+rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
+pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
+AS_IF([_AC_DO_STDERR($pspp_link2) && {
+ test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
+ test ! -s conftest.err
+ } && test -s conftest$ac_exeext && {
+ test "$cross_compiling" = yes ||
+ AS_TEST_X([conftest$ac_exeext])
+ }],
+ [$3],
+ [echo "$as_me: failed source file 1 of 2 was:" >&5
+sed 's/^/| /' conftest1.$ac_ext >&5
+echo "$as_me: failed source file 2 of 2 was:" >&5
+sed 's/^/| /' conftest2.$ac_ext >&5
+ $4])
+dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
+dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
+dnl as it would interfere with the next link command.
+rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
+rm -f core conftest.err conftest1.err conftest2.err
+rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
+rm -f conftest$ac_exeext
+rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
+])# PSPP_LINK2_IFELSE
+
+# GSL uses "extern inline" without determining whether the compiler uses
+# GCC inline rules or C99 inline rules. If it uses the latter then GSL
+# will be broken without passing -fgnu89-inline to GCC.
+AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
+[# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
+ # In turn, gnulib's gl_INLINE is one macro that does that. We need to
+ # make sure that it has run by the time we run this test, otherwise we'll
+ # get a false result.
+ AC_REQUIRE([gl_INLINE])
+ PSPP_CHECK_CC_OPTION(
+ [-fgnu89-inline],
+ [AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
+ pspp_cv_gsl_needs_fgnu89_inline, [
+ PSPP_LINK2_IFELSE(
+ [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
+ ], [GSL_MAX_INT(1,2);])],
+ [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
+ void x (void) {}])],
+ [pspp_cv_gsl_needs_fgnu89_inline=no],
+ [pspp_cv_gsl_needs_fgnu89_inline=yes])])
+ if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
+ CFLAGS="$CFLAGS -fgnu89-inline"
+ fi])
+])
+
+AC_DEFUN([PSPP_CHECK_CLICKSEQUENCE],
+ [AC_REQUIRE([AM_INIT_AUTOMAKE]) # Defines MAKEINFO
+ AC_CACHE_CHECK([whether makeinfo supports @clicksequence],
+ [pspp_cv_have_clicksequence],
+ [cat > conftest.texi <<EOF
+@setfilename conftest.info
+@clicksequence{File @click{} Open}
+EOF
+ echo "configure:__oline__: running $MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
+ eval "$MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD 2>&1"
+ retval=$?
+ echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
+ if test $retval = 0; then
+ pspp_cv_have_clicksequence=yes
+ else
+ pspp_cv_have_clicksequence=no
+ fi
+ rm -f conftest.texi conftest.info])
+ if test $pspp_cv_have_clicksequence = no; then
+ AC_MSG_ERROR([$MAKEINFO does not support @clicksequence.
+Please install a newer or working version, or point the MAKEINFO variable
+to one that is already installed.])
+ fi])
+
+dnl Texinfo 4.13 generates broken DocBook XML. Probably other old
+dnl versions do too, but that's the one that causes problems.
+AC_DEFUN([PSPP_CHECK_MAKEINFO_DOCBOOK_XML],
+ [AC_REQUIRE([AM_INIT_AUTOMAKE]) # Defines MAKEINFO
+ AC_CACHE_CHECK(
+ [whether makeinfo generates broken DocBook XML],
+ [pspp_cv_broken_docbook_xml],
+ [AS_CASE(
+ [$(eval "$MAKEINFO --version | head -1")],
+ [*texinfo*4.13*], [pspp_cv_broken_docbook_xml=yes],
+ [*texinfo*], [pspp_cv_broken_docbook_xml=no],
+ [*], [pspp_cv_broken_docbook_xml=yes])])
+ AM_CONDITIONAL(
+ [BROKEN_DOCBOOK_XML], [test "$pspp_cv_broken_docbook_xml" = yes])])
+
+# The following comes from Open vSwitch:
+# ----------------------------------------------------------------------
+# Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+dnl PSPP_ENABLE_WERROR
+AC_DEFUN([PSPP_ENABLE_WERROR],
+ [AC_ARG_ENABLE(
+ [Werror],
+ [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
+ [], [enable_Werror=no])
+ AC_CONFIG_COMMANDS_PRE(
+ [if test "X$enable_Werror" = Xyes; then
+ CFLAGS="$CFLAGS -Werror -Wno-error=deprecated-declarations"
+ # gnulib needs this, for now:
+ CFLAGS="$CFLAGS -Wno-error=attributes"
+ fi])])
+
+# The following comes from Open vSwitch:
+# ----------------------------------------------------------------------
+# Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+dnl Checks for dot.
+AC_DEFUN([PSPP_CHECK_DOT],
+ [AC_CACHE_CHECK(
+ [for dot],
+ [pspp_cv_dot],
+ [dnl "dot" writes -V output to stderr:
+ if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
+ pspp_cv_dot=yes
+ else
+ pspp_cv_dot=no
+ fi])
+ AM_CONDITIONAL([HAVE_DOT], [test "$pspp_cv_dot" = yes])])
+
+
+dnl Check that xgettext is sufficiently recent
+dnl Before calling this macro, AC_CHECK_PROGS([XGETTEXT], [xgettext]) should have been called,
+dnl which sets the ac_cv_prog_XGETTEXT cache variable.
+AC_DEFUN([PSPP_CHECK_XGETTEXT],
+ [AC_CACHE_CHECK([whether gettext is sufficiently recent],
+ [pspp_cv_progrecent_xgettext],
+ [pspp_cv_progrecent_xgettext=maybe
+ ver=`$ac_cv_prog_XGETTEXT --version | sed -n -e '/xgettext/s/[[^0-9]]*\([[0-9\.]][[0-9\.]]*\).*/\1/p'`
+ case $ver in # (
+ *.*.*) ;; # (
+ *.*) ver="$ver.0" ;;
+ esac
+ majmin=`echo $ver | sed -e 's/\.[[0-9]]*$//'`
+ major=`echo $majmin | sed -e 's/\.[[0-9]]*$//'`
+ minor=`echo $majmin | sed -e 's/^[[0-9]]*\.//'`
+ if test "$major" -lt 0; then
+ pspp_cv_progrecent_xgettext=no;
+ elif test "$minor" -lt 20; then
+ pspp_cv_progrecent_xgettext=no
+ else
+ pspp_cv_progrecent_xgettext=yes
+ fi])])
projects / pspp / blobdiff