From: Ben Pfaff <blp@gnu.org>
Date: Sun, 13 Jul 2008 18:17:22 +0000 (-0700)
Subject: Autodetect and fix GSL use of GCC-style "extern inline".
X-Git-Tag: v0.7.0~20
X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=9a12eb1d5baf9c8fc25d8e6bf1ec5c852ac840d0;p=pspp-builds.git

Autodetect and fix GSL use of GCC-style "extern inline".
---

diff --git a/README b/README
index 07aae20a..02e81d77 100644
--- a/README
+++ b/README
@@ -21,12 +21,6 @@ at http://savannah.gnu.org/projects/pspp
 
 The following miscellaneous notes apply to this release:
 
-	* If you use GCC 4.3 or later to compile PSPP, along with any
-	  version of the GNU Scientific Library (GSL) released as of
-	  this writing (June 2008), then you will need to specify the
-	  -fgnu89-inline flag to the compiler on the "configure"
-	  command line: "./configure CFLAGS=-fgnu89-inline".
-
 	* On a few operating systems, such as OpenBSD, some of the
           tests may fail with messages similar to: 'Warning: cannot
           create a convertor for "646" to "UTF-8"'.  These test
diff --git a/acinclude.m4 b/acinclude.m4
index cbf927aa..10ea269b 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -205,4 +205,68 @@ AC_DEFUN([PSPP_LC_PAPER],
   fi
 ])
 
+
+# PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+# -------------------------------------------------------------
+# Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
+# into a program.
+#
+# Test that resulting file is executable; see the problem reported by mwoehlke
+# in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
+# But skip the test when cross-compiling, to prevent problems like the one
+# reported by Chris Johns in
+# <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
+#
+m4_define([PSPP_LINK2_IFELSE],
+[m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
+mv conftest.$ac_ext conftest1.$ac_ext
+m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
+mv conftest.$ac_ext conftest2.$ac_ext
+rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
+pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&AS_MESSAGE_LOG_FD'
+AS_IF([_AC_DO_STDERR($pspp_link2) && {
+	 test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
+	 test ! -s conftest.err
+       } && test -s conftest$ac_exeext && {
+	 test "$cross_compiling" = yes ||
+	 AS_TEST_X([conftest$ac_exeext])
+       }],
+      [$3],
+      [AS_ECHO(["$as_me: failed source file 1 of 2 was:"]) >&AS_MESSAGE_LOG_FD
+sed 's/^/| /' conftest1.$ac_ext >&AS_MESSAGE_LOG_FD
+AS_ECHO(["$as_me: failed source file 2 of 2 was:"]) >&AS_MESSAGE_LOG_FD
+sed 's/^/| /' conftest2.$ac_ext >&AS_MESSAGE_LOG_FD
+	$4])
+dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
+dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
+dnl as it would interfere with the next link command.
+rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
+rm -f core conftest.err conftest1.err conftest2.err
+rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
+rm -f conftest$ac_exeext
+rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
+])# PSPP_LINK2_IFELSE
+
+# GSL uses "extern inline" without determining whether the compiler uses
+# GCC inline rules or C99 inline rules.  If it uses the latter then GSL
+# will be broken without passing -fgnu89-inline to GCC.
+AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
+[# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
+ # In turn, gnulib's gl_INLINE is one macro that does that.  We need to
+ # make sure that it has run by the time we run this test, otherwise we'll
+ # get a false result.
+ AC_REQUIRE([gl_INLINE])
+ AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
+                pspp_cv_gsl_needs_fgnu89_inline, [
+		PSPP_LINK2_IFELSE(
+		  [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
+                                   ], [GSL_MAX_INT(1,2);])],
+                  [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
+                                   void x (void) {}])],
+                  [pspp_cv_gsl_needs_fgnu89_inline=no],
+		  [pspp_cv_gsl_needs_fgnu89_inline=yes])])
+ if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
+     CFLAGS="$CFLAGS -fgnu89-inline"
+ fi
+])
 dnl acinclude.m4 ends here
diff --git a/configure.ac b/configure.ac
index a028fcbf..f38aafbc 100644
--- a/configure.ac
+++ b/configure.ac
@@ -129,6 +129,7 @@ AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 
 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 AC_SEARCH_LIBS([gsl_cdf_chisq_Q], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.4 or later)])])
+PSPP_GSL_NEEDS_FGNU89_INLINE
 
 dnl Recent versions of GNU ncurses install the curses header files into
 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which