pintos-os.org Git - pspp/blob - m4/getopt.m4

   1 # getopt.m4 serial 9
   2 dnl Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # The getopt module assume you want GNU getopt, with getopt_long etc,
   8 # rather than vanilla POSIX getopt.  This means your your code should
   9 # always include <getopt.h> for the getopt prototypes.
  10
  11 AC_DEFUN([gl_GETOPT_SUBSTITUTE],
  12 [
  13   GETOPT_H=getopt.h
  14   AC_LIBOBJ([getopt])
  15   AC_LIBOBJ([getopt1])
  16   AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
  17     [Define to rpl_ if the getopt replacement functions and variables
  18      should be used.])
  19   AC_SUBST([GETOPT_H])
  20 ])
  21
  22 AC_DEFUN([gl_GETOPT],
  23 [
  24   gl_PREREQ_GETOPT
  25
  26   if test -z "$GETOPT_H"; then
  27     GETOPT_H=
  28     AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  29     if test -z "$GETOPT_H"; then
  30       AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  31     fi
  32
  33     dnl BSD getopt_long uses an incompatible method to reset option processing,
  34     dnl and (as of 2004-10-15) mishandles optional option-arguments.
  35     if test -z "$GETOPT_H"; then
  36       AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  37     fi
  38
  39     dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  40     dnl option string (as of 2005-05-05).
  41     if test -z "$GETOPT_H"; then
  42       AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
  43       [AC_RUN_IFELSE(
  44         [AC_LANG_PROGRAM([#include <getopt.h>],
  45            [[
  46              char *myargv[3];
  47              myargv[0] = "conftest";
  48              myargv[1] = "-+";
  49              myargv[2] = 0;
  50              return getopt (2, myargv, "+a") != '?';
  51            ]])],
  52         [gl_cv_func_gnu_getopt=yes],
  53         [gl_cv_func_gnu_getopt=no],
  54         [dnl cross compiling - pessimistically guess based on decls
  55          dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  56          dnl option string (as of 2005-05-05).
  57          AC_CHECK_DECL([getopt_clip],
  58            [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
  59            [#include <getopt.h>])])])
  60       if test "$gl_cv_func_gnu_getopt" = "no"; then
  61         GETOPT_H=getopt.h
  62       fi
  63     fi
  64
  65     if test -n "$GETOPT_H"; then
  66       gl_GETOPT_SUBSTITUTE
  67     fi
  68   fi
  69 ])
  70
  71 # Prerequisites of lib/getopt*.
  72 AC_DEFUN([gl_PREREQ_GETOPT], [:])