pintos-os.org Git - pspp/blob - m4/sys_socket_h.m4

   1 # sys_socket_h.m4 serial 8
   2 dnl Copyright (C) 2005-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson.
   8
   9 AC_DEFUN([gl_HEADER_SYS_SOCKET],
  10 [
  11   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
  12   AC_REQUIRE([AC_C_INLINE])
  13
  14   AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
  15     [gl_cv_header_sys_socket_h_selfcontained],
  16     [
  17       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]], [[]])],
  18         [gl_cv_header_sys_socket_h_selfcontained=yes],
  19         [gl_cv_header_sys_socket_h_selfcontained=no])
  20     ])
  21   if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
  22     SYS_SOCKET_H=''
  23     dnl If the shutdown function exists, <sys/socket.h> should define
  24     dnl SHUT_RD, SHUT_WR, SHUT_RDWR.
  25     AC_CHECK_FUNCS([shutdown])
  26     if test $ac_cv_func_shutdown = yes; then
  27       AC_CACHE_CHECK([whether <sys/socket.h> defines the SHUT_* macros],
  28         [gl_cv_header_sys_socket_h_shut],
  29         [
  30           AC_COMPILE_IFELSE(
  31             [AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  32                [[int a[] = { SHUT_RD, SHUT_WR, SHUT_RDWR };]])],
  33             [gl_cv_header_sys_socket_h_shut=yes],
  34             [gl_cv_header_sys_socket_h_shut=no])
  35         ])
  36       if test $gl_cv_header_sys_socket_h_shut = no; then
  37         SYS_SOCKET_H='sys/socket.h'
  38       fi
  39     fi
  40   else
  41     SYS_SOCKET_H='sys/socket.h'
  42   fi
  43   if test -n "$SYS_SOCKET_H"; then
  44     dnl Check prerequisites of the <sys/socket.h> replacement.
  45     gl_CHECK_NEXT_HEADERS([sys/socket.h])
  46     if test $ac_cv_header_sys_socket_h = yes; then
  47       HAVE_SYS_SOCKET_H=1
  48       HAVE_WS2TCPIP_H=0
  49     else
  50       HAVE_SYS_SOCKET_H=0
  51       dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  52       dnl the check for those headers unconditional; yet cygwin reports
  53       dnl that the headers are present but cannot be compiled (since on
  54       dnl cygwin, all socket information should come from sys/socket.h).
  55       AC_CHECK_HEADERS([ws2tcpip.h])
  56       if test $ac_cv_header_ws2tcpip_h = yes; then
  57         HAVE_WS2TCPIP_H=1
  58       else
  59         HAVE_WS2TCPIP_H=0
  60       fi
  61     fi
  62     gl_PREREQ_SYS_H_WINSOCK2
  63     if test x$ac_cv_header_winsock2_h = xyes; then
  64       AC_LIBOBJ(winsock)
  65     fi
  66     AC_SUBST([HAVE_SYS_SOCKET_H])
  67     AC_SUBST([HAVE_WS2TCPIP_H])
  68   fi
  69   AC_SUBST([SYS_SOCKET_H])
  70 ])
  71
  72 # Common prerequisites of of the <sys/socket.h> replacement and of the
  73 # <sys/select.h> replacement.
  74 # Sets and substitutes HAVE_WINSOCK2_H.
  75 AC_DEFUN([gl_PREREQ_SYS_H_WINSOCK2],
  76 [
  77   AC_CHECK_HEADERS_ONCE([sys/socket.h])
  78   if test $ac_cv_header_sys_socket_h != yes; then
  79     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  80     dnl the check for those headers unconditional; yet cygwin reports
  81     dnl that the headers are present but cannot be compiled (since on
  82     dnl cygwin, all socket information should come from sys/socket.h).
  83     AC_CHECK_HEADERS([winsock2.h])
  84   fi
  85   if test "$ac_cv_header_winsock2_h" = yes; then
  86     HAVE_WINSOCK2_H=1
  87   else
  88     HAVE_WINSOCK2_H=0
  89   fi
  90   AC_SUBST([HAVE_WINSOCK2_H])
  91 ])
  92
  93 AC_DEFUN([gl_SYS_SOCKET_MODULE_INDICATOR],
  94 [
  95   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  96   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
  97   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  98   gl_MODULE_INDICATOR([$1])
  99 ])
 100
 101 AC_DEFUN([gl_SYS_SOCKET_H_DEFAULTS],
 102 [
 103   GNULIB_SOCKET=0;      AC_SUBST([GNULIB_SOCKET])
 104   GNULIB_CONNECT=0;     AC_SUBST([GNULIB_CONNECT])
 105   GNULIB_ACCEPT=0;      AC_SUBST([GNULIB_ACCEPT])
 106   GNULIB_BIND=0;        AC_SUBST([GNULIB_BIND])
 107   GNULIB_GETPEERNAME=0; AC_SUBST([GNULIB_GETPEERNAME])
 108   GNULIB_GETSOCKNAME=0; AC_SUBST([GNULIB_GETSOCKNAME])
 109   GNULIB_GETSOCKOPT=0;  AC_SUBST([GNULIB_GETSOCKOPT])
 110   GNULIB_LISTEN=0;      AC_SUBST([GNULIB_LISTEN])
 111   GNULIB_RECV=0;        AC_SUBST([GNULIB_RECV])
 112   GNULIB_SEND=0;        AC_SUBST([GNULIB_SEND])
 113   GNULIB_RECVFROM=0;    AC_SUBST([GNULIB_RECVFROM])
 114   GNULIB_SENDTO=0;      AC_SUBST([GNULIB_SENDTO])
 115   GNULIB_SETSOCKOPT=0;  AC_SUBST([GNULIB_SETSOCKOPT])
 116 ])