pintos-os.org Git - pspp/blob - m4/vsnprintf-posix.m4

   1 # vsnprintf-posix.m4 serial 7
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VSNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  15   AC_REQUIRE([gl_PRINTF_POSITIONS])
  16   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  17   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  18   gl_cv_func_vsnprintf_posix=no
  19   AC_CHECK_FUNCS([vsnprintf])
  20   if test $ac_cv_func_vsnprintf = yes; then
  21     dnl Assume that if vsnprintf() exists, snprintf() also exists.
  22     gl_SNPRINTF_TRUNCATION_C99
  23     gl_SNPRINTF_RETVAL_C99
  24     gl_SNPRINTF_DIRECTIVE_N
  25     gl_VSNPRINTF_ZEROSIZE_C99
  26     case "$gl_cv_func_printf_sizes_c99" in
  27       *yes)
  28         case "$gl_cv_func_printf_long_double" in
  29           *yes)
  30             case "$gl_cv_func_printf_directive_a" in
  31               *yes)
  32                 case "$gl_cv_func_printf_directive_f" in
  33                   *yes)
  34                     case "$gl_cv_func_printf_directive_n" in
  35                       *yes)
  36                         case "$gl_cv_func_printf_positions" in
  37                           *yes)
  38                             case "$gl_cv_func_printf_flag_grouping" in
  39                               *yes)
  40                                 case "$gl_cv_func_printf_flag_zero" in
  41                                   *yes)
  42                                     case "$gl_cv_func_snprintf_truncation_c99" in
  43                                       *yes)
  44                                         case "$gl_cv_func_snprintf_retval_c99" in
  45                                           *yes)
  46                                             case "$gl_cv_func_snprintf_directive_n" in
  47                                               *yes)
  48                                                 case "$gl_cv_func_vsnprintf_zerosize_c99" in
  49                                                   *yes)
  50                                                     # vsnprintf exists and is
  51                                                     # already POSIX compliant.
  52                                                     gl_cv_func_vsnprintf_posix=yes
  53                                                     ;;
  54                                                 esac
  55                                                 ;;
  56                                             esac
  57                                             ;;
  58                                         esac
  59                                         ;;
  60                                     esac
  61                                     ;;
  62                                 esac
  63                                 ;;
  64                             esac
  65                             ;;
  66                         esac
  67                         ;;
  68                     esac
  69                     ;;
  70                 esac
  71                 ;;
  72             esac
  73             ;;
  74         esac
  75         ;;
  76     esac
  77   fi
  78   if test $gl_cv_func_vsnprintf_posix = no; then
  79     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  80     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  81     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  82     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  83     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  84     gl_REPLACE_VASNPRINTF
  85     gl_REPLACE_VSNPRINTF
  86   fi
  87 ])