pintos-os.org Git - pspp/blob - m4/setenv.m4

   1 # setenv.m4 serial 12
   2 dnl Copyright (C) 2001-2004, 2006-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SETENV],
   8 [
   9   AC_REQUIRE([gl_FUNC_SETENV_SEPARATE])
  10   if test $HAVE_SETENV$REPLACE_SETENV != 10; then
  11     AC_LIBOBJ([setenv])
  12   fi
  13 ])
  14
  15 # Like gl_FUNC_SETENV, except prepare for separate compilation (no AC_LIBOBJ).
  16 AC_DEFUN([gl_FUNC_SETENV_SEPARATE],
  17 [
  18   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  19   AC_CHECK_FUNCS_ONCE([setenv])
  20   if test $ac_cv_func_setenv = no; then
  21     HAVE_SETENV=0
  22   else
  23     AC_CACHE_CHECK([whether setenv validates arguments],
  24       [gl_cv_func_setenv_works],
  25       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  26        #include <stdlib.h>
  27        #include <errno.h>
  28       ]], [[
  29        if (setenv (NULL, "", 0) != -1) return 1;
  30        if (errno != EINVAL) return 2;
  31        if (setenv ("a", "=", 1) != 0) return 3;
  32        if (strcmp (getenv ("a"), "=") != 0) return 4;
  33       ]])],
  34       [gl_cv_func_setenv_works=yes], [gl_cv_func_setenv_works=no],
  35       [gl_cv_func_setenv_works="guessing no"])])
  36     if test "$gl_cv_func_setenv_works" != yes; then
  37       REPLACE_SETENV=1
  38       AC_LIBOBJ([setenv])
  39     fi
  40   fi
  41   gl_PREREQ_SETENV
  42 ])
  43
  44 AC_DEFUN([gl_FUNC_UNSETENV],
  45 [
  46   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  47   AC_CHECK_FUNCS([unsetenv])
  48   if test $ac_cv_func_unsetenv = no; then
  49     HAVE_UNSETENV=0
  50     AC_LIBOBJ([unsetenv])
  51     gl_PREREQ_UNSETENV
  52   else
  53     AC_CACHE_CHECK([for unsetenv() return type], [gt_cv_func_unsetenv_ret],
  54       [AC_TRY_COMPILE([#include <stdlib.h>
  55 extern
  56 #ifdef __cplusplus
  57 "C"
  58 #endif
  59 #if defined(__STDC__) || defined(__cplusplus)
  60 int unsetenv (const char *name);
  61 #else
  62 int unsetenv();
  63 #endif
  64 ], , gt_cv_func_unsetenv_ret='int', gt_cv_func_unsetenv_ret='void')])
  65     if test $gt_cv_func_unsetenv_ret = 'void'; then
  66       AC_DEFINE([VOID_UNSETENV], [1], [Define to 1 if unsetenv returns void
  67        instead of int.])
  68       REPLACE_UNSETENV=1
  69       AC_LIBOBJ([unsetenv])
  70     fi
  71   fi
  72 ])
  73
  74 # Prerequisites of lib/setenv.c.
  75 AC_DEFUN([gl_PREREQ_SETENV],
  76 [
  77   AC_REQUIRE([AC_FUNC_ALLOCA])
  78   AC_REQUIRE([gl_ENVIRON])
  79   AC_CHECK_HEADERS_ONCE([unistd.h])
  80   AC_CHECK_HEADERS([search.h])
  81   AC_CHECK_FUNCS([tsearch])
  82 ])
  83
  84 # Prerequisites of lib/unsetenv.c.
  85 AC_DEFUN([gl_PREREQ_UNSETENV],
  86 [
  87   AC_REQUIRE([gl_ENVIRON])
  88   AC_CHECK_HEADERS_ONCE([unistd.h])
  89 ])