pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.6], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Internationalization macros.
  36 AC_PROVIDE([AM_PO_SUBDIRS])     # PSPP provides its own po/ support.
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 AM_GNU_GETTEXT_VERSION([0.17])
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  77     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  78
  79   AC_ARG_VAR([GLIB_GENMARSHAL])
  80   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  81   if test "x$GLIB_GENMARSHAL" = x; then
  82     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  83   fi
  84 fi
  85
  86 dnl Checks needed for psql reader
  87
  88 dnl The 8.x series postgres tarballs installs with a default prefix of
  89 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  90
  91 dnl If the libpq.so file is in a non standard path, (one which the linker
  92 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  93 dnl However, if the system happens to have more than one version of other
  94 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  95 dnl /usr and /usr/local) then the wrong one may get linked.
  96
  97 dnl To overcome this, we first check for libpq in the standard places, and
  98 dnl only set PG_LDFLAGS if it's not found.
  99
 100
 101 AC_ARG_WITH(
 102   libpq,
 103   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 104 AC_ARG_VAR([PG_CONFIG],
 105            [Full pathname of the pg_config program shipped with Postgresql])
 106 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 107              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 108
 109 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 110   AC_SUBST(PG_CONFIG)
 111   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 112   AC_SUBST(PG_CFLAGS)
 113
 114   AC_CHECK_LIB([pq], [PQexec],
 115      [:],
 116      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 117   AC_SUBST(PG_LDFLAGS)
 118
 119   PG_LIBS=-lpq
 120   AC_SUBST(PG_LIBS)
 121
 122   PKG_CHECK_EXISTS(libssl,
 123         AC_DEFINE([USE_SSL],1,
 124                    [Define to 1 if the openssl library is present.])
 125            ,)
 126
 127   # Now verify that we can actually link against libpq.  If we are
 128   # cross-compiling and picked up a host libpq, or if libpq is just
 129   # badly installed, this will fail.
 130   AC_CACHE_CHECK(
 131     [whether -lpq links successfully],
 132     [pspp_cv_have_libpq],
 133     [save_CPPFLAGS=$CPPFLAGS
 134      save_LIBS=$LIBS
 135      save_LDFLAGS=$LDFLAGS
 136      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 137      LIBS="$PG_LIBS $LIBS"
 138      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 139      AC_LINK_IFELSE(
 140        [AC_LANG_PROGRAM(
 141          [#include <libpq-fe.h>
 142          ], [PQfinish (0);])],
 143        [pspp_cv_have_libpq=yes],
 144        [pspp_cv_have_libpq=no])
 145      CPPFLAGS=$save_CPPFLAGS
 146      LIBS=$save_LIBS
 147      LDFLAGS=$save_LDFLAGS])
 148
 149   if test $pspp_cv_have_libpq = yes; then
 150     PSQL_SUPPORT=yes
 151     AC_DEFINE([PSQL_SUPPORT], [1],
 152       [Define to 1 if building in support for reading from postgres
 153        databases.])
 154   else
 155     PSQL_SUPPORT=no
 156     PG_CONFIG=
 157     PG_CFLAGS=
 158     PG_LDFLAGS=
 159     PG_LIBS=
 160   fi
 161 else
 162   PSQL_SUPPORT=no
 163   pspp_cv_have_libpq=no
 164 fi
 165 AC_SUBST([PSQL_SUPPORT])
 166
 167 dnl Check for libxml2
 168 PKG_CHECK_MODULES(
 169   [LIBXML2], [libxml-2.0],
 170   [HAVE_LIBXML2=yes],
 171   [HAVE_LIBXML2=no
 172    PSPP_OPTIONAL_PREREQ([libxml2])])
 173
 174 dnl Check for zlib.
 175 AC_SEARCH_LIBS(
 176   [gzopen], [z],
 177   [HAVE_ZLIB=yes],
 178   [HAVE_ZLIB=no
 179    PSPP_OPTIONAL_PREREQ([zlib])])
 180 AC_CHECK_HEADERS(
 181   [zlib.h],
 182   [],
 183   [HAVE_ZLIB=no
 184    PSPP_OPTIONAL_PREREQ([zlib])])
 185
 186 dnl Avoid interference between zlib's crc32() function and gnulib's
 187 dnl crc32() function, which have different signatures.  PSPP calls
 188 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 189 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 190 dnl crc32(), then zlib will call gnulib's version instead of its own,
 191 dnl causing failures.  (This can happen even if zlib isn't detected
 192 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 193 dnl sometimes use zlib themselves.)
 194 AC_DEFINE(
 195   [crc32], [gl_crc32],
 196   [Avoid making zlib call gnulib's crc32() instead of its own.])
 197
 198 dnl Gnumeric support requires libxml2 and zlib.
 199 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 200   GNM_SUPPORT=yes
 201   AC_DEFINE(
 202     [GNM_SUPPORT], [1],
 203     [Define to 1 if building in support for reading Gnumeric files.])
 204 else
 205   GNM_SUPPORT=no
 206 fi
 207 AC_SUBST([GNM_SUPPORT])
 208
 209 dnl ODT support requires libxml2.
 210 if test $HAVE_LIBXML2 = yes; then
 211   AC_DEFINE(
 212     [ODT_SUPPORT], [1],
 213     [Define to 1 if building in support for writing ODT files.])
 214 fi
 215 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 216
 217 AC_ARG_WITH(
 218   gui_tools,
 219   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 220 if test x"$with_gui_tools" = x"yes" ; then
 221         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 222 fi
 223 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 224
 225 AC_ARG_WITH(
 226   [perl-module],
 227   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 228   [case $with_perl_module in # (
 229      yes|no) ;; # (
 230      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 231    esac
 232    WITH_PERL_MODULE=$with_perl_module],
 233   [if test x"$cross_compiling" != x"yes"; then
 234      WITH_PERL_MODULE=yes
 235    else
 236      WITH_PERL_MODULE=no
 237    fi])
 238 AC_SUBST([WITH_PERL_MODULE])
 239 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 240
 241 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 242 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 243                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 244
 245
 246 PSPP_GSL_NEEDS_FGNU89_INLINE
 247
 248 dnl Recent versions of GNU ncurses install the curses header files into
 249 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 250 dnl enables us to discover where they are. Earlier versions don't have
 251 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 252 dnl we'll trust it to find the right information.  Otherwise, we'll
 253 dnl try to discover it ourselves.
 254 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 255 dnl to ncurses8-config !!!
 256 AC_ARG_WITH(
 257   libncurses,
 258   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 259
 260 if test x"$with_libncurses" != x"no" ; then
 261   if test x"$cross_compiling" != x"yes" ; then
 262           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 263   fi
 264   if test x"$NCURSES_CONFIG" = x ; then
 265           AC_SEARCH_LIBS([tgetent], [ncurses],
 266               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 267   else
 268           old_cflags=$CFLAGS
 269           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 270           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 271           CFLAGS=$old_cflags
 272           if test x"$curses_available" = x"yes" ; then
 273            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 274            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 275            AC_SUBST(NCURSES_CFLAGS)
 276            AC_SUBST(NCURSES_LIBS)
 277           fi
 278   fi
 279   if test x"$curses_available" = x"yes" ; then
 280           AC_DEFINE([LIBNCURSES_USABLE], 1,
 281               [Define to 1 if the libncurses is both present and usable.])
 282   fi
 283   AC_CHECK_HEADERS([termcap.h])
 284 fi
 285
 286 PSPP_READLINE
 287
 288 dnl Checks for header files.
 289 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 290
 291 dnl Some systems dont have SIGWINCH
 292 AC_CHECK_DECLS([SIGWINCH], [], [],
 293           [#include <signal.h>
 294           /* NetBSD declares sys_siglist in unistd.h.  */
 295           #ifdef HAVE_UNISTD_H
 296           # include <unistd.h>
 297           #endif
 298           ])
 299
 300
 301 # For gnulib.
 302 gl_INIT
 303
 304 AC_C_INLINE
 305
 306 AC_C_BIGENDIAN
 307
 308 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 309
 310 AC_PROG_LN_S
 311
 312 AC_ARG_ENABLE(
 313   debug,
 314   [AS_HELP_STRING([--enable-debug],
 315                   [Turn on diagnostic features in the program])])
 316 if test x"$enable_debug" = x"yes"  ; then
 317   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 318 fi
 319
 320 # iconv is required
 321 if test "$am_cv_func_iconv" != "yes"; then
 322    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 323 fi
 324
 325 dnl Required by the gnulib 'relocatable-prog' module.
 326 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 327 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 328 RELOCATABLE_STRIP=:
 329
 330 PSPP_CHECK_PREREQS
 331
 332 AC_CONFIG_FILES(
 333   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 334
 335 AC_OUTPUT
 336 echo "PSPP configured successfully."
 337
 338 dnl configure.ac ends here