From: Ben Pfaff <blp@gnu.org>
Date: Sun, 16 Apr 2006 02:15:06 +0000 (+0000)
Subject: Complain about missing prerequisites in a group at the end of
X-Git-Tag: v0.6.0~988
X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?p=pspp-builds.git;a=commitdiff_plain;h=8b12ba69bb4555f4bfaa910d6e37223e67bbdf04

Complain about missing prerequisites in a group at the end of
configuration, not piecemeal.  This should make building PSPP less
frustrating.  Thanks to John Darrington for the suggestion.
---

diff --git a/ChangeLog b/ChangeLog
index b2a95162..eec290a4 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,10 @@
+Sat Apr 15 19:13:59 2006  Ben Pfaff  <blp@gnu.org>
+
+	* configure.ac, acinclude.m4: Complain about missing prerequisites
+	in a group at the end of configuration, not piecemeal.  This
+	should make building PSPP less frustrating.  Thanks to John
+	Darrington for the suggestion.
+
 Sat Apr 15 18:17:15 2006  Ben Pfaff  <blp@gnu.org>
 
 	* configure.ac: Move code into acinclude.m4 to make the configure
diff --git a/acinclude.m4 b/acinclude.m4
index 353a6a58..0eb9c1f3 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -3,17 +3,35 @@ dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
+dnl Prerequisites.
+
+dnl Instead of giving an error about each prerequisite as we encounter it, 
+dnl group them all together at the end of the run, to be user-friendly.
+AC_DEFUN([PSPP_REQUIRED_PREREQ], [pspp_required_prereqs="$pspp_required_prereqs
+	$1"])
+AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
+	$1"])
+AC_DEFUN([PSPP_CHECK_PREREQS], 
+[
+  if test "$pspp_optional_prereqs" != ""; then
+    AC_MSG_WARN([The following optional prerequisites are not installed.
+You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
+fi
+  if test "$pspp_required_prereqs" != ""; then
+    AC_MSG_ERROR([The following required prerequisites are not installed.
+You must install them before PSPP can be built:$pspp_required_prereqs])
+fi
+])
+    
+
 dnl Check that a new enough version of Perl is available.
 AC_DEFUN([PSPP_PERL],
 [
   AC_PATH_PROG([PERL], perl, no)
   AC_SUBST([PERL])dnl
-  if test "$PERL" = no; then
-    AC_MSG_ERROR([perl is not found])
+  if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
+    PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
   fi
-  $PERL -e 'require 5.005_03;' || {
-     AC_MSG_ERROR([Perl 5.005_03 or better is required])
-  }
 ])
 
 dnl Check that libplot is available.
@@ -22,9 +40,8 @@ AC_DEFUN([PSPP_LIBPLOT],
   AC_ARG_WITH(libplot, [  --without-libplot         don't compile in support of charts (using libplot)])
 
   if test x"$with_libplot" != x"no" ; then 
-	  AC_CHECK_LIB(plot, pl_newpl_r,,
-	    AC_MSG_ERROR([You must install libplot development libraries (or use --without-libplot)])
-	  )
+    AC_CHECK_LIB(plot, pl_newpl_r,,
+	         [PSPP_REQUIRED_PREREQ([libplot (or use --without-libplot)])])
   fi
 ])
 
@@ -117,9 +134,6 @@ AC_DEFUN([PSPP_READLINE],
 
   if test "$gl_cv_lib_readline" = yes; then
     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
-  fi
-
-  if test "$gl_cv_lib_readline" = yes; then
     AC_MSG_CHECKING([how to link with libreadline])
     AC_MSG_RESULT([$LIBREADLINE])
   else
@@ -130,6 +144,7 @@ AC_DEFUN([PSPP_READLINE],
     LTLIBREADLINE=
     LIBHISTORY=
     LTLIBHISTORY=
+    PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
   fi
   AC_SUBST(LIBREADLINE)
   AC_SUBST(LTLIBREADLINE)
diff --git a/configure.ac b/configure.ac
index c6f61612..02ef4a5b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -42,9 +42,8 @@ AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
 
 PSPP_OFF_T
 
-AC_CHECK_LIB(gslcblas,main,,AC_MSG_ERROR([You must install libgslcblas development libraries]))
-AC_CHECK_LIB(gsl, gsl_cdf_chisq_Q,,
-  AC_MSG_ERROR([You must install development libraries for libgsl version 1.4 or later]))
+AC_CHECK_LIB(gslcblas,main,,[PSPP_REQUIRED_PREREQ([libgslcblas])])
+AC_CHECK_LIB(gsl, gsl_cdf_chisq_Q,,[PSPP_REQUIRED_PREREQ([libgsl (version 1.4 or later)])])
 
 AC_CHECK_LIB(ncurses, tgetent)
 AC_CHECK_HEADERS(termcap.h)
@@ -94,6 +93,8 @@ if test x"$enable_debug" = x"yes"  ; then
   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 fi
 
+PSPP_CHECK_PREREQS
+
 AC_CONFIG_FILES([Makefile gl/Makefile intl/Makefile po/Makefile.in])
 
 AC_OUTPUT