From: Paul Eggert <eggert@cs.ucla.edu>
Date: Fri, 24 Dec 2004 08:36:41 +0000 (+0000)
Subject: (gl_C99_STRTOLD): New macro.
X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=c2704078bca2a5efe4a8ae1feafe521c4adfc51d;p=pspp

(gl_C99_STRTOLD): New macro.
(gl_C_STRTOD): Use it instead of AC_CHECK_DECLS_ONCE(strtold).
---

diff --git a/m4/c-strtod.m4 b/m4/c-strtod.m4
index c212c5c9e3..b343fddae9 100644
--- a/m4/c-strtod.m4
+++ b/m4/c-strtod.m4
@@ -1,4 +1,4 @@
-# c-strtod.m4 serial 3
+# c-strtod.m4 serial 4
 
 # Copyright (C) 2004 Free Software Foundation, Inc.
 
@@ -18,6 +18,32 @@
 
 # Written by Paul Eggert.
 
+AC_DEFUN([gl_C99_STRTOLD],
+[
+  AC_CACHE_CHECK([whether strtold conforms to C99],
+    [gl_cv_func_c99_strtold],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[/* On HP-UX before 11.23, strtold returns a struct instead of
+		long double.  Reject implementations like that, by requiring
+		compatibility with the C99 prototype.  */
+	     #include <stdlib.h>
+	     static long double (*p) (char const *, char **) = strtold;
+	     static long double
+	     test (char const *nptr, char **endptr)
+	     {
+	       long double r;
+	       r = strtold (nptr, endptr);
+	       return r;
+	     }]],
+           [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
+       [gl_cv_func_c99_strtold=yes],
+       [gl_cv_func_c99_strtold=no])])
+  if test $gl_cv_func_c99_strtold = yes; then
+    AC_DEFINE([HAVE_C99_STRTOLD], 1, [Define to 1 if strtold conforms to C99.])
+  fi
+])
+
 AC_DEFUN([gl_C_STRTOD],
 [
   dnl Prerequisites of lib/c-strtod.c.
@@ -29,5 +55,6 @@ AC_DEFUN([gl_C_STRTOLD],
 [
   dnl Prerequisites of lib/c-strtold.c.
   AC_REQUIRE([gl_C_STRTOD])
-  AC_CHECK_DECLS_ONCE([strtold])
+  AC_REQUIRE([gl_C99_STRTOLD])
+  :
 ])