configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LIBPLOT
  45 PSPP_LC_PAPER
  46 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  47
  48
  49 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  50 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  51
  52
  53 AC_ARG_WITH(
  54   gui,
  55   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  56
  57 required_gtk_version=2.12
  58
  59 if test x"$with_gui" != x"no" ; then
  60   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  61     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  62   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  63   AC_SUBST(XMLLINT)
  64 fi
  65 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  66
  67
  68 dnl Checks needed for psql reader
  69
  70 dnl The 8.x series postgres tarballs installs with a default prefix of
  71 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  72
  73 dnl If the libpq.so file is in a non standard path, (one which the linker
  74 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  75 dnl However, if the system happens to have more than one version of other
  76 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  77 dnl /usr and /usr/local) then the wrong one may get linked.
  78
  79 dnl To overcome this, we first check for libpq in the standard places, and
  80 dnl only set PG_LDFLAGS if it's not found.
  81
  82
  83 AC_ARG_WITH(
  84   libpq,
  85   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  86
  87 if test x"$with_libpq" != x"no" ; then
  88  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  89
  90  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  91  if test x"$cross_compiling" != x"yes" ; then
  92    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  93  fi
  94  if test -n "$PG_CONFIG" ; then
  95    AC_SUBST(PG_CONFIG)
  96    AC_DEFINE([PSQL_SUPPORT], 1,
  97    [Define to 1 if building in support for reading from postgres databases.])
  98    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  99    AC_SUBST(PG_CFLAGS)
 100
 101    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 102       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 103    fi
 104    AC_SUBST(PG_LDFLAGS)
 105
 106    PG_LIBS=-lpq
 107    AC_SUBST(PG_LIBS)
 108    PKG_CHECK_EXISTS(libssl,
 109          AC_DEFINE([USE_SSL],1,
 110                     [Define to 1 if the openssl library is present.])
 111             ,)
 112  fi
 113 fi
 114 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 115
 116 dnl Checks needed for Gnumeric reader
 117 gnm_support=yes;
 118 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 119                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 120 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 121 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 122
 123 if test x"$gnm_support" = x"yes" ; then
 124    AC_DEFINE([GNM_SUPPORT], 1,
 125    [Define to 1 if building in support for reading Gnumeric files.])
 126 fi
 127 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 128
 129 AC_ARG_WITH(
 130   gui_tools,
 131   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 132 if test x"$with_gui_tools" = x"yes" ; then
 133         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 134 fi
 135 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 136
 137 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 138
 139 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 140 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 141 PSPP_GSL_NEEDS_FGNU89_INLINE
 142
 143 dnl Recent versions of GNU ncurses install the curses header files into
 144 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 145 dnl enables us to discover where they are. Earlier versions don't have
 146 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 147 dnl we'll trust it to find the right information.  Otherwise, we'll
 148 dnl try to discover it ourselves.
 149 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 150 dnl to ncurses8-config !!!
 151 AC_ARG_WITH(
 152   libncurses,
 153   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 154
 155 if test x"$with_libncurses" != x"no" ; then
 156   if test x"$cross_compiling" != x"yes" ; then
 157           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 158   fi
 159   if test x"$NCURSES_CONFIG" = x ; then
 160           AC_SEARCH_LIBS([tgetent], [ncurses],
 161               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 162   else
 163           old_cflags=$CFLAGS
 164           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 165           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 166           CFLAGS=$old_cflags
 167           if test x"$curses_available" = x"yes" ; then
 168            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 169            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 170            AC_SUBST(NCURSES_CFLAGS)
 171            AC_SUBST(NCURSES_LIBS)
 172           fi
 173   fi
 174   if test x"$curses_available" = x"yes" ; then
 175           AC_DEFINE([LIBNCURSES_USABLE], 1,
 176               [Define to 1 if the libncurses is both present and usable.])
 177   fi
 178   AC_CHECK_HEADERS([termcap.h])
 179 fi
 180
 181 PSPP_READLINE
 182
 183 dnl Checks for header files.
 184 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 185
 186 # For gnulib.
 187 gl_INIT
 188
 189 AC_C_INLINE
 190
 191 AC_CHECK_SIZEOF(double)
 192
 193 AC_C_BIGENDIAN
 194
 195 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 196
 197 AC_PROG_LN_S
 198
 199 AC_ARG_ENABLE(
 200   debug,
 201   [AS_HELP_STRING([--enable-debug],
 202                   [Turn on diagnostic features in the program])])
 203 if test x"$enable_debug" = x"yes"  ; then
 204   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 205 fi
 206
 207 # iconv is required
 208 if test "$am_cv_func_iconv" != "yes"; then
 209    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 210 fi
 211
 212 dnl Required by the gnulib 'relocatable-prog' module.
 213 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 214 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 215 RELOCATABLE_STRIP=:
 216
 217 PSPP_CHECK_PREREQS
 218
 219 AC_CONFIG_FILES([Makefile gl/Makefile])
 220
 221 AC_OUTPUT
 222 echo "PSPP configured successfully."
 223
 224 dnl configure.ac ends here