X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?a=blobdiff_plain;f=acinclude.m4;h=aa6e4d77b3ea756eb24deb1d675b2de20a3b7964;hb=53ceff2865473a6b561b521986fafd31a993a1a6;hp=6f8cd296d953518242a96c103564b699598d6102;hpb=2e0595dd8e344dbdcab740d7d2a3b67d153d6b39;p=pspp-builds.git

diff --git a/acinclude.m4 b/acinclude.m4
index 6f8cd296..aa6e4d77 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -1,3 +1,8 @@
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
 dnl Check longest integer in digits.
 
 AC_DEFUN([BLP_INT_DIGITS],
@@ -78,4 +83,77 @@ else
 fi
 ])dnl
 
+dnl Check for readline and history libraries.
+
+dnl Modified for PSPP by Ben Pfaff, based on readline.m4 serial 3 from
+dnl gnulib, which was written by Simon Josefsson, with help from Bruno
+dnl Haible and Oskar Liljeblad.
+
+AC_DEFUN([PSPP_READLINE],
+[
+  dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
+  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
+  AC_REQUIRE([AC_LIB_RPATH])
+
+  dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
+  dnl INCREADLINE accordingly.
+  AC_LIB_LINKFLAGS_BODY([readline])
+  AC_LIB_LINKFLAGS_BODY([history])
+
+  dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
+  dnl because if the user has installed libreadline and not disabled its use
+  dnl via --without-libreadline-prefix, he wants to use it. The AC_TRY_LINK
+  dnl will then succeed.
+  am_save_CPPFLAGS="$CPPFLAGS"
+  AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
+
+  AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
+    gl_cv_lib_readline=no
+    am_save_LIBS="$LIBS"
+    dnl On some systems, -lreadline doesn't link without an additional
+    dnl -lncurses or -ltermcap.
+    dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
+    dnl by design and obsolete since 1994. Try -lcurses last, because
+    dnl libcurses is unusable on some old Unices.
+    for extra_lib in "" ncurses termcap curses; do
+      LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
+      if test -n "$extra_lib"; then
+        LIBS="$LIBS -l$extra_lib"
+      fi
+      AC_TRY_LINK([#include <stdio.h>
+#include <readline/readline.h>
+#include <readline/history.h>],
+        [readline((char*)0); add_history((char*)0);],
+        gl_cv_lib_readline=yes)
+      if test "$gl_cv_lib_readline" = yes; then
+        if test -n "$extra_lib"; then
+          LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
+          LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
+        fi
+        break
+      fi
+    done
+    LIBS="$am_save_LIBS"
+  ])
+
+  if test "$gl_cv_lib_readline" = yes; then
+    AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
+  fi
+
+  if test "$gl_cv_lib_readline" = yes; then
+    AC_MSG_CHECKING([how to link with libreadline])
+    AC_MSG_RESULT([$LIBREADLINE])
+  else
+    dnl If $LIBREADLINE didn't lead to a usable library, we don't
+    dnl need $INCREADLINE either.
+    CPPFLAGS="$am_save_CPPFLAGS"
+    LIBREADLINE=
+    LTLIBREADLINE=
+    LIBHISTORY=
+    LTLIBHISTORY=
+  fi
+  AC_SUBST(LIBREADLINE)
+  AC_SUBST(LTLIBREADLINE)
+])
+
 dnl aclocal.m4 ends here