pintos-os.org Git - pspp/blob - m4/isnanl.m4

   1 # isnanl.m4 serial 13
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ISNANL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   ISNANL_LIBM=
  11   gl_HAVE_ISNANL_NO_LIBM
  12   if test $gl_cv_func_isnanl_no_libm = no; then
  13     gl_HAVE_ISNANL_IN_LIBM
  14     if test $gl_cv_func_isnanl_in_libm = yes; then
  15       ISNANL_LIBM=-lm
  16     fi
  17   fi
  18   if test $gl_cv_func_isnanl_no_libm = yes \
  19      || test $gl_cv_func_isnanl_in_libm = yes; then
  20     save_LIBS="$LIBS"
  21     LIBS="$LIBS $ISNANL_LIBM"
  22     gl_FUNC_ISNANL_WORKS
  23     LIBS="$save_LIBS"
  24     case "$gl_cv_func_isnanl_works" in
  25       *yes) gl_func_isnanl=yes ;;
  26       *)    gl_func_isnanl=no; ISNANL_LIBM= ;;
  27     esac
  28   else
  29     gl_func_isnanl=no
  30   fi
  31   if test $gl_func_isnanl != yes; then
  32     HAVE_ISNANL=0
  33     gl_BUILD_ISNANL
  34   fi
  35   AC_SUBST([ISNANL_LIBM])
  36 ])
  37
  38 AC_DEFUN([gl_FUNC_ISNANL_NO_LIBM],
  39 [
  40   gl_HAVE_ISNANL_NO_LIBM
  41   gl_func_isnanl_no_libm=$gl_cv_func_isnanl_no_libm
  42   if test $gl_func_isnanl_no_libm = yes; then
  43     gl_FUNC_ISNANL_WORKS
  44     case "$gl_cv_func_isnanl_works" in
  45       *yes) ;;
  46       *)    gl_func_isnanl_no_libm=no ;;
  47     esac
  48   fi
  49   if test $gl_func_isnanl_no_libm = yes; then
  50     AC_DEFINE([HAVE_ISNANL_IN_LIBC], [1],
  51       [Define if the isnan(long double) function is available in libc.])
  52   else
  53     gl_BUILD_ISNANL
  54   fi
  55 ])
  56
  57 dnl Pull in replacement isnanl definition. It does not need -lm.
  58 AC_DEFUN([gl_BUILD_ISNANL],
  59 [
  60   AC_LIBOBJ([isnanl])
  61   gl_LONG_DOUBLE_EXPONENT_LOCATION
  62 ])
  63
  64 dnl Test whether isnanl() can be used without libm.
  65 AC_DEFUN([gl_HAVE_ISNANL_NO_LIBM],
  66 [
  67   AC_CACHE_CHECK([whether isnan(long double) can be used without linking with libm],
  68     [gl_cv_func_isnanl_no_libm],
  69     [
  70       AC_LINK_IFELSE(
  71         [AC_LANG_PROGRAM(
  72            [[#include <math.h>
  73              #if __GNUC__ >= 4
  74              # undef isnanl
  75              # define isnanl(x) __builtin_isnanl ((long double)(x))
  76              #elif defined isnan
  77              # undef isnanl
  78              # define isnanl(x) isnan ((long double)(x))
  79              #endif
  80              long double x;]],
  81            [[return isnanl (x);]])],
  82         [gl_cv_func_isnanl_no_libm=yes],
  83         [gl_cv_func_isnanl_no_libm=no])
  84     ])
  85 ])
  86
  87 dnl Test whether isnanl() can be used with libm.
  88 AC_DEFUN([gl_HAVE_ISNANL_IN_LIBM],
  89 [
  90   AC_CACHE_CHECK([whether isnan(long double) can be used with libm],
  91     [gl_cv_func_isnanl_in_libm],
  92     [
  93       save_LIBS="$LIBS"
  94       LIBS="$LIBS -lm"
  95       AC_LINK_IFELSE(
  96         [AC_LANG_PROGRAM(
  97            [[#include <math.h>
  98              #if __GNUC__ >= 4
  99              # undef isnanl
 100              # define isnanl(x) __builtin_isnanl ((long double)(x))
 101              #elif defined isnan
 102              # undef isnanl
 103              # define isnanl(x) isnan ((long double)(x))
 104              #endif
 105              long double x;]],
 106            [[return isnanl (x);]])],
 107         [gl_cv_func_isnanl_in_libm=yes],
 108         [gl_cv_func_isnanl_in_libm=no])
 109       LIBS="$save_LIBS"
 110     ])
 111 ])
 112
 113 dnl Test whether isnanl() recognizes all numbers which are neither finite nor
 114 dnl infinite. This test fails e.g. on NetBSD/i386 and on glibc/ia64.
 115 dnl Also, the GCC >= 4.0 built-in __builtin_isnanl does not pass the tests
 116 dnl - for pseudo-denormals on i686 and x86_64,
 117 dnl - for pseudo-zeroes, unnormalized numbers, and pseudo-denormals on ia64.
 118 AC_DEFUN([gl_FUNC_ISNANL_WORKS],
 119 [
 120   AC_REQUIRE([AC_PROG_CC])
 121   AC_REQUIRE([gl_BIGENDIAN])
 122   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 123   AC_CACHE_CHECK([whether isnanl works], [gl_cv_func_isnanl_works],
 124     [
 125       AC_TRY_RUN([
 126 #include <float.h>
 127 #include <limits.h>
 128 #include <math.h>
 129 #if __GNUC__ >= 4
 130 # undef isnanl
 131 # define isnanl(x) __builtin_isnanl ((long double)(x))
 132 #elif defined isnan
 133 # undef isnanl
 134 # define isnanl(x) isnan ((long double)(x))
 135 #endif
 136 #define NWORDS \
 137   ((sizeof (long double) + sizeof (unsigned int) - 1) / sizeof (unsigned int))
 138 typedef union { unsigned int word[NWORDS]; long double value; }
 139         memory_long_double;
 140 /* On Irix 6.5, gcc 3.4.3 can't compute compile-time NaN, and needs the
 141    runtime type conversion.  */
 142 #ifdef __sgi
 143 static long double NaNl ()
 144 {
 145   double zero = 0.0;
 146   return zero / zero;
 147 }
 148 #else
 149 # define NaNl() (0.0L / 0.0L)
 150 #endif
 151 int main ()
 152 {
 153   memory_long_double m;
 154   unsigned int i;
 155
 156   if (!isnanl (NaNl ()))
 157     return 1;
 158
 159   /* The isnanl function should be immune against changes in the sign bit and
 160      in the mantissa bits.  The xor operation twiddles a bit that can only be
 161      a sign bit or a mantissa bit (since the exponent never extends to
 162      bit 31).  */
 163   m.value = NaNl ();
 164   m.word[NWORDS / 2] ^= (unsigned int) 1 << (sizeof (unsigned int) * CHAR_BIT - 1);
 165   for (i = 0; i < NWORDS; i++)
 166     m.word[i] |= 1;
 167   if (!isnanl (m.value))
 168     return 1;
 169
 170 #if ((defined __ia64 && LDBL_MANT_DIG == 64) || (defined __x86_64__ || defined __amd64__) || (defined __i386 || defined __i386__ || defined _I386 || defined _M_IX86 || defined _X86_))
 171 /* Representation of an 80-bit 'long double' as an initializer for a sequence
 172    of 'unsigned int' words.  */
 173 # ifdef WORDS_BIGENDIAN
 174 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
 175      { ((unsigned int) (exponent) << 16) | ((unsigned int) (manthi) >> 16), \
 176        ((unsigned int) (manthi) << 16) | (unsigned int) (mantlo) >> 16),    \
 177        (unsigned int) (mantlo) << 16                                        \
 178      }
 179 # else
 180 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
 181      { mantlo, manthi, exponent }
 182 # endif
 183   { /* Quiet NaN.  */
 184     static memory_long_double x =
 185       { LDBL80_WORDS (0xFFFF, 0xC3333333, 0x00000000) };
 186     if (!isnanl (x.value))
 187       return 1;
 188   }
 189   {
 190     /* Signalling NaN.  */
 191     static memory_long_double x =
 192       { LDBL80_WORDS (0xFFFF, 0x83333333, 0x00000000) };
 193     if (!isnanl (x.value))
 194       return 1;
 195   }
 196   /* The isnanl function should recognize Pseudo-NaNs, Pseudo-Infinities,
 197      Pseudo-Zeroes, Unnormalized Numbers, and Pseudo-Denormals, as defined in
 198        Intel IA-64 Architecture Software Developer's Manual, Volume 1:
 199        Application Architecture.
 200        Table 5-2 "Floating-Point Register Encodings"
 201        Figure 5-6 "Memory to Floating-Point Register Data Translation"
 202    */
 203   { /* Pseudo-NaN.  */
 204     static memory_long_double x =
 205       { LDBL80_WORDS (0xFFFF, 0x40000001, 0x00000000) };
 206     if (!isnanl (x.value))
 207       return 1;
 208   }
 209   { /* Pseudo-Infinity.  */
 210     static memory_long_double x =
 211       { LDBL80_WORDS (0xFFFF, 0x00000000, 0x00000000) };
 212     if (!isnanl (x.value))
 213       return 1;
 214   }
 215   { /* Pseudo-Zero.  */
 216     static memory_long_double x =
 217       { LDBL80_WORDS (0x4004, 0x00000000, 0x00000000) };
 218     if (!isnanl (x.value))
 219       return 1;
 220   }
 221   { /* Unnormalized number.  */
 222     static memory_long_double x =
 223       { LDBL80_WORDS (0x4000, 0x63333333, 0x00000000) };
 224     if (!isnanl (x.value))
 225       return 1;
 226   }
 227   { /* Pseudo-Denormal.  */
 228     static memory_long_double x =
 229       { LDBL80_WORDS (0x0000, 0x83333333, 0x00000000) };
 230     if (!isnanl (x.value))
 231       return 1;
 232   }
 233 #endif
 234
 235   return 0;
 236 }], [gl_cv_func_isnanl_works=yes], [gl_cv_func_isnanl_works=no],
 237       [case "$host_cpu" in
 238                                # Guess no on ia64, x86_64, i386.
 239          ia64 | x86_64 | i*86) gl_cv_func_isnanl_works="guessing no";;
 240          *)
 241            case "$host_os" in
 242              netbsd*) gl_cv_func_isnanl_works="guessing no";;
 243              *)       gl_cv_func_isnanl_works="guessing yes";;
 244            esac
 245            ;;
 246        esac
 247       ])
 248     ])
 249 ])