Change assembly from AT&T to Intel syntax.

[pintos-anon] / src / threads / switch.S

diff --git a/src/threads/switch.S b/src/threads/switch.S
index fddd821afc8ef296fb22d800768e743577be89c5..4f0d412c7266e3117d6fa33bdb2e9f598dbb63e8 100644 (file)
--- a/src/threads/switch.S
+++ b/src/threads/switch.S
@@ -1,47 +1,65 @@
-#include "switch.h"
+#include "threads/switch.h"
 
-        .globl switch_threads 
+#### struct thread *switch_threads (struct thread *cur, struct thread *next);
+####
+#### Switches from CUR, which must be the running thread, to NEXT,
+#### which must also be running switch_threads(), returning CUR in
+#### NEXT's context.
+####
+#### This function works by assuming that the thread we're switching
+#### into is also running switch_threads().  Thus, all it has to do is
+#### preserve a few registers on the stack, then switch stacks and
+#### restore the registers.  As part of switching stacks we record the
+#### current stack pointer in CUR's thread structure.
+
+       .intel_syntax noprefix
+
+.globl switch_threads 
 switch_threads:
        # Save caller's register state.
-       # Note that the SVR4 ABI allows us to destroy %eax, %ecx, %edx.
+       #
+       # Note that the SVR4 ABI allows us to destroy eax, ecx, edx,
+       # but requires us to preserve ebx, ebp, esi, edi.  See
+       # [SysV-ABI-386] pages 3-11 and 3-12 for details.
+       #
        # This stack frame must match the one set up by thread_create().
-       pushl %ebx
-       pushl %ebp
-       pushl %esi
-       pushl %edi
+       push ebx
+       push ebp
+       push esi
+       push edi
 
        # Get offsetof (struct thread, stack).
-       .globl thread_stack_ofs
-       mov thread_stack_ofs, %edx
+.globl thread_stack_ofs
+       mov edx, thread_stack_ofs
 
        # Save current stack pointer to old thread's stack, if any.
-       movl SWITCH_CUR(%esp), %eax
-       test %eax, %eax
+       mov eax, SWITCH_CUR[esp]
+       test eax, eax
        jz 1f
-       movl %esp, (%eax,%edx,1)
+       mov [eax + edx], esp
 1:
 
        # Restore stack pointer from new thread's stack.
-       movl SWITCH_NEXT(%esp), %ecx
-       movl (%ecx,%edx,1), %esp
+       mov ecx, SWITCH_NEXT[esp]
+       mov esp, [ecx + edx]
 
        # Restore caller's register state.
-       popl %edi
-       popl %esi
-       popl %ebp
-       popl %ebx
+       pop edi
+       pop esi
+       pop ebp
+       pop ebx
         ret
 
-       .globl switch_entry
+.globl switch_entry
 switch_entry:
-       # Discard thread_switch() arguments.
-       addl $8, %esp
+       # Discard switch_threads() arguments.
+       add esp, 8
 
        # Call schedule_tail(prev).
-       pushl %eax
-       .globl schedule_tail
+       push eax
+.globl schedule_tail
        call schedule_tail
-       addl $4, %esp
+       add esp, 4
 
        # Start thread proper.
        ret