configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.7], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  36 AC_PROVIDE([AM_PO_SUBDIRS])
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38
  39 dnl Checks for libraries.
  40 AC_SYS_LARGEFILE
  41 AC_SEARCH_LIBS([sin], [m])
  42 AC_SEARCH_LIBS([dcgettext], [intl])
  43 PSPP_LC_PAPER
  44
  45
  46 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  47 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  48
  49 # Support for Cairo and Pango.
  50 AC_ARG_WITH([cairo],
  51   [AS_HELP_STRING(
  52     [--without-cairo],
  53     [Don't build support for charts (using Cairo and Pango);
  54      implies --without-gui])],
  55   [], [with_cairo=yes])
  56 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  57 if test "$with_cairo" != no; then
  58   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  59     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  60      AC_DEFINE([HAVE_CAIRO], 1,
  61        [Define to 1 if Cairo and Pango are available.])],
  62     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  63   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  64   AC_SUBST(XMLLINT)
  65 fi
  66
  67 # Support for GUI.
  68 AC_ARG_WITH([gui],
  69   [AS_HELP_STRING([--without-gui],
  70                   [Don't build the PSPPIRE GUI (using GTK+)])],
  71   [], [with_gui=yes])
  72 AM_CONDITIONAL([HAVE_GUI],
  73                [test "$with_cairo" != no && test "$with_gui" != "no"])
  74 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  75   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  76     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  77
  78   AC_ARG_VAR([GLIB_GENMARSHAL])
  79   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  80   if test "x$GLIB_GENMARSHAL" = x; then
  81     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  82   fi
  83 fi
  84
  85 dnl Checks needed for psql reader
  86
  87 dnl The 8.x series postgres tarballs installs with a default prefix of
  88 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  89
  90 dnl If the libpq.so file is in a non standard path, (one which the linker
  91 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  92 dnl However, if the system happens to have more than one version of other
  93 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  94 dnl /usr and /usr/local) then the wrong one may get linked.
  95
  96 dnl To overcome this, we first check for libpq in the standard places, and
  97 dnl only set PG_LDFLAGS if it's not found.
  98
  99
 100 AC_ARG_WITH(
 101   libpq,
 102   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 103 AC_ARG_VAR([PG_CONFIG],
 104            [Full pathname of the pg_config program shipped with Postgresql])
 105 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 106              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 107
 108 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 109   AC_SUBST(PG_CONFIG)
 110   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 111   AC_SUBST(PG_CFLAGS)
 112
 113   AC_CHECK_LIB([pq], [PQexec],
 114      [:],
 115      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 116   AC_SUBST(PG_LDFLAGS)
 117
 118   PG_LIBS=-lpq
 119   AC_SUBST(PG_LIBS)
 120
 121   PKG_CHECK_EXISTS(libssl,
 122         AC_DEFINE([USE_SSL],1,
 123                    [Define to 1 if the openssl library is present.])
 124            ,)
 125
 126   # Now verify that we can actually link against libpq.  If we are
 127   # cross-compiling and picked up a host libpq, or if libpq is just
 128   # badly installed, this will fail.
 129   AC_CACHE_CHECK(
 130     [whether -lpq links successfully],
 131     [pspp_cv_have_libpq],
 132     [save_CPPFLAGS=$CPPFLAGS
 133      save_LIBS=$LIBS
 134      save_LDFLAGS=$LDFLAGS
 135      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 136      LIBS="$PG_LIBS $LIBS"
 137      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 138      AC_LINK_IFELSE(
 139        [AC_LANG_PROGRAM(
 140          [#include <libpq-fe.h>
 141          ], [PQfinish (0);])],
 142        [pspp_cv_have_libpq=yes],
 143        [pspp_cv_have_libpq=no])
 144      CPPFLAGS=$save_CPPFLAGS
 145      LIBS=$save_LIBS
 146      LDFLAGS=$save_LDFLAGS])
 147
 148   if test $pspp_cv_have_libpq = yes; then
 149     PSQL_SUPPORT=yes
 150     AC_DEFINE([PSQL_SUPPORT], [1],
 151       [Define to 1 if building in support for reading from postgres
 152        databases.])
 153   else
 154     PSQL_SUPPORT=no
 155     PG_CONFIG=
 156     PG_CFLAGS=
 157     PG_LDFLAGS=
 158     PG_LIBS=
 159   fi
 160 else
 161   PSQL_SUPPORT=no
 162   pspp_cv_have_libpq=no
 163 fi
 164 AC_SUBST([PSQL_SUPPORT])
 165
 166 dnl Check for libxml2
 167 PKG_CHECK_MODULES(
 168   [LIBXML2], [libxml-2.0],
 169   [HAVE_LIBXML2=yes],
 170   [HAVE_LIBXML2=no
 171    PSPP_OPTIONAL_PREREQ([libxml2])])
 172
 173 dnl Check for zlib.
 174 AC_SEARCH_LIBS(
 175   [gzopen], [z],
 176   [HAVE_ZLIB=yes],
 177   [HAVE_ZLIB=no
 178    PSPP_OPTIONAL_PREREQ([zlib])])
 179 AC_CHECK_HEADERS(
 180   [zlib.h],
 181   [],
 182   [HAVE_ZLIB=no
 183    PSPP_OPTIONAL_PREREQ([zlib])])
 184
 185 dnl Avoid interference between zlib's crc32() function and gnulib's
 186 dnl crc32() function, which have different signatures.  PSPP calls
 187 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 188 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 189 dnl crc32(), then zlib will call gnulib's version instead of its own,
 190 dnl causing failures.  (This can happen even if zlib isn't detected
 191 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 192 dnl sometimes use zlib themselves.)
 193 AC_DEFINE(
 194   [crc32], [gl_crc32],
 195   [Avoid making zlib call gnulib's crc32() instead of its own.])
 196
 197 dnl Gnumeric support requires libxml2 and zlib.
 198 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 199   GNM_SUPPORT=yes
 200   AC_DEFINE(
 201     [GNM_SUPPORT], [1],
 202     [Define to 1 if building in support for reading Gnumeric files.])
 203 else
 204   GNM_SUPPORT=no
 205 fi
 206 AC_SUBST([GNM_SUPPORT])
 207
 208 dnl ODT support requires libxml2.
 209 if test $HAVE_LIBXML2 = yes; then
 210   AC_DEFINE(
 211     [ODT_SUPPORT], [1],
 212     [Define to 1 if building in support for writing ODT files.])
 213 fi
 214 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 215
 216 AC_ARG_WITH(
 217   gui_tools,
 218   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 219 if test x"$with_gui_tools" = x"yes" ; then
 220         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 221 fi
 222 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 223
 224 AC_ARG_WITH(
 225   [perl-module],
 226   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 227   [case $with_perl_module in # (
 228      yes|no) ;; # (
 229      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 230    esac
 231    WITH_PERL_MODULE=$with_perl_module],
 232   [if test x"$cross_compiling" != x"yes"; then
 233      WITH_PERL_MODULE=yes
 234    else
 235      WITH_PERL_MODULE=no
 236    fi])
 237 AC_SUBST([WITH_PERL_MODULE])
 238 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 239
 240 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 241 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 242                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 243
 244
 245 PSPP_GSL_NEEDS_FGNU89_INLINE
 246
 247 dnl Recent versions of GNU ncurses install the curses header files into
 248 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 249 dnl enables us to discover where they are. Earlier versions don't have
 250 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 251 dnl we'll trust it to find the right information.  Otherwise, we'll
 252 dnl try to discover it ourselves.
 253 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 254 dnl to ncurses8-config !!!
 255 AC_ARG_WITH(
 256   libncurses,
 257   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 258
 259 if test x"$with_libncurses" != x"no" ; then
 260   if test x"$cross_compiling" != x"yes" ; then
 261           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 262   fi
 263   if test x"$NCURSES_CONFIG" = x ; then
 264           AC_SEARCH_LIBS([tgetent], [ncurses],
 265               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 266   else
 267           old_cflags=$CFLAGS
 268           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 269           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 270           CFLAGS=$old_cflags
 271           if test x"$curses_available" = x"yes" ; then
 272            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 273            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 274            AC_SUBST(NCURSES_CFLAGS)
 275            AC_SUBST(NCURSES_LIBS)
 276           fi
 277   fi
 278   if test x"$curses_available" = x"yes" ; then
 279           AC_DEFINE([LIBNCURSES_USABLE], 1,
 280               [Define to 1 if the libncurses is both present and usable.])
 281   fi
 282   AC_CHECK_HEADERS([termcap.h])
 283 fi
 284
 285 PSPP_READLINE
 286
 287 dnl Checks for header files.
 288 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 289
 290 dnl Some systems dont have SIGWINCH
 291 AC_CHECK_DECLS([SIGWINCH], [], [],
 292           [#include <signal.h>
 293           /* NetBSD declares sys_siglist in unistd.h.  */
 294           #ifdef HAVE_UNISTD_H
 295           # include <unistd.h>
 296           #endif
 297           ])
 298
 299
 300 # For gnulib.
 301 gl_INIT
 302
 303 AC_C_INLINE
 304
 305 AC_CHECK_SIZEOF([size_t])
 306 SIZEOF_SIZE_T=$ac_cv_sizeof_size_t
 307 AC_SUBST([SIZEOF_SIZE_T])
 308
 309 AC_C_BIGENDIAN
 310
 311 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 312
 313 AC_PROG_LN_S
 314
 315 AC_ARG_ENABLE(
 316   debug,
 317   [AS_HELP_STRING([--enable-debug],
 318                   [Turn on diagnostic features in the program])])
 319 if test x"$enable_debug" = x"yes"  ; then
 320   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 321 fi
 322
 323 # iconv is required
 324 AM_ICONV
 325 if test "$am_cv_func_iconv" != "yes"; then
 326    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 327 fi
 328
 329 dnl Required by the gnulib 'relocatable-prog' module.
 330 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 331 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 332 RELOCATABLE_STRIP=:
 333
 334 PSPP_CHECK_PREREQS
 335
 336 AC_CONFIG_FILES(
 337   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 338
 339 AC_OUTPUT
 340 echo "PSPP configured successfully."
 341
 342 dnl configure.ac ends here