X-Git-Url: https://pintos-os.org/cgi-bin/gitweb.cgi?a=blobdiff_plain;f=acinclude.m4;h=0eb9c1f31a1562b2b1ee6249cbc9547a2b4e6bb7;hb=0188d216a999f6f45ccb98f6ee40bb82c13ac7fd;hp=e3ddb129b1464f0119500566fbe61d8e8bbdb6c3;hpb=2048ef1bcb81fa766ccff3bb1cf30a886316983c;p=pspp-builds.git

diff --git a/acinclude.m4 b/acinclude.m4
index e3ddb129..0eb9c1f3 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -3,6 +3,82 @@ dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
+dnl Prerequisites.
+
+dnl Instead of giving an error about each prerequisite as we encounter it, 
+dnl group them all together at the end of the run, to be user-friendly.
+AC_DEFUN([PSPP_REQUIRED_PREREQ], [pspp_required_prereqs="$pspp_required_prereqs
+	$1"])
+AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
+	$1"])
+AC_DEFUN([PSPP_CHECK_PREREQS], 
+[
+  if test "$pspp_optional_prereqs" != ""; then
+    AC_MSG_WARN([The following optional prerequisites are not installed.
+You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
+fi
+  if test "$pspp_required_prereqs" != ""; then
+    AC_MSG_ERROR([The following required prerequisites are not installed.
+You must install them before PSPP can be built:$pspp_required_prereqs])
+fi
+])
+    
+
+dnl Check that a new enough version of Perl is available.
+AC_DEFUN([PSPP_PERL],
+[
+  AC_PATH_PROG([PERL], perl, no)
+  AC_SUBST([PERL])dnl
+  if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
+    PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
+  fi
+])
+
+dnl Check that libplot is available.
+AC_DEFUN([PSPP_LIBPLOT],
+[
+  AC_ARG_WITH(libplot, [  --without-libplot         don't compile in support of charts (using libplot)])
+
+  if test x"$with_libplot" != x"no" ; then 
+    AC_CHECK_LIB(plot, pl_newpl_r,,
+	         [PSPP_REQUIRED_PREREQ([libplot (or use --without-libplot)])])
+  fi
+])
+
+dnl Check that off_t is defined as an integer type.
+dnl Solaris sometimes declares it as a struct, if it
+dnl thinks that the compiler does not support `long long'.
+AC_DEFUN([PSPP_OFF_T],
+[
+  AC_COMPILE_IFELSE([#include <sys/types.h>
+  #include <unistd.h>
+  off_t x = 0;
+  int main (void) 
+  { 
+    lseek (0, 1, 2);
+    return 0;
+  }], [], [AC_MSG_ERROR(
+  [Your system's definition of off_t is broken.  You are probably
+  using Solaris.  You can probably fix the problem with
+  `--disable-largefile' or `CFLAGS=-ansi'.])])
+])
+
+dnl Check whether a warning flag is accepted.
+dnl If so, add it to CFLAGS.
+dnl Example: PSPP_ENABLE_WARNING(-Wdeclaration-after-statement)
+AC_DEFUN([PSPP_ENABLE_WARNING],
+[
+  m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
+  AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name], 
+    [pspp_save_CFLAGS="$CFLAGS"
+     CFLAGS="$CFLAGS $1"
+     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
+     CFLAGS="$pspp_save_CFLAGS"])
+  if test $pspp_cv_name = yes; then
+    CFLAGS="$CFLAGS $1"
+  fi
+])
+
 dnl Check for readline and history libraries.
 
 dnl Modified for PSPP by Ben Pfaff, based on readline.m4 serial 3 from
@@ -58,9 +134,6 @@ AC_DEFUN([PSPP_READLINE],
 
   if test "$gl_cv_lib_readline" = yes; then
     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
-  fi
-
-  if test "$gl_cv_lib_readline" = yes; then
     AC_MSG_CHECKING([how to link with libreadline])
     AC_MSG_RESULT([$LIBREADLINE])
   else
@@ -71,6 +144,7 @@ AC_DEFUN([PSPP_READLINE],
     LTLIBREADLINE=
     LIBHISTORY=
     LTLIBHISTORY=
+    PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
   fi
   AC_SUBST(LIBREADLINE)
   AC_SUBST(LTLIBREADLINE)