pintos-os.org Git - pspp/blob - m4/fsusage.m4

   1 # serial 29
   2 # Obtaining file system usage information.
   3
   4 # Copyright (C) 1997-1998, 2000-2001, 2003-2011 Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 # Written by Jim Meyering.
  11
  12 AC_DEFUN([gl_FSUSAGE],
  13 [
  14   AC_CHECK_HEADERS_ONCE([sys/param.h])
  15   AC_CHECK_HEADERS_ONCE([sys/vfs.h sys/fs_types.h])
  16   AC_CHECK_HEADERS([sys/mount.h], [], [],
  17     [AC_INCLUDES_DEFAULT
  18      [#if HAVE_SYS_PARAM_H
  19        #include <sys/param.h>
  20       #endif]])
  21   gl_FILE_SYSTEM_USAGE([gl_cv_fs_space=yes], [gl_cv_fs_space=no])
  22 ])
  23
  24 # Try to determine how a program can obtain file system usage information.
  25 # If successful, define the appropriate symbol (see fsusage.c) and
  26 # execute ACTION-IF-FOUND.  Otherwise, execute ACTION-IF-NOT-FOUND.
  27 #
  28 # gl_FILE_SYSTEM_USAGE([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  29
  30 AC_DEFUN([gl_FILE_SYSTEM_USAGE],
  31 [
  32 dnl Enable large-file support. This has the effect of changing the size
  33 dnl of field f_blocks in 'struct statvfs' from 32 bit to 64 bit on
  34 dnl glibc/Hurd, HP-UX 11, Solaris (32-bit mode). It also changes the size
  35 dnl of field f_blocks in 'struct statfs' from 32 bit to 64 bit on
  36 dnl MacOS X >= 10.5 (32-bit mode).
  37 AC_REQUIRE([AC_SYS_LARGEFILE])
  38
  39 AC_MSG_NOTICE([checking how to get file system space usage])
  40 ac_fsusage_space=no
  41
  42 # Perform only the link test since it seems there are no variants of the
  43 # statvfs function.  This check is more than just AC_CHECK_FUNCS([statvfs])
  44 # because that got a false positive on SCO OSR5.  Adding the declaration
  45 # of a `struct statvfs' causes this test to fail (as it should) on such
  46 # systems.  That system is reported to work fine with STAT_STATFS4 which
  47 # is what it gets when this test fails.
  48 if test $ac_fsusage_space = no; then
  49   # glibc/{Hurd,kFreeBSD}, FreeBSD >= 5.0, NetBSD >= 3.0,
  50   # OpenBSD >= 4.4, AIX, HP-UX, IRIX, Solaris, Cygwin, Interix, BeOS.
  51   AC_CACHE_CHECK([for statvfs function (SVR4)], [fu_cv_sys_stat_statvfs],
  52                  [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
  53 #if (defined __GLIBC__ || defined __UCLIBC__) && defined __linux__
  54 Do not use statvfs on systems with GNU libc on Linux, because that function
  55 stats all preceding entries in /proc/mounts, and that makes df hang if even
  56 one of the corresponding file systems is hard-mounted, but not available.
  57 statvfs in GNU libc on Hurd, BeOS, Haiku operates differently: it only makes
  58 a system call.
  59 #endif
  60
  61 #ifdef __osf__
  62 "Do not use Tru64's statvfs implementation"
  63 #endif
  64
  65 #include <sys/statvfs.h>
  66
  67 struct statvfs fsd;
  68
  69 #if defined __APPLE__ && defined __MACH__
  70 #include <limits.h>
  71 /* On MacOS X >= 10.5, f_blocks in 'struct statvfs' is a 32-bit quantity;
  72    that commonly limits file systems to 4 TiB.  Whereas f_blocks in
  73    'struct statfs' is a 64-bit type, thanks to the large-file support
  74    that was enabled above.  In this case, don't use statvfs(); use statfs()
  75    instead.  */
  76 int check_f_blocks_size[sizeof fsd.f_blocks * CHAR_BIT <= 32 ? -1 : 1];
  77 #endif
  78 ]],
  79                                     [[statvfs (0, &fsd);]])],
  80                                  [fu_cv_sys_stat_statvfs=yes],
  81                                  [fu_cv_sys_stat_statvfs=no])])
  82   if test $fu_cv_sys_stat_statvfs = yes; then
  83     ac_fsusage_space=yes
  84     AC_DEFINE([STAT_STATVFS], [1],
  85               [  Define if there is a function named statvfs.  (SVR4)])
  86   fi
  87 fi
  88
  89 if test $ac_fsusage_space = no; then
  90   # DEC Alpha running OSF/1
  91   AC_MSG_CHECKING([for 3-argument statfs function (DEC OSF/1)])
  92   AC_CACHE_VAL([fu_cv_sys_stat_statfs3_osf1],
  93   [AC_RUN_IFELSE([AC_LANG_SOURCE([[
  94 #include <sys/param.h>
  95 #include <sys/types.h>
  96 #include <sys/mount.h>
  97   int
  98   main ()
  99   {
 100     struct statfs fsd;
 101     fsd.f_fsize = 0;
 102     return statfs (".", &fsd, sizeof (struct statfs)) != 0;
 103   }]])],
 104     [fu_cv_sys_stat_statfs3_osf1=yes],
 105     [fu_cv_sys_stat_statfs3_osf1=no],
 106     [fu_cv_sys_stat_statfs3_osf1=no])])
 107   AC_MSG_RESULT([$fu_cv_sys_stat_statfs3_osf1])
 108   if test $fu_cv_sys_stat_statfs3_osf1 = yes; then
 109     ac_fsusage_space=yes
 110     AC_DEFINE([STAT_STATFS3_OSF1], [1],
 111               [   Define if  statfs takes 3 args.  (DEC Alpha running OSF/1)])
 112   fi
 113 fi
 114
 115 if test $ac_fsusage_space = no; then
 116   # glibc/Linux, MacOS X, FreeBSD < 5.0, NetBSD < 3.0, OpenBSD < 4.4.
 117   # (glibc/{Hurd,kFreeBSD}, FreeBSD >= 5.0, NetBSD >= 3.0,
 118   # OpenBSD >= 4.4, AIX, HP-UX, OSF/1, Cygwin already handled above.)
 119   # (On IRIX you need to include <sys/statfs.h>, not only <sys/mount.h> and
 120   # <sys/vfs.h>.)
 121   # (On Solaris, statfs has 4 arguments.)
 122   AC_MSG_CHECKING([for two-argument statfs with statfs.f_bsize dnl
 123 member (AIX, 4.3BSD)])
 124   AC_CACHE_VAL([fu_cv_sys_stat_statfs2_bsize],
 125   [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 126 #ifdef HAVE_SYS_PARAM_H
 127 #include <sys/param.h>
 128 #endif
 129 #ifdef HAVE_SYS_MOUNT_H
 130 #include <sys/mount.h>
 131 #endif
 132 #ifdef HAVE_SYS_VFS_H
 133 #include <sys/vfs.h>
 134 #endif
 135   int
 136   main ()
 137   {
 138   struct statfs fsd;
 139   fsd.f_bsize = 0;
 140   return statfs (".", &fsd) != 0;
 141   }]])],
 142     [fu_cv_sys_stat_statfs2_bsize=yes],
 143     [fu_cv_sys_stat_statfs2_bsize=no],
 144     [fu_cv_sys_stat_statfs2_bsize=no])])
 145   AC_MSG_RESULT([$fu_cv_sys_stat_statfs2_bsize])
 146   if test $fu_cv_sys_stat_statfs2_bsize = yes; then
 147     ac_fsusage_space=yes
 148     AC_DEFINE([STAT_STATFS2_BSIZE], [1],
 149 [  Define if statfs takes 2 args and struct statfs has a field named f_bsize.
 150    (4.3BSD, SunOS 4, HP-UX, AIX PS/2)])
 151   fi
 152 fi
 153
 154 if test $ac_fsusage_space = no; then
 155   # SVR3
 156   # (Solaris already handled above.)
 157   AC_MSG_CHECKING([for four-argument statfs (AIX-3.2.5, SVR3)])
 158   AC_CACHE_VAL([fu_cv_sys_stat_statfs4],
 159   [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 160 #include <sys/types.h>
 161 #include <sys/statfs.h>
 162   int
 163   main ()
 164   {
 165   struct statfs fsd;
 166   return statfs (".", &fsd, sizeof fsd, 0) != 0;
 167   }]])],
 168     [fu_cv_sys_stat_statfs4=yes],
 169     [fu_cv_sys_stat_statfs4=no],
 170     [fu_cv_sys_stat_statfs4=no])])
 171   AC_MSG_RESULT([$fu_cv_sys_stat_statfs4])
 172   if test $fu_cv_sys_stat_statfs4 = yes; then
 173     ac_fsusage_space=yes
 174     AC_DEFINE([STAT_STATFS4], [1],
 175       [  Define if statfs takes 4 args.  (SVR3, Dynix, old Irix, old AIX, Dolphin)])
 176   fi
 177 fi
 178
 179 if test $ac_fsusage_space = no; then
 180   # 4.4BSD and older NetBSD
 181   # (OSF/1 already handled above.)
 182   # (On AIX, you need to include <sys/statfs.h>, not only <sys/mount.h>.)
 183   # (On Solaris, statfs has 4 arguments and 'struct statfs' is not declared in
 184   # <sys/mount.h>.)
 185   AC_MSG_CHECKING([for two-argument statfs with statfs.f_fsize dnl
 186 member (4.4BSD and NetBSD)])
 187   AC_CACHE_VAL([fu_cv_sys_stat_statfs2_fsize],
 188   [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 189 #include <sys/types.h>
 190 #ifdef HAVE_SYS_PARAM_H
 191 #include <sys/param.h>
 192 #endif
 193 #ifdef HAVE_SYS_MOUNT_H
 194 #include <sys/mount.h>
 195 #endif
 196   int
 197   main ()
 198   {
 199   struct statfs fsd;
 200   fsd.f_fsize = 0;
 201   return statfs (".", &fsd) != 0;
 202   }]])],
 203     [fu_cv_sys_stat_statfs2_fsize=yes],
 204     [fu_cv_sys_stat_statfs2_fsize=no],
 205     [fu_cv_sys_stat_statfs2_fsize=no])])
 206   AC_MSG_RESULT([$fu_cv_sys_stat_statfs2_fsize])
 207   if test $fu_cv_sys_stat_statfs2_fsize = yes; then
 208     ac_fsusage_space=yes
 209     AC_DEFINE([STAT_STATFS2_FSIZE], [1],
 210 [  Define if statfs takes 2 args and struct statfs has a field named f_fsize.
 211    (4.4BSD, NetBSD)])
 212   fi
 213 fi
 214
 215 if test $ac_fsusage_space = no; then
 216   # Ultrix
 217   AC_MSG_CHECKING([for two-argument statfs with struct fs_data (Ultrix)])
 218   AC_CACHE_VAL([fu_cv_sys_stat_fs_data],
 219   [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 220 #include <sys/types.h>
 221 #ifdef HAVE_SYS_PARAM_H
 222 #include <sys/param.h>
 223 #endif
 224 #ifdef HAVE_SYS_MOUNT_H
 225 #include <sys/mount.h>
 226 #endif
 227 #ifdef HAVE_SYS_FS_TYPES_H
 228 #include <sys/fs_types.h>
 229 #endif
 230   int
 231   main ()
 232   {
 233   struct fs_data fsd;
 234   /* Ultrix's statfs returns 1 for success,
 235      0 for not mounted, -1 for failure.  */
 236   return statfs (".", &fsd) != 1;
 237   }]])],
 238     [fu_cv_sys_stat_fs_data=yes],
 239     [fu_cv_sys_stat_fs_data=no],
 240     [fu_cv_sys_stat_fs_data=no])])
 241   AC_MSG_RESULT([$fu_cv_sys_stat_fs_data])
 242   if test $fu_cv_sys_stat_fs_data = yes; then
 243     ac_fsusage_space=yes
 244     AC_DEFINE([STAT_STATFS2_FS_DATA], [1],
 245 [  Define if statfs takes 2 args and the second argument has
 246    type struct fs_data.  (Ultrix)])
 247   fi
 248 fi
 249
 250 if test $ac_fsusage_space = no; then
 251   # SVR2
 252   # (AIX, HP-UX, OSF/1 already handled above.)
 253   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <sys/filsys.h>
 254         ]])],
 255     [AC_DEFINE([STAT_READ_FILSYS], [1],
 256       [Define if there is no specific function for reading file systems usage
 257        information and you have the <sys/filsys.h> header file.  (SVR2)])
 258      ac_fsusage_space=yes])
 259 fi
 260
 261 AS_IF([test $ac_fsusage_space = yes], [$1], [$2])
 262
 263 ])
 264
 265
 266 # Check for SunOS statfs brokenness wrt partitions 2GB and larger.
 267 # If <sys/vfs.h> exists and struct statfs has a member named f_spare,
 268 # enable the work-around code in fsusage.c.
 269 AC_DEFUN([gl_STATFS_TRUNCATES],
 270 [
 271   AC_MSG_CHECKING([for statfs that truncates block counts])
 272   AC_CACHE_VAL([fu_cv_sys_truncating_statfs],
 273   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 274 #if !defined(sun) && !defined(__sun)
 275 choke -- this is a workaround for a Sun-specific problem
 276 #endif
 277 #include <sys/types.h>
 278 #include <sys/vfs.h>]],
 279       [[struct statfs t; long c = *(t.f_spare);
 280         if (c) return 0;]])],
 281     [fu_cv_sys_truncating_statfs=yes],
 282     [fu_cv_sys_truncating_statfs=no])])
 283   if test $fu_cv_sys_truncating_statfs = yes; then
 284     AC_DEFINE([STATFS_TRUNCATES_BLOCK_COUNTS], [1],
 285       [Define if the block counts reported by statfs may be truncated to 2GB
 286        and the correct values may be stored in the f_spare array.
 287        (SunOS 4.1.2, 4.1.3, and 4.1.3_U1 are reported to have this problem.
 288        SunOS 4.1.1 seems not to be affected.)])
 289   fi
 290   AC_MSG_RESULT([$fu_cv_sys_truncating_statfs])
 291 ])
 292
 293
 294 # Prerequisites of lib/fsusage.c not done by gl_FILE_SYSTEM_USAGE.
 295 AC_DEFUN([gl_PREREQ_FSUSAGE_EXTRA],
 296 [
 297   AC_CHECK_HEADERS([dustat.h sys/fs/s5param.h sys/filsys.h sys/statfs.h])
 298   gl_STATFS_TRUNCATES
 299 ])