pintos-os.org Git - pspp/blob - m4/floorl.m4

   1 # floorl.m4 serial 2
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FLOORL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare floorl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   dnl Test whether floorl() is declared.
  13   AC_CHECK_DECLS([floorl], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_floorl" = yes; then
  15     dnl Test whether floorl() can be used without libm.
  16     gl_FUNC_FLOORL_LIBS
  17     if test "$FLOORL_LIBM" = "?"; then
  18       FLOORL_LIBM=
  19     fi
  20   else
  21     HAVE_DECL_FLOORL=0
  22     AC_LIBOBJ([floorl])
  23     FLOORL_LIBM=
  24   fi
  25   AC_SUBST([HAVE_DECL_FLOORL])
  26   AC_SUBST([FLOORL_LIBM])
  27 ])
  28
  29 # Determines the libraries needed to get the floorl() function.
  30 # Sets FLOORL_LIBM.
  31 AC_DEFUN([gl_FUNC_FLOORL_LIBS],
  32 [
  33   AC_CACHE_VAL([gl_func_floorl_libm], [
  34     gl_func_floorl_libm=?
  35     AC_TRY_LINK([
  36        #ifndef __NO_MATH_INLINES
  37        # define __NO_MATH_INLINES 1 /* for glibc */
  38        #endif
  39        #include <math.h>
  40        long double x;],
  41       [x = floorl(x);],
  42       [gl_func_floorl_libm=])
  43     if test "$gl_func_floorl_libm" = "?"; then
  44       save_LIBS="$LIBS"
  45       LIBS="$LIBS -lm"
  46       AC_TRY_LINK([
  47          #ifndef __NO_MATH_INLINES
  48          # define __NO_MATH_INLINES 1 /* for glibc */
  49          #endif
  50          #include <math.h>
  51          long double x;],
  52         [x = floorl(x);],
  53         [gl_func_floorl_libm="-lm"])
  54       LIBS="$save_LIBS"
  55     fi
  56   ])
  57   FLOORL_LIBM="$gl_func_floorl_libm"
  58 ])