pintos-os.org Git - pspp/blob - m4/malloc.m4

   1 # malloc.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_FUNC_MALLOC_POSIX
   8 # --------------------
   9 # Test whether 'malloc' is POSIX compliant (sets errno to ENOMEM when it
  10 # fails), and replace malloc if it is not.
  11 AC_DEFUN([gl_FUNC_MALLOC_POSIX],
  12 [
  13   AC_CACHE_CHECK([whether malloc, realloc, calloc are POSIX compliant],
  14     [gl_cv_func_malloc_posix],
  15     [
  16       dnl It is too dangerous to try to allocate a large amount of memory:
  17       dnl some systems go to their knees when you do that. So assume that
  18       dnl all Unix implementations of the function are POSIX compliant.
  19       AC_TRY_COMPILE([],
  20         [#if !((defined _WIN32 || defined __WIN32__) && ! defined __CYGWIN__)
  21          choke me
  22          #endif
  23         ], [gl_cv_func_malloc_posix=yes], [gl_cv_func_malloc_posix=no])
  24     ])
  25   if test $gl_cv_func_malloc_posix = yes; then
  26     HAVE_MALLOC_POSIX=1
  27     AC_DEFINE([HAVE_MALLOC_POSIX], 1,
  28       [Define if the 'malloc' function is POSIX compliant.])
  29   else
  30     AC_LIBOBJ([malloc])
  31     HAVE_MALLOC_POSIX=0
  32   fi
  33   AC_SUBST([HAVE_MALLOC_POSIX])
  34 ])