configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LIBPLOT
  40 PSPP_LC_PAPER
  41 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  42
  43
  44 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  45 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  46
  47
  48 AC_ARG_WITH(
  49   gui,
  50   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  51
  52 required_gtk_version=2.12
  53
  54 if test x"$with_gui" != x"no" ; then
  55   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  56     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  57   PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0,,
  58     [PSPP_REQUIRED_PREREQ([libglade 2.0 v2.6.0 or later (or use --without-gui)])])
  59 fi
  60 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  61
  62
  63 dnl Checks needed for psql reader
  64
  65 dnl The 8.x series postgres tarballs installs with a default prefix of
  66 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  67
  68 dnl If the libpq.so file is in a non standard path, (one which the linker
  69 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  70 dnl However, if the system happens to have more than one version of other
  71 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  72 dnl /usr and /usr/local) then the wrong one may get linked.
  73
  74 dnl To overcome this, we first check for libpq in the standard places, and
  75 dnl only set PG_LDFLAGS if it's not found.
  76
  77
  78 AC_ARG_WITH(
  79   libpq,
  80   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  81
  82 if test x"$with_libpq" != x"no" ; then
  83  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  84
  85  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  86  if test x"$cross_compiling" != x"yes" ; then
  87    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  88  fi
  89  if test -n "$PG_CONFIG" ; then
  90    AC_SUBST(PG_CONFIG)
  91    AC_DEFINE([PSQL_SUPPORT], 1,
  92    [Define to 1 if building in support for reading from postgres databases.])
  93    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  94    AC_SUBST(PG_CFLAGS)
  95
  96    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  97       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
  98    fi
  99    AC_SUBST(PG_LDFLAGS)
 100
 101    PG_LIBS=-lpq
 102    AC_SUBST(PG_LIBS)
 103    PKG_CHECK_EXISTS(libssl,
 104          AC_DEFINE([USE_SSL],1,
 105                     [Define to 1 if the openssl library is present.])
 106             ,)
 107  fi
 108 fi
 109 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 110
 111 dnl Checks needed for gnumeric reader
 112 gnm_support=yes;
 113 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 114                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 115 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 116 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 117
 118 if test x"$gnm_support" = x"yes" ; then
 119    AC_DEFINE([GNM_SUPPORT], 1,
 120    [Define to 1 if building in support for reading Gnumeric files.])
 121 fi
 122 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 123
 124 AC_ARG_WITH(
 125   gui_tools,
 126   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 127 if test x"$with_gui_tools" = x"yes" ; then
 128         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 129 fi
 130 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 131
 132 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 133
 134 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 135 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 136 PSPP_GSL_NEEDS_FGNU89_INLINE
 137
 138 dnl Recent versions of GNU ncurses install the curses header files into
 139 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 140 dnl enables us to discover where they are. Earlier versions don't have
 141 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 142 dnl we'll trust it to find the right information.  Otherwise, we'll
 143 dnl try to discover it ourselves.
 144 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 145 dnl to ncurses8-config !!!
 146 AC_ARG_WITH(
 147   libncurses,
 148   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 149
 150 if test x"$with_libncurses" != x"no" ; then
 151   if test x"$cross_compiling" != x"yes" ; then
 152           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 153   fi
 154   if test x"$NCURSES_CONFIG" = x ; then
 155           AC_SEARCH_LIBS([tgetent], [ncurses],
 156               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 157   else
 158           old_cflags=$CFLAGS
 159           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 160           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 161           CFLAGS=$old_cflags
 162           if test x"$curses_available" = x"yes" ; then
 163            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 164            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 165            AC_SUBST(NCURSES_CFLAGS)
 166            AC_SUBST(NCURSES_LIBS)
 167           fi
 168   fi
 169   if test x"$curses_available" = x"yes" ; then
 170           AC_DEFINE([LIBNCURSES_USABLE], 1,
 171               [Define to 1 if the libncurses is both present and usable.])
 172   fi
 173   AC_CHECK_HEADERS([termcap.h])
 174 fi
 175
 176 PSPP_READLINE
 177
 178 dnl Checks for header files.
 179 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 180
 181 # For gnulib.
 182 gl_INIT
 183
 184 AC_C_INLINE
 185
 186 AC_CHECK_SIZEOF(double)
 187
 188 AC_C_BIGENDIAN
 189
 190 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 191
 192 AC_PROG_LN_S
 193
 194 AC_ARG_ENABLE(
 195   debug,
 196   [AS_HELP_STRING([--enable-debug],
 197                   [Turn on diagnostic features in the program])])
 198 if test x"$enable_debug" = x"yes"  ; then
 199   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 200 fi
 201
 202 # iconv is required
 203 if test "$am_cv_func_iconv" != "yes"; then
 204    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 205 fi
 206
 207 PSPP_CHECK_PREREQS
 208
 209 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 210
 211 AC_OUTPUT
 212 echo "PSPP configured successfully."
 213
 214 dnl configure.ac ends here