pintos-os.org Git - pspp/blob - m4/acosl.m4

   1 # acosl.m4 serial 4
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ACOSL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare acosl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   ACOSL_LIBM=
  14   AC_CACHE_CHECK([whether acosl() can be used without linking with libm],
  15     [gl_cv_func_acosl_no_libm],
  16     [
  17       AC_LINK_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#ifndef __NO_MATH_INLINES
  20              # define __NO_MATH_INLINES 1 /* for glibc */
  21              #endif
  22              #include <math.h>
  23              long double x;]],
  24            [[return acosl (x) > 1;]])],
  25         [gl_cv_func_acosl_no_libm=yes],
  26         [gl_cv_func_acosl_no_libm=no])
  27     ])
  28   if test $gl_cv_func_acosl_no_libm = no; then
  29     AC_CACHE_CHECK([whether acosl() can be used with libm],
  30       [gl_cv_func_acosl_in_libm],
  31       [
  32         save_LIBS="$LIBS"
  33         LIBS="$LIBS -lm"
  34         AC_LINK_IFELSE(
  35           [AC_LANG_PROGRAM(
  36              [[#ifndef __NO_MATH_INLINES
  37                # define __NO_MATH_INLINES 1 /* for glibc */
  38                #endif
  39                #include <math.h>
  40                long double x;]],
  41              [[return acosl (x) > 1;]])],
  42           [gl_cv_func_acosl_in_libm=yes],
  43           [gl_cv_func_acosl_in_libm=no])
  44         LIBS="$save_LIBS"
  45       ])
  46     if test $gl_cv_func_acosl_in_libm = yes; then
  47       ACOSL_LIBM=-lm
  48     fi
  49   fi
  50   if test $gl_cv_func_acosl_no_libm = yes \
  51      || test $gl_cv_func_acosl_in_libm = yes; then
  52     dnl Also check whether it's declared.
  53     dnl MacOS X 10.3 has acosl() in libc but doesn't declare it in <math.h>.
  54     AC_CHECK_DECL([acosl], , [HAVE_DECL_ACOSL=0], [#include <math.h>])
  55   else
  56     HAVE_DECL_ACOSL=0
  57     HAVE_ACOSL=0
  58     dnl Find libraries needed to link lib/acosl.c.
  59     AC_REQUIRE([gl_FUNC_ASINL])
  60     AC_REQUIRE([gl_FUNC_SQRTL])
  61     dnl Append $ASINL_LIBM to ACOSL_LIBM, avoiding gratuitous duplicates.
  62     case " $ACOSL_LIBM " in
  63       *" $ASINL_LIBM "*) ;;
  64       *) ACOSL_LIBM="$ACOSL_LIBM $ASINL_LIBM" ;;
  65     esac
  66     dnl Append $SQRTL_LIBM to ACOSL_LIBM, avoiding gratuitous duplicates.
  67     case " $ACOSL_LIBM " in
  68       *" $SQRTL_LIBM "*) ;;
  69       *) ACOSL_LIBM="$ACOSL_LIBM $SQRTL_LIBM" ;;
  70     esac
  71   fi
  72   AC_SUBST([ACOSL_LIBM])
  73 ])