pintos-os.org Git - pspp/blob - m4/setenv.m4

   1 # setenv.m4 serial 19
   2 dnl Copyright (C) 2001-2004, 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SETENV],
   8 [
   9   AC_REQUIRE([gl_FUNC_SETENV_SEPARATE])
  10   if test $HAVE_SETENV$REPLACE_SETENV != 10; then
  11     AC_LIBOBJ([setenv])
  12   fi
  13 ])
  14
  15 # Like gl_FUNC_SETENV, except prepare for separate compilation (no AC_LIBOBJ).
  16 AC_DEFUN([gl_FUNC_SETENV_SEPARATE],
  17 [
  18   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  19   AC_CHECK_DECLS_ONCE([setenv])
  20   if test $ac_cv_have_decl_setenv = no; then
  21     HAVE_DECL_SETENV=0
  22   fi
  23   AC_CHECK_FUNCS_ONCE([setenv])
  24   if test $ac_cv_func_setenv = yes; then
  25     AC_CACHE_CHECK([whether setenv validates arguments],
  26       [gl_cv_func_setenv_works],
  27       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  28        #include <stdlib.h>
  29        #include <errno.h>
  30        #include <string.h>
  31       ]], [[
  32        int result = 0;
  33        {
  34          if (setenv ("", "", 0) != -1)
  35            result |= 1;
  36          else if (errno != EINVAL)
  37            result |= 2;
  38        }
  39        {
  40          if (setenv ("a", "=", 1) != 0)
  41            result |= 4;
  42          else if (strcmp (getenv ("a"), "=") != 0)
  43            result |= 8;
  44        }
  45        return result;
  46       ]])],
  47       [gl_cv_func_setenv_works=yes], [gl_cv_func_setenv_works=no],
  48       [gl_cv_func_setenv_works="guessing no"])])
  49     if test "$gl_cv_func_setenv_works" != yes; then
  50       REPLACE_SETENV=1
  51       AC_LIBOBJ([setenv])
  52     fi
  53   fi
  54   gl_PREREQ_SETENV
  55 ])
  56
  57 AC_DEFUN([gl_FUNC_UNSETENV],
  58 [
  59   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  60   AC_CHECK_FUNCS([unsetenv])
  61   if test $ac_cv_func_unsetenv = no; then
  62     HAVE_UNSETENV=0
  63     AC_LIBOBJ([unsetenv])
  64     gl_PREREQ_UNSETENV
  65   else
  66     dnl Some BSDs return void, failing to do error checking.
  67     AC_CACHE_CHECK([for unsetenv() return type], [gt_cv_func_unsetenv_ret],
  68       [AC_COMPILE_IFELSE(
  69          [AC_LANG_PROGRAM(
  70             [[
  71 #include <stdlib.h>
  72 extern
  73 #ifdef __cplusplus
  74 "C"
  75 #endif
  76 #if defined(__STDC__) || defined(__cplusplus)
  77 int unsetenv (const char *name);
  78 #else
  79 int unsetenv();
  80 #endif
  81             ]],
  82             [[]])],
  83          [gt_cv_func_unsetenv_ret='int'],
  84          [gt_cv_func_unsetenv_ret='void'])])
  85     if test $gt_cv_func_unsetenv_ret = 'void'; then
  86       AC_DEFINE([VOID_UNSETENV], [1], [Define to 1 if unsetenv returns void
  87        instead of int.])
  88       REPLACE_UNSETENV=1
  89       AC_LIBOBJ([unsetenv])
  90     fi
  91
  92     dnl Solaris 10 unsetenv does not remove all copies of a name.
  93     dnl OpenBSD 4.7 unsetenv("") does not fail.
  94     AC_CACHE_CHECK([whether unsetenv obeys POSIX],
  95       [gl_cv_func_unsetenv_works],
  96       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  97        #include <stdlib.h>
  98        #include <errno.h>
  99       ]], [[
 100        char entry[] = "b=2";
 101        if (putenv ((char *) "a=1")) return 1;
 102        if (putenv (entry)) return 2;
 103        entry[0] = 'a';
 104        unsetenv ("a");
 105        if (getenv ("a")) return 3;
 106        if (!unsetenv ("") || errno != EINVAL) return 4;
 107       ]])],
 108       [gl_cv_func_unsetenv_works=yes], [gl_cv_func_unsetenv_works=no],
 109       [gl_cv_func_unsetenv_works="guessing no"])])
 110     if test "$gl_cv_func_unsetenv_works" != yes; then
 111       REPLACE_UNSETENV=1
 112       AC_LIBOBJ([unsetenv])
 113     fi
 114   fi
 115 ])
 116
 117 # Prerequisites of lib/setenv.c.
 118 AC_DEFUN([gl_PREREQ_SETENV],
 119 [
 120   AC_REQUIRE([AC_FUNC_ALLOCA])
 121   AC_REQUIRE([gl_ENVIRON])
 122   AC_CHECK_HEADERS_ONCE([unistd.h])
 123   AC_CHECK_HEADERS([search.h])
 124   AC_CHECK_FUNCS([tsearch])
 125 ])
 126
 127 # Prerequisites of lib/unsetenv.c.
 128 AC_DEFUN([gl_PREREQ_UNSETENV],
 129 [
 130   AC_REQUIRE([gl_ENVIRON])
 131   AC_CHECK_HEADERS_ONCE([unistd.h])
 132 ])