pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AX_PREREQ(2.57)
   5 AC_INIT(pspp, 0.3.2,bug-gnu-pspp@gnu.org)
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 AC_PROG_RANLIB
  13
  14 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  15
  16 AC_PATH_PROG([PERL], perl, no)
  17 AC_SUBST([PERL])dnl
  18 if test "$PERL" = no; then
  19   AC_MSG_ERROR([perl is not found])
  20 fi
  21 $PERL -e 'require 5.005_03;' || {
  22    AC_MSG_ERROR([Perl 5.005_03 or better is required])
  23 }
  24
  25 dnl Internationalization macros.
  26 AM_GNU_GETTEXT
  27 AM_GNU_GETTEXT_VERSION  dnl Prevents autoreconf complaint.
  28
  29 dnl Checks for libraries.
  30 AC_SYS_LARGEFILE
  31 AC_FUNC_FSEEKO
  32 AC_CHECK_LIB(m, sin)
  33 AC_ARG_WITH(libplot, [  --without-libplot         don't compile in support of charts (using libplot)])
  34
  35 if test x"$with_libplot" != x"no" ; then
  36         AC_CHECK_LIB(plot, pl_newpl_r,,
  37           AC_MSG_ERROR([You must install libplot (or use --without-libplot)])
  38         )
  39 fi
  40 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  41
  42
  43 AC_CHECK_LIB(gmp, mpf_get_str,,
  44         AC_CHECK_LIB(gmp, __gmpf_get_str,,
  45           AC_MSG_ERROR([You must install libgmp])
  46         )
  47 )
  48
  49 AC_CHECK_LIB(gslcblas,main,,AC_MSG_ERROR([You must install libgslcblas]))
  50 AC_CHECK_LIB(gsl, gsl_cdf_chisq_Q,,
  51   AC_MSG_ERROR([You must install libgsl version 1.4 or later]))
  52
  53 AC_CHECK_LIB(gnugetopt,getopt_long)
  54 AC_CHECK_FUNC(getopt_long,,
  55         AC_MSG_ERROR(`This application depends upon getopt_long'))
  56
  57 AC_ARG_WITH(ncurses,
  58 [  --without-ncurses         don't compile in ncurses command line editing])
  59
  60
  61 if test "x$with_ncurses" = x"yes"; then
  62 AC_CHECK_LIB(ncurses, tgetent, LIBS="-lncurses $LIBS" termcap=yes,
  63   AC_CHECK_LIB(termcap, tgetent, LIBS="-ltermcap $LIBS" termcap=yes,
  64                termcap=no))
  65 fi
  66
  67
  68 if test "$termcap" = yes; then
  69   AC_CHECK_HEADERS(termcap.h)
  70   AC_DEFINE(HAVE_LIBTERMCAP, 1,
  71         [Define if you have the termcap library (-ltermcap).])
  72 fi
  73
  74 AC_CHECK_LIB(readline, readline)
  75 if test "$ac_cv_lib_readline_readline" = yes; then
  76   AC_CHECK_HEADERS(readline/readline.h)
  77   AC_CHECK_LIB(readline, add_history, history=yes,
  78     AC_CHECK_LIB(history, add_history, LIBS="-lhistory" history=yes,
  79                  history=no))
  80   if test "$history" = yes; then
  81     AC_CHECK_HEADERS(readline/history.h)
  82     AC_DEFINE(HAVE_LIBHISTORY, 1,
  83         [Define if you have the history library (-lhistory).])
  84   fi
  85 fi
  86
  87 dnl Checks for header files.
  88 AC_ARG_WITH(valgrind, [  --without-valgrind        don't compile in valgrind])
  89 if test "x$with_valgrind" != x"no"; then
  90  AC_CHECK_HEADERS([valgrind/valgrind.h])
  91 fi
  92 AC_CHECK_HEADERS([limits.h memory.h sys/stat.h sys/time.h sys/types.h \
  93                   fpu_control.h sys/mman.h sys/wait.h ieeefp.h fenv.h] )
  94
  95 AC_HEADER_STAT
  96 AC_HEADER_STDC
  97 AC_HEADER_TIME
  98 AC_HEADER_STDBOOL
  99
 100 AC_C_CONST
 101 AC_C_INLINE
 102 dnl  Dont use AC_TYPE_OFF_T --- it doesnt generate the HAVE_TYPE macro
 103 AC_CHECK_TYPES(off_t)
 104 AC_TYPE_SIZE_T
 105 AC_STRUCT_TM
 106
 107 AC_CHECK_SIZEOF(short, 2)
 108 AC_CHECK_SIZEOF(int, 4)
 109 AC_CHECK_SIZEOF(long, 4)
 110 AC_CHECK_SIZEOF(long long, 0)
 111 AC_CHECK_SIZEOF(float, 0)
 112 AC_CHECK_SIZEOF(double, 8)
 113 AC_CHECK_SIZEOF(long double, 0)
 114
 115 AC_DEFINE(FPREP_IEEE754, 1,
 116         [Define for machines that have IEEE 754 floating point arithmetic,
 117          the most common format today.])
 118
 119 AC_C_BIGENDIAN
 120
 121 BLP_IS_SPRINTF_GOOD
 122 BLP_INT_DIGITS
 123 BLP_RANDOM
 124
 125 AC_FUNC_ALLOCA
 126 AC_FUNC_MEMCMP
 127 AC_FUNC_VPRINTF
 128 AC_REPLACE_FUNCS([memmove memset stpcpy strpbrk strerror strtol strtoul \
 129                   memchr getline getdelim strcasecmp strncasecmp memmem \
 130                   strtok_r])
 131 AC_CHECK_FUNCS([gethostname strstr strtod __setfpucw isinf isnan finite \
 132                 getpid feholdexcept mkdtemp])
 133
 134 AC_PROG_LN_S
 135
 136
 137 AH_BOTTOM([#include <pref.h>])
 138
 139
 140 AM_CONDITIONAL(unix, test x"$host_os" != x"msdos" )
 141 AM_CONDITIONAL(msdos, test x"$host_os" == x"msdos" )
 142
 143 dnl This is needed otherwise --with-included-gettext fails
 144 AH_BOTTOM([#include <locale.h>])
 145
 146 AC_ARG_ENABLE(debug, [  --enable-debug          Turn on diagnostic features in the program])
 147 if test x"$enable_debug" = x"yes"  ; then
 148   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 149 fi
 150
 151 AC_CONFIG_FILES([Makefile po/Makefile.in m4/Makefile
 152                  lib/Makefile lib/misc/Makefile lib/gsl-extras/Makefile
 153                  doc/Makefile
 154                  src/Makefile src/expressions/Makefile
 155                  config/Makefile
 156                  tests/Makefile])
 157 AC_CONFIG_COMMANDS([pref.h],[
 158            # Copy pref.h from pref.h.orig if prudent
 159            if test ! -f pref.h; then
 160              echo "creating pref.h"
 161              cp $ac_given_srcdir/pref.h.orig pref.h
 162            elif test "`ls -t pref.h.orig pref.h 2>/dev/null | sed 1q`" = pref.h.orig; then
 163              echo "replacing pref.h with newer pref.h.orig"
 164              cp $ac_given_srcdir/pref.h.orig pref.h
 165            else
 166              echo "pref.h exists"
 167            fi
 168            if test -f pref.h; then touch pref.h; fi
 169           ])
 170 AC_OUTPUT(intl/Makefile)
 171
 172 dnl configure.ac ends here