pintos-os.org Git - pspp/blob - m4/snprintf-posix.m4

   1 # snprintf-posix.m4 serial 4
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  14   AC_REQUIRE([gl_PRINTF_POSITIONS])
  15   gl_cv_func_snprintf_posix=no
  16   AC_CHECK_FUNCS([snprintf])
  17   if test $ac_cv_func_snprintf = yes; then
  18     gl_SNPRINTF_TRUNCATION_C99
  19     gl_SNPRINTF_RETVAL_C99
  20     gl_SNPRINTF_DIRECTIVE_N
  21     gl_VSNPRINTF_ZEROSIZE_C99
  22     case "$gl_cv_func_printf_sizes_c99" in
  23       *yes)
  24         case "$gl_cv_func_printf_directive_a" in
  25           *yes)
  26             case "$gl_cv_func_printf_directive_f" in
  27               *yes)
  28                 case "$gl_cv_func_printf_directive_n" in
  29                   *yes)
  30                     case "$gl_cv_func_printf_positions" in
  31                       *yes)
  32                         case "$gl_cv_func_snprintf_truncation_c99" in
  33                           *yes)
  34                             case "$gl_cv_func_snprintf_retval_c99" in
  35                               *yes)
  36                                 case "$gl_cv_func_snprintf_directive_n" in
  37                                   *yes)
  38                                     case "$gl_cv_func_vsnprintf_zerosize_c99" in
  39                                       *yes)
  40                                         # snprintf exists and is already POSIX
  41                                         # compliant.
  42                                         gl_cv_func_snprintf_posix=yes
  43                                         ;;
  44                                     esac
  45                                     ;;
  46                                 esac
  47                                 ;;
  48                             esac
  49                             ;;
  50                         esac
  51                         ;;
  52                     esac
  53                     ;;
  54                 esac
  55                 ;;
  56             esac
  57             ;;
  58         esac
  59         ;;
  60     esac
  61   fi
  62   if test $gl_cv_func_snprintf_posix = no; then
  63     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  64     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  65     gl_REPLACE_VASNPRINTF
  66     gl_REPLACE_SNPRINTF
  67   fi
  68 ])