ceill-ieee: Make it work on OSF/1 5.1 with cc.

* doc/posix-functions/ceill.texi: Mention the OSF/1 5.1 bug.
* m4/ceill.m4 (gl_FUNC_CEILL): If gl_FUNC_CEILL_IEEE is also used,
test whether ceill works according to ISO C 99 with IEC 60559.
* m4/ceill-ieee.m4: New file.
* modules/ceill-ieee (Files): Add it and m4/minus-zero.m4,
m4/signbit.m4.
(configure.ac): Invoke gl_FUNC_CEILL_IEEE.

diff --git a/ChangeLog b/ChangeLog
index 7620cba4b18be3d4e63ff1b75de9ab0b7e2d097c..6e5444d23de863bcc7d7d9158d3c628dd59e1d18 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,14 @@
+2010-12-25  Bruno Haible  <bruno@clisp.org>
+
+       ceill-ieee: Make it work on OSF/1 5.1 with cc.
+       * doc/posix-functions/ceill.texi: Mention the OSF/1 5.1 bug.
+       * m4/ceill.m4 (gl_FUNC_CEILL): If gl_FUNC_CEILL_IEEE is also used,
+       test whether ceill works according to ISO C 99 with IEC 60559.
+       * m4/ceill-ieee.m4: New file.
+       * modules/ceill-ieee (Files): Add it and m4/minus-zero.m4,
+       m4/signbit.m4.
+       (configure.ac): Invoke gl_FUNC_CEILL_IEEE.
+
 2010-12-25  Bruno Haible  <bruno@clisp.org>
 
        Ensure all prerequisites of <wchar.h> are included.

diff --git a/doc/posix-functions/ceill.texi b/doc/posix-functions/ceill.texi
index 1291327b4b1b61200c6143ae9929b912d24a65da..13cf02e4596cd64fbccbef5711d274677910d052 100644 (file)
--- a/doc/posix-functions/ceill.texi
+++ b/doc/posix-functions/ceill.texi
@@ -6,13 +6,21 @@ POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/funct
 
 Gnulib module: ceill or ceill-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{ceill} or @code{ceill-ieee}:
 @itemize
 @item
 This function is missing on some platforms:
 FreeBSD 5.2.1, NetBSD 5.0, OpenBSD 3.8, HP-UX 11, IRIX 6.5, Solaris 9, Cygwin, Interix 3.5, BeOS.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{ceill-ieee}:
+@itemize
+@item
+This function returns a positive zero for an argument between -1 and 0
+on some platforms:
+OSF/1 5.1.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize

diff --git a/m4/ceill-ieee.m4 b/m4/ceill-ieee.m4
new file mode 100644 (file)
index 0000000..b70b9c5
--- /dev/null
+++ b/m4/ceill-ieee.m4
@@ -0,0 +1,15 @@
+# ceill-ieee.m4 serial 1
+dnl Copyright (C) 2010 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in ceill.m4 and not inlined in the
+dnl module description), so that gl_FUNC_CEILL can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_CEILL_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_ceill_required=ieee])
+  AC_REQUIRE([gl_FUNC_CEILL])
+])

diff --git a/m4/ceill.m4 b/m4/ceill.m4
index 49aa37697ffee2bb05682c27de42c88022bbba95..68fdca0d279210dca0afdd2cfb379d0d09a5e49a 100644 (file)
--- a/m4/ceill.m4
+++ b/m4/ceill.m4
@@ -1,4 +1,4 @@
-# ceill.m4 serial 7
+# ceill.m4 serial 8
 dnl Copyright (C) 2007, 2009-2010 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_CEILL],
 [
+  m4_divert_text([DEFAULTS], [gl_ceill_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   dnl Persuade glibc <math.h> to declare ceill().
   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
@@ -19,6 +20,40 @@ AC_DEFUN([gl_FUNC_CEILL],
       dnl libm.so, but not in the libm.so that the compiler uses.
       REPLACE_CEILL=1
     fi
+    m4_ifdef([gl_FUNC_CEILL_IEEE], [
+      if test $gl_ceill_required = ieee && test $REPLACE_CEILL = 0; then
+        AC_CACHE_CHECK([whether ceill works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_ceill_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $CEILL_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
+]gl_LONG_DOUBLE_SIGNBIT_CODE[
+int main()
+{
+  /* Test whether ceill (-0.3L) is -0.0L.  */
+  if (signbitl (minus_zerol) && !signbitl (ceill (-0.3L)))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_ceill_ieee=yes],
+              [gl_cv_func_ceill_ieee=no],
+              [gl_cv_func_ceill_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_ceill_ieee" in
+          *yes) ;;
+          *) REPLACE_CEILL=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_DECL_CEILL=0
   fi

diff --git a/modules/ceill-ieee b/modules/ceill-ieee
index 8566780e39d147905df692344cfd0ed20095aee3..b6dded31ec60eec0596caeaabec5837078c08172 100644 (file)
--- a/modules/ceill-ieee
+++ b/modules/ceill-ieee
@@ -2,11 +2,15 @@ Description:
 ceill() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/ceill-ieee.m4
+m4/minus-zero.m4
+m4/signbit.m4
 
 Depends-on:
 ceill
 
 configure.ac:
+gl_FUNC_CEILL_IEEE
 
 Makefile.am: