pintos-os.org Git - pspp/blob - tests/libpspp/i18n.at

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl AT_BANNER([i18n recoding])
  17
  18 # CHECK_I18N_RECODE([TITLE], [FROM-CODING], [TO-CODING],
  19 #                   [FROM-TEXT], [TO-TEXT])
  20 #
  21 # Converts FROM-TEXT from FROM-CODING to TO-CODING and checks that the result
  22 # is TO-TEXT.  The "printf" program is applied to both FROM-TEXT and TO-TEXT to
  23 # allow for backslash-escapes.  (Hex escapes are not portable; use octal
  24 # escapes instead.)
  25 m4_define([CHECK_I18N_RECODE],
  26   [AT_SETUP([convert $1])
  27    AT_KEYWORDS([i18n])
  28
  29    dnl Skip the test if this host doesn't know the source and target encodings.
  30    AT_CHECK([i18n-test supports_encodings '$2' '$3'])
  31    AT_CHECK_UNQUOTED([i18n-test recode '$2' '$3' `printf '$4'`], [0], [`printf '$5'`
  32 ])
  33    AT_CLEANUP])
  34
  35 CHECK_I18N_RECODE([reflexively], [ASCII], [ASCII], [abc], [abc])
  36 CHECK_I18N_RECODE([without any change], [ASCII], [UTF-8], [abc], [abc])
  37
  38 CHECK_I18N_RECODE([from ISO-8859-1 to UTF-8], [ISO-8859-1], [UTF-8],
  39                   [\242], [\302\242])
  40 CHECK_I18N_RECODE([from UTF-8 to ISO-8859-1], [UTF-8], [ISO-8859-1],
  41                   [\302\242], [\242])
  42
  43 # 0xc0 == 0300 is invalid in UTF-8
  44 CHECK_I18N_RECODE([invalid UTF-8 to ISO-8859-1], [UTF-8], [ISO-8859-1],
  45                   [xy\300z], [xy?z])
  46 # 0xc2 == 0302 is the first byte of a 2-byte UTF-8 sequence
  47 CHECK_I18N_RECODE([truncated UTF-8 to ISO-8559-1], [UTF-8], [ISO-8859-1],
  48                   [xy\302], [xy?])
  49
  50 # Checks for a bug that caused the last character to be dropped in conversions
  51 # from encodings that have combining diacritics (e.g. windows-1258).
  52 CHECK_I18N_RECODE([dropped final character in windows-1258], [windows-1258],
  53                   [UTF-8], [aeiou], [aeiou])
  54
  55 dnl The input to this test is 7 bytes long and the expected output is 9 bytes.
  56 dnl So it should exercise the E2BIG case
  57 CHECK_I18N_RECODE([from ISO-8859-1 to UTF-8 with overflow],
  58                   [ISO-8859-1], [UTF-8],
  59                   [Tsch\374\337!], [Tsch\303\274\303\237!])
  60
  61 AT_SETUP([convert unknown encoding])
  62 AT_KEYWORDS([i18n])
  63 AT_CHECK([i18n-test recode nonexistent1 nonexistent2 asdf], [0], [asdf
  64 ],
  65   [Warning: cannot create a converter for `nonexistent1' to `nonexistent2': Invalid argument
  66 ])
  67 AT_CLEANUP
  68 \f
  69 AT_BANNER([i18n concatenation])
  70
  71 # CHECK_I18N_CONCAT([HEAD], [TAIL], [ENCODING], [MAX-LEN], [ANSWER])
  72 #
  73 # Concatenates HEAD and TAIL, omitting as many characters from HEAD as needed
  74 # to make the result come out to no more than MAX-LEN bytes if it was expressed
  75 # in ENCODING, and checks that the answer matches ANSWER.  HEAD, TAIL, and
  76 # ANSWER are all in UTF-8.  The "printf" program is applied to HEAD, TAIL, and
  77 # ANSWER to allow for backslash-escapes.  (Hex escapes are not portable; use
  78 # octal escapes instead.)
  79 m4_define([CHECK_I18N_CONCAT],
  80   [AT_SETUP([m4_if([$2], [], [truncate "$1" to $4 bytes in $3],
  81                              [truncate "$1" + "$2" to $4 bytes in $3])])
  82    AT_KEYWORDS([i18n])
  83
  84    dnl Skip the test if this host doesn't know the encoding.
  85    AT_CHECK([i18n-test supports_encodings '$3'])
  86    AT_CHECK_UNQUOTED(
  87      [i18n-test concat "`printf '$1'`" "`printf '$2'`" '$3' '$4'], [0],
  88      [`printf '$5'`
  89 ])
  90    AT_CLEANUP])
  91
  92 CHECK_I18N_CONCAT([abc], [], [UTF-8], [6], [abc])
  93 CHECK_I18N_CONCAT([], [xyz], [UTF-8], [6], [xyz])
  94 CHECK_I18N_CONCAT([], [], [UTF-8], [6], [])
  95 CHECK_I18N_CONCAT([abcdefghij], [], [UTF-8], [6], [abcdef])
  96 CHECK_I18N_CONCAT([], [tuvwxyz], [UTF-8], [6], [tuvwxyz])
  97
  98 CHECK_I18N_CONCAT([abc], [xyz], [UTF-8], [6], [abcxyz])
  99 CHECK_I18N_CONCAT([abcd], [xyz], [UTF-8], [6], [abcxyz])
 100 CHECK_I18N_CONCAT([abc], [uvwxyz], [UTF-8], [6], [uvwxyz])
 101
 102 # x in a box ( x⃞ ) is U+0078, U+20DE, 4 bytes in UTF-8, and one grapheme
 103 # cluster.
 104 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [0], [y])
 105 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [1], [y])
 106 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [2], [y])
 107 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [3], [y])
 108 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [4], [y])
 109 CHECK_I18N_CONCAT([x\342\203\236], [y], [UTF-8], [5], [x\342\203\236y])
 110
 111 # éèä is only 3 bytes in ISO-8859-1.
 112 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [0], [xyz])
 113 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [1], [xyz])
 114 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [2], [xyz])
 115 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [3], [xyz])
 116 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [4],
 117                   [\303\251xyz])
 118 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [5],
 119                   [\303\251\303\250xyz])
 120 CHECK_I18N_CONCAT([\303\251\303\250\303\244], [xyz], [ISO-8859-1], [6],
 121                   [\303\251\303\250\303\244xyz])