pintos-os.org Git - pspp/blob - m4/memmem.m4

   1 # memmem.m4 serial 15
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2008, 2009, 2010 Free Software
   3 dnl Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Check that memmem is present.
   9 AC_DEFUN([gl_FUNC_MEMMEM_SIMPLE],
  10 [
  11   dnl Persuade glibc <string.h> to declare memmem().
  12   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  13
  14   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  15   AC_REPLACE_FUNCS([memmem])
  16   AC_CHECK_DECLS_ONCE([memmem])
  17   if test $ac_cv_have_decl_memmem = no; then
  18     HAVE_DECL_MEMMEM=0
  19   fi
  20   gl_PREREQ_MEMMEM
  21 ]) # gl_FUNC_MEMMEM_SIMPLE
  22
  23 dnl Additionally, check that memmem is efficient and handles empty needles.
  24 AC_DEFUN([gl_FUNC_MEMMEM],
  25 [
  26   AC_REQUIRE([gl_FUNC_MEMMEM_SIMPLE])
  27   if test $ac_cv_have_decl_memmem = yes; then
  28     AC_CACHE_CHECK([whether memmem works in linear time],
  29       [gl_cv_func_memmem_works],
  30       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  31 #include <signal.h> /* for signal */
  32 #include <string.h> /* for memmem */
  33 #include <stdlib.h> /* for malloc */
  34 #include <unistd.h> /* for alarm */
  35 static void quit (int sig) { exit (sig + 128); }
  36 ]], [[size_t m = 1000000;
  37     char *haystack = (char *) malloc (2 * m + 1);
  38     char *needle = (char *) malloc (m + 1);
  39     void *result = 0;
  40     /* Failure to compile this test due to missing alarm is okay,
  41        since all such platforms (mingw) also lack memmem.  */
  42     signal (SIGALRM, quit);
  43     alarm (5);
  44     /* Check for quadratic performance.  */
  45     if (haystack && needle)
  46       {
  47         memset (haystack, 'A', 2 * m);
  48         haystack[2 * m] = 'B';
  49         memset (needle, 'A', m);
  50         needle[m] = 'B';
  51         result = memmem (haystack, 2 * m + 1, needle, m + 1);
  52       }
  53     /* Check for empty needle behavior.  */
  54     return !result || !memmem ("a", 1, 0, 0);]])],
  55         [gl_cv_func_memmem_works=yes], [gl_cv_func_memmem_works=no],
  56         [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  57          dnl memmem that works in linear time.
  58          AC_EGREP_CPP([Lucky user],
  59            [
  60 #include <features.h>
  61 #ifdef __GNU_LIBRARY__
  62  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  63   Lucky user
  64  #endif
  65 #endif
  66 #ifdef __CYGWIN__
  67  #include <cygwin/version.h>
  68  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  69   Lucky user
  70  #endif
  71 #endif
  72            ],
  73            [gl_cv_func_memmem_works=yes],
  74            [gl_cv_func_memmem_works="guessing no"])
  75         ])
  76       ])
  77     if test "$gl_cv_func_memmem_works" != yes; then
  78       REPLACE_MEMMEM=1
  79       AC_LIBOBJ([memmem])
  80     fi
  81   fi
  82 ]) # gl_FUNC_MEMMEM
  83
  84 # Prerequisites of lib/memmem.c.
  85 AC_DEFUN([gl_PREREQ_MEMMEM], [:])