From: Paul Eggert <eggert@cs.ucla.edu>
Date: Fri, 2 Dec 2005 18:23:00 +0000 (+0000)
Subject: * socklen.m4 (gl_TYPE_SOCKLEN_T): Renamed from gl_SOCKLEN_T.
X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=41f33021bba216bf24c5d93951fbede15390ea92;p=pspp

* socklen.m4 (gl_TYPE_SOCKLEN_T): Renamed from gl_SOCKLEN_T.
Use implementation from Albert Chin, with some
comments/corrections by Stepan Kasal and myself.
---

diff --git a/m4/ChangeLog b/m4/ChangeLog
index d285d7c296..12bce6b370 100644
--- a/m4/ChangeLog
+++ b/m4/ChangeLog
@@ -1,3 +1,9 @@
+2005-12-02  Paul Eggert  <eggert@cs.ucla.edu>
+
+	* socklen.m4 (gl_TYPE_SOCKLEN_T): Renamed from gl_SOCKLEN_T.
+	Use implementation from Albert Chin, with some
+	comments/corrections by Stepan Kasal and myself.
+
 2005-12-01  Paul Eggert  <eggert@cs.ucla.edu>
 
 	* regex.m4 (gl_REGEX): Check whether off_t can be used in a switch
diff --git a/m4/socklen.m4 b/m4/socklen.m4
index c26a2813a4..7db6ba3550 100644
--- a/m4/socklen.m4
+++ b/m4/socklen.m4
@@ -1,21 +1,42 @@
-# socklen.m4 serial 1
+# socklen.m4 serial 2
 dnl Copyright (C) 2005 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
-dnl From Simon Josefsson.
+dnl From Albert Chin.
 
-AC_DEFUN([gl_SOCKLEN_T],
-[
-  AC_CHECK_HEADERS_ONCE(sys/types.h sys/socket.h)
-  AC_CHECK_TYPE([socklen_t],, [AC_DEFINE([socklen_t], [int],
-                [Map `socklen_t' to `int' if it is missing.])], [
-#ifdef HAVE_SYS_TYPES_H
-# include <sys/types.h>
-#endif
-#ifdef HAVE_SYS_SOCKET_H
-# include <sys/socket.h>
-#endif)
-])
-])
+dnl Check for socklen_t: historically on BSD it is an int, and in
+dnl POSIX 1g it is a type of its own, but some platforms use different
+dnl types for the argument to getsockopt, getpeername, etc.  So we
+dnl have to test to find something that will work.
+AC_DEFUN([gl_TYPE_SOCKLEN_T],
+  [AC_CHECK_TYPE([socklen_t], ,
+     [AC_MSG_CHECKING([for socklen_t equivalent])
+      AC_CACHE_VAL([gl_cv_gl_cv_socklen_t_equiv],
+        [# Systems have either "struct sockaddr *" or
+         # "void *" as the second argument to getpeername
+         gl_cv_socklen_t_equiv=
+         for arg2 in "struct sockaddr" void; do
+	   for t in int size_t "unsigned int" "long int" "unsigned long int"; do
+	     AC_TRY_COMPILE(
+	       [#include <sys/types.h>
+		#include <sys/socket.h>
+
+		int getpeername (int, $arg2 *, $t *);],
+               [$t len;
+		getpeername (0, 0, &len);],
+	       [gl_cv_socklen_t_equiv="$t"])
+             test "$gl_cv_socklen_t_equiv" != "" && break
+	   done
+           test "$gl_cv_socklen_t_equiv" != "" && break
+         done
+      ])
+      if test "$gl_cv_socklen_t_equiv" = ""; then
+	AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+      fi
+      AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
+      AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
+        [type to use in place of socklen_t if not defined])],
+     [#include <sys/types.h>
+      #include <sys/socket.h>])])