configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LIBPLOT
  40 PSPP_LC_PAPER
  41 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  42
  43
  44 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  45 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  46
  47
  48 AC_ARG_WITH(
  49   gui,
  50   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  51
  52 required_gtk_version=2.12
  53
  54 if test x"$with_gui" != x"no" ; then
  55   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  56     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  57 fi
  58 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  59
  60
  61 dnl Checks needed for psql reader
  62
  63 dnl The 8.x series postgres tarballs installs with a default prefix of
  64 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  65
  66 dnl If the libpq.so file is in a non standard path, (one which the linker
  67 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  68 dnl However, if the system happens to have more than one version of other
  69 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  70 dnl /usr and /usr/local) then the wrong one may get linked.
  71
  72 dnl To overcome this, we first check for libpq in the standard places, and
  73 dnl only set PG_LDFLAGS if it's not found.
  74
  75
  76 AC_ARG_WITH(
  77   libpq,
  78   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  79
  80 if test x"$with_libpq" != x"no" ; then
  81  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  82
  83  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  84  if test x"$cross_compiling" != x"yes" ; then
  85    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  86  fi
  87  if test -n "$PG_CONFIG" ; then
  88    AC_SUBST(PG_CONFIG)
  89    AC_DEFINE([PSQL_SUPPORT], 1,
  90    [Define to 1 if building in support for reading from postgres databases.])
  91    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  92    AC_SUBST(PG_CFLAGS)
  93
  94    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  95       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
  96    fi
  97    AC_SUBST(PG_LDFLAGS)
  98
  99    PG_LIBS=-lpq
 100    AC_SUBST(PG_LIBS)
 101    PKG_CHECK_EXISTS(libssl,
 102          AC_DEFINE([USE_SSL],1,
 103                     [Define to 1 if the openssl library is present.])
 104             ,)
 105  fi
 106 fi
 107 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 108
 109 dnl Checks needed for Gnumeric reader
 110 gnm_support=yes;
 111 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 112                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 113 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 114 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 115
 116 if test x"$gnm_support" = x"yes" ; then
 117    AC_DEFINE([GNM_SUPPORT], 1,
 118    [Define to 1 if building in support for reading Gnumeric files.])
 119 fi
 120 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 121
 122 AC_ARG_WITH(
 123   gui_tools,
 124   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 125 if test x"$with_gui_tools" = x"yes" ; then
 126         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 127 fi
 128 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 129
 130 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 131
 132 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 133 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 134 PSPP_GSL_NEEDS_FGNU89_INLINE
 135
 136 dnl Recent versions of GNU ncurses install the curses header files into
 137 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 138 dnl enables us to discover where they are. Earlier versions don't have
 139 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 140 dnl we'll trust it to find the right information.  Otherwise, we'll
 141 dnl try to discover it ourselves.
 142 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 143 dnl to ncurses8-config !!!
 144 AC_ARG_WITH(
 145   libncurses,
 146   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 147
 148 if test x"$with_libncurses" != x"no" ; then
 149   if test x"$cross_compiling" != x"yes" ; then
 150           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 151   fi
 152   if test x"$NCURSES_CONFIG" = x ; then
 153           AC_SEARCH_LIBS([tgetent], [ncurses],
 154               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 155   else
 156           old_cflags=$CFLAGS
 157           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 158           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 159           CFLAGS=$old_cflags
 160           if test x"$curses_available" = x"yes" ; then
 161            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 162            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 163            AC_SUBST(NCURSES_CFLAGS)
 164            AC_SUBST(NCURSES_LIBS)
 165           fi
 166   fi
 167   if test x"$curses_available" = x"yes" ; then
 168           AC_DEFINE([LIBNCURSES_USABLE], 1,
 169               [Define to 1 if the libncurses is both present and usable.])
 170   fi
 171   AC_CHECK_HEADERS([termcap.h])
 172 fi
 173
 174 PSPP_READLINE
 175
 176 dnl Checks for header files.
 177 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 178
 179 # For gnulib.
 180 gl_INIT
 181
 182 AC_C_INLINE
 183
 184 AC_CHECK_SIZEOF(double)
 185
 186 AC_C_BIGENDIAN
 187
 188 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 189
 190 AC_PROG_LN_S
 191
 192 AC_ARG_ENABLE(
 193   debug,
 194   [AS_HELP_STRING([--enable-debug],
 195                   [Turn on diagnostic features in the program])])
 196 if test x"$enable_debug" = x"yes"  ; then
 197   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 198 fi
 199
 200 # iconv is required
 201 if test "$am_cv_func_iconv" != "yes"; then
 202    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 203 fi
 204
 205 PSPP_CHECK_PREREQS
 206
 207 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 208
 209 AC_OUTPUT
 210 echo "PSPP configured successfully."
 211
 212 dnl configure.ac ends here