pintos-os.org Git - pspp/blob - m4/posix_spawn.m4

   1 # posix_spawn.m4 serial 4
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Tests whether the entire posix_spawn facility is available.
   8 AC_DEFUN([gl_POSIX_SPAWN],
   9 [
  10   AC_REQUIRE([gl_POSIX_SPAWN_BODY])
  11 ])
  12
  13 AC_DEFUN([gl_POSIX_SPAWN_BODY],
  14 [
  15   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  16   AC_CHECK_FUNCS_ONCE([posix_spawn])
  17   dnl Assume that when the main function exists, all the others are
  18   dnl available as well.
  19   dnl AC_CHECK_FUNCS_ONCE([posix_spawnp])
  20   dnl AC_CHECK_FUNCS_ONCE([posix_spawn_file_actions_init])
  21   dnl AC_CHECK_FUNCS_ONCE([posix_spawn_file_actions_addclose])
  22   dnl AC_CHECK_FUNCS_ONCE([posix_spawn_file_actions_adddup2])
  23   dnl AC_CHECK_FUNCS_ONCE([posix_spawn_file_actions_addopen])
  24   dnl AC_CHECK_FUNCS_ONCE([posix_spawn_file_actions_destroy])
  25   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_init])
  26   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getflags])
  27   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setflags])
  28   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getpgroup])
  29   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setpgroup])
  30   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getschedparam])
  31   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setschedparam])
  32   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getschedpolicy])
  33   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setschedpolicy])
  34   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getsigdefault])
  35   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setsigdefault])
  36   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_getsigmask])
  37   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_setsigmask])
  38   dnl AC_CHECK_FUNCS_ONCE([posix_spawnattr_destroy])
  39   if test $ac_cv_func_posix_spawn = yes; then
  40     gl_POSIX_SPAWN_WORKS
  41     case "$gl_cv_func_posix_spawn_works" in
  42       *yes) ;;
  43       *) REPLACE_POSIX_SPAWN=1 ;;
  44     esac
  45   else
  46     HAVE_POSIX_SPAWN=0
  47   fi
  48 ])
  49
  50 dnl Test whether posix_spawn actually works.
  51 dnl posix_spawn on AIX 5.3..6.1 has a bug: When it fails to execute the
  52 dnl program, the child process exits with exit() rather than _exit(),
  53 dnl which causes the stdio buffers to be flushed. Reported by Rainer Tammer.
  54 dnl posix_spawn on AIX 5.3..6.1 has also a second bug: It does not work
  55 dnl when POSIX threads are used. But we don't test against this bug here.
  56 AC_DEFUN([gl_POSIX_SPAWN_WORKS],
  57 [
  58   AC_REQUIRE([AC_PROG_CC])
  59   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  60   AC_CACHE_CHECK([whether posix_spawn works], [gl_cv_func_posix_spawn_works],
  61     [if test $cross_compiling = no; then
  62        AC_LINK_IFELSE([AC_LANG_SOURCE([[
  63 #include <errno.h>
  64 #include <fcntl.h>
  65 #include <signal.h>
  66 #include <spawn.h>
  67 #include <stdbool.h>
  68 #include <stdio.h>
  69 #include <stdlib.h>
  70 #include <string.h>
  71 #include <unistd.h>
  72 #include <sys/types.h>
  73 #include <sys/wait.h>
  74
  75 extern char **environ;
  76
  77 #ifndef STDIN_FILENO
  78 # define STDIN_FILENO 0
  79 #endif
  80 #ifndef STDOUT_FILENO
  81 # define STDOUT_FILENO 1
  82 #endif
  83 #ifndef STDERR_FILENO
  84 # define STDERR_FILENO 2
  85 #endif
  86
  87 #ifndef WTERMSIG
  88 # define WTERMSIG(x) ((x) & 0x7f)
  89 #endif
  90 #ifndef WIFEXITED
  91 # define WIFEXITED(x) (WTERMSIG (x) == 0)
  92 #endif
  93 #ifndef WEXITSTATUS
  94 # define WEXITSTATUS(x) (((x) >> 8) & 0xff)
  95 #endif
  96
  97 #define CHILD_PROGRAM_FILENAME "/non/exist/ent"
  98
  99 static int
 100 fd_safer (int fd)
 101 {
 102   if (0 <= fd && fd <= 2)
 103     {
 104       int f = fd_safer (dup (fd));
 105       int e = errno;
 106       close (fd);
 107       errno = e;
 108       fd = f;
 109     }
 110
 111   return fd;
 112 }
 113
 114 int
 115 main ()
 116 {
 117   char *argv[2] = { CHILD_PROGRAM_FILENAME, NULL };
 118   int ofd[2];
 119   sigset_t blocked_signals;
 120   sigset_t fatal_signal_set;
 121   posix_spawn_file_actions_t actions;
 122   bool actions_allocated;
 123   posix_spawnattr_t attrs;
 124   bool attrs_allocated;
 125   int err;
 126   pid_t child;
 127   int status;
 128   int exitstatus;
 129
 130   setvbuf (stdout, NULL, _IOFBF, 0);
 131   puts ("This should be seen only once.");
 132   if (pipe (ofd) < 0 || (ofd[1] = fd_safer (ofd[1])) < 0)
 133     {
 134       perror ("cannot create pipe");
 135       exit (1);
 136     }
 137   sigprocmask (SIG_SETMASK, NULL, &blocked_signals);
 138   sigemptyset (&fatal_signal_set);
 139   sigaddset (&fatal_signal_set, SIGINT);
 140   sigaddset (&fatal_signal_set, SIGTERM);
 141   sigaddset (&fatal_signal_set, SIGHUP);
 142   sigaddset (&fatal_signal_set, SIGPIPE);
 143   sigprocmask (SIG_BLOCK, &fatal_signal_set, NULL);
 144   actions_allocated = false;
 145   attrs_allocated = false;
 146   if ((err = posix_spawn_file_actions_init (&actions)) != 0
 147       || (actions_allocated = true,
 148           (err = posix_spawn_file_actions_adddup2 (&actions, ofd[0], STDIN_FILENO)) != 0
 149           || (err = posix_spawn_file_actions_addclose (&actions, ofd[0])) != 0
 150           || (err = posix_spawn_file_actions_addclose (&actions, ofd[1])) != 0
 151           || (err = posix_spawnattr_init (&attrs)) != 0
 152           || (attrs_allocated = true,
 153               (err = posix_spawnattr_setsigmask (&attrs, &blocked_signals)) != 0
 154               || (err = posix_spawnattr_setflags (&attrs, POSIX_SPAWN_SETSIGMASK)) != 0)
 155           || (err = posix_spawnp (&child, CHILD_PROGRAM_FILENAME, &actions, &attrs, argv, environ)) != 0))
 156     {
 157       if (actions_allocated)
 158         posix_spawn_file_actions_destroy (&actions);
 159       if (attrs_allocated)
 160         posix_spawnattr_destroy (&attrs);
 161       sigprocmask (SIG_UNBLOCK, &fatal_signal_set, NULL);
 162       if (err == ENOENT)
 163         return 0;
 164       else
 165         {
 166           errno = err;
 167           perror ("subprocess failed");
 168           exit (1);
 169         }
 170     }
 171   posix_spawn_file_actions_destroy (&actions);
 172   posix_spawnattr_destroy (&attrs);
 173   sigprocmask (SIG_UNBLOCK, &fatal_signal_set, NULL);
 174   close (ofd[0]);
 175   close (ofd[1]);
 176   status = 0;
 177   while (waitpid (child, &status, 0) != child)
 178     ;
 179   if (!WIFEXITED (status))
 180     {
 181       fprintf (stderr, "subprocess terminated with unexpected wait status %d\n", status);
 182       exit (1);
 183     }
 184   exitstatus = WEXITSTATUS (status);
 185   if (exitstatus != 127)
 186     {
 187       fprintf (stderr, "subprocess terminated with unexpected exit status %d\n", exitstatus);
 188       exit (1);
 189     }
 190   return 0;
 191 }
 192 ]])],
 193          [if test -s conftest$ac_exeext \
 194              && ./conftest$ac_exeext > conftest.out \
 195              && echo 'This should be seen only once.' > conftest.ok \
 196              && cmp conftest.out conftest.ok > /dev/null; then
 197             gl_cv_func_posix_spawn_works=yes
 198           else
 199             gl_cv_func_posix_spawn_works=no
 200           fi],
 201          [gl_cv_func_posix_spawn_works=no])
 202      else
 203        case "$host_os" in
 204          aix*) gl_cv_func_posix_spawn_works="guessing no";;
 205          *)    gl_cv_func_posix_spawn_works="guessing yes";;
 206        esac
 207      fi
 208     ])
 209 ])
 210
 211 AC_DEFUN([gl_POSIX_SPAWN_INTERNAL],
 212 [
 213   AC_LIBOBJ([spawni])
 214   dnl Prerequisites of lib/spawni.c.
 215   AC_CHECK_HEADERS([paths.h])
 216   AC_CHECK_FUNCS([confstr sched_setparam sched_setscheduler setegid seteuid vfork])
 217 ])