pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.9], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29 PSPP_ENABLE_WERROR
  30
  31 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  32
  33 PSPP_CC_FOR_BUILD
  34 PSPP_PERL
  35
  36 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  37 AC_PROVIDE([AM_PO_SUBDIRS])
  38 AM_GNU_GETTEXT([external], [need-ngettext])
  39 LIBS="$LIBINTL $LIBS"
  40
  41 dnl Checks for libraries.
  42 AC_SYS_LARGEFILE
  43 AC_SEARCH_LIBS([sin], [m])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  77     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  78
  79   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  80     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  81
  82   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  83     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  84
  85   AC_ARG_VAR([GLIB_GENMARSHAL])
  86   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  87   if test "x$GLIB_GENMARSHAL" = x; then
  88     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  89   fi
  90
  91 fi
  92
  93 gl_NEXT_HEADERS([gtk/gtk.h])
  94
  95 dnl Checks needed for psql reader
  96
  97 dnl The 8.x series postgres tarballs installs with a default prefix of
  98 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  99
 100 dnl If the libpq.so file is in a non standard path, (one which the linker
 101 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 102 dnl However, if the system happens to have more than one version of other
 103 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 104 dnl /usr and /usr/local) then the wrong one may get linked.
 105
 106 dnl To overcome this, we first check for libpq in the standard places, and
 107 dnl only set PG_LDFLAGS if it's not found.
 108
 109
 110 AC_ARG_WITH(
 111   libpq,
 112   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 113 AC_ARG_VAR([PG_CONFIG],
 114            [Full pathname of the pg_config program shipped with Postgresql])
 115 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 116              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 117
 118 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 119   AC_SUBST(PG_CONFIG)
 120   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 121   AC_SUBST(PG_CFLAGS)
 122
 123   AC_CHECK_LIB([pq], [PQexec],
 124      [:],
 125      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 126   AC_SUBST(PG_LDFLAGS)
 127
 128   PG_LIBS=-lpq
 129   AC_SUBST(PG_LIBS)
 130
 131   PKG_CHECK_EXISTS(libssl,
 132         AC_DEFINE([USE_SSL],1,
 133                    [Define to 1 if the openssl library is present.])
 134            ,)
 135
 136   # Now verify that we can actually link against libpq.  If we are
 137   # cross-compiling and picked up a host libpq, or if libpq is just
 138   # badly installed, this will fail.
 139   AC_CACHE_CHECK(
 140     [whether -lpq links successfully],
 141     [pspp_cv_have_libpq],
 142     [save_CPPFLAGS=$CPPFLAGS
 143      save_LIBS=$LIBS
 144      save_LDFLAGS=$LDFLAGS
 145      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 146      LIBS="$PG_LIBS $LIBS"
 147      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 148      AC_LINK_IFELSE(
 149        [AC_LANG_PROGRAM(
 150          [#include <libpq-fe.h>
 151          ], [PQfinish (0);])],
 152        [pspp_cv_have_libpq=yes],
 153        [pspp_cv_have_libpq=no])
 154      CPPFLAGS=$save_CPPFLAGS
 155      LIBS=$save_LIBS
 156      LDFLAGS=$save_LDFLAGS])
 157
 158   if test $pspp_cv_have_libpq = yes; then
 159     PSQL_SUPPORT=yes
 160     AC_DEFINE([PSQL_SUPPORT], [1],
 161       [Define to 1 if building in support for reading from postgres
 162        databases.])
 163   else
 164     PSQL_SUPPORT=no
 165     PG_CONFIG=
 166     PG_CFLAGS=
 167     PG_LDFLAGS=
 168     PG_LIBS=
 169   fi
 170 else
 171   PSQL_SUPPORT=no
 172   pspp_cv_have_libpq=no
 173 fi
 174 AC_SUBST([PSQL_SUPPORT])
 175
 176 dnl Check for libxml2
 177 PKG_CHECK_MODULES(
 178   [LIBXML2], [libxml-2.0],
 179   [HAVE_LIBXML2=yes],
 180   [HAVE_LIBXML2=no
 181    PSPP_OPTIONAL_PREREQ([libxml2])])
 182
 183 dnl Check for zlib.
 184 AC_SEARCH_LIBS(
 185   [gzopen], [z],
 186   [HAVE_ZLIB=yes],
 187   [HAVE_ZLIB=no
 188    PSPP_OPTIONAL_PREREQ([zlib])])
 189 AC_CHECK_HEADERS(
 190   [zlib.h],
 191   [],
 192   [HAVE_ZLIB=no
 193    PSPP_OPTIONAL_PREREQ([zlib])])
 194
 195 dnl Avoid interference between zlib's crc32() function and gnulib's
 196 dnl crc32() function, which have different signatures.  PSPP calls
 197 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 198 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 199 dnl crc32(), then zlib will call gnulib's version instead of its own,
 200 dnl causing failures.  (This can happen even if zlib isn't detected
 201 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 202 dnl sometimes use zlib themselves.)
 203 AC_DEFINE(
 204   [crc32], [gl_crc32],
 205   [Avoid making zlib call gnulib's crc32() instead of its own.])
 206
 207 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 208 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 209   GNM_SUPPORT=yes
 210   ODF_READ_SUPPORT=yes
 211   AC_DEFINE(
 212     [GNM_SUPPORT], [1],
 213     [Define to 1 if building in support for reading Gnumeric files.])
 214   AC_DEFINE(
 215     [ODF_READ_SUPPORT], [1],
 216     [Define to 1 if building in support for reading OpenDocument files.])
 217 else
 218   GNM_SUPPORT=no
 219   ODF_READ_SUPPORT=no
 220 fi
 221 AC_SUBST([GNM_SUPPORT])
 222 AC_SUBST([ODF_READ_SUPPORT])
 223
 224 dnl ODF support requires libxml2 (zlib is optional).
 225 if test $HAVE_LIBXML2 = yes; then
 226   AC_DEFINE(
 227     [ODF_WRITE_SUPPORT], [1],
 228     [Define to 1 if building in support for writing OpenDocument files.])
 229 fi
 230 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 231
 232 AC_ARG_WITH(
 233   gui_tools,
 234   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 235 if test x"$with_gui_tools" = x"yes" ; then
 236         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 237 fi
 238 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 239
 240 AC_ARG_WITH(
 241   [perl-module],
 242   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 243   [case $with_perl_module in # (
 244      yes|no) ;; # (
 245      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 246    esac
 247    WITH_PERL_MODULE=$with_perl_module],
 248   [if test x"$cross_compiling" != x"yes"; then
 249      WITH_PERL_MODULE=yes
 250    else
 251      WITH_PERL_MODULE=no
 252    fi])
 253 AC_SUBST([WITH_PERL_MODULE])
 254 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 255
 256 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 257 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 258                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 259
 260
 261 PSPP_GSL_NEEDS_FGNU89_INLINE
 262
 263 dnl Recent versions of GNU ncurses install the curses header files into
 264 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 265 dnl enables us to discover where they are. Earlier versions don't have
 266 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 267 dnl we'll trust it to find the right information.  Otherwise, we'll
 268 dnl try to discover it ourselves.
 269 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 270 dnl to ncurses8-config !!!
 271 AC_ARG_WITH(
 272   libncurses,
 273   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 274
 275 if test x"$with_libncurses" != x"no" ; then
 276   if test x"$cross_compiling" != x"yes" ; then
 277           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 278   fi
 279   if test x"$NCURSES_CONFIG" = x ; then
 280           AC_SEARCH_LIBS([tgetent], [ncurses],
 281               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 282   else
 283           old_cflags=$CFLAGS
 284           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 285           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 286           CFLAGS=$old_cflags
 287           if test x"$curses_available" = x"yes" ; then
 288            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 289            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 290            AC_SUBST(NCURSES_CFLAGS)
 291            AC_SUBST(NCURSES_LIBS)
 292           fi
 293   fi
 294   if test x"$curses_available" = x"yes" ; then
 295           AC_DEFINE([LIBNCURSES_USABLE], 1,
 296               [Define to 1 if the libncurses is both present and usable.])
 297   fi
 298   AC_CHECK_HEADERS([termcap.h])
 299 fi
 300
 301 PSPP_READLINE
 302
 303 dnl Checks for header files.
 304 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 305
 306 dnl Some systems dont have SIGWINCH
 307 AC_CHECK_DECLS([SIGWINCH], [], [],
 308           [#include <signal.h>
 309           /* NetBSD declares sys_siglist in unistd.h.  */
 310           #ifdef HAVE_UNISTD_H
 311           # include <unistd.h>
 312           #endif
 313           ])
 314
 315
 316 # For gnulib.
 317 gl_INIT
 318
 319 AC_C_INLINE
 320
 321 AC_CHECK_SIZEOF([size_t])
 322 SIZEOF_SIZE_T=$ac_cv_sizeof_size_t
 323 AC_SUBST([SIZEOF_SIZE_T])
 324
 325 AC_C_BIGENDIAN
 326
 327 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 328
 329 AC_PROG_LN_S
 330
 331 AC_ARG_ENABLE(
 332   debug,
 333   [AS_HELP_STRING([--enable-debug],
 334                   [Turn on diagnostic features in the program])])
 335 if test x"$enable_debug" = x"yes"  ; then
 336   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 337 fi
 338
 339 # iconv is required
 340 AM_ICONV
 341 if test "$am_cv_func_iconv" != "yes"; then
 342    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 343 fi
 344 LIBS="$LIBICONV $LIBS"
 345
 346 dnl Required by the gnulib 'relocatable-prog' module.
 347 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 348 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 349 RELOCATABLE_STRIP=:
 350
 351 PSPP_CHECK_PREREQS
 352
 353 AC_CONFIG_FILES(
 354   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 355
 356 AC_OUTPUT
 357 echo "PSPP configured successfully."
 358
 359 dnl configure.ac ends here