+AC_SEARCH_LIBS([sin], [m])
+PSPP_LC_PAPER
+
+
+AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
+AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
+
+# Support for Cairo and Pango.
+AC_ARG_WITH([cairo],
+ [AS_HELP_STRING(
+ [--without-cairo],
+ [Don't build support for charts (using Cairo and Pango);
+ implies --without-gui])],
+ [], [with_cairo=yes])
+AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
+if test "$with_cairo" != no; then
+ PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
+ [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
+ AC_DEFINE([HAVE_CAIRO], 1,
+ [Define to 1 if Cairo and Pango are available.])],
+ [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
+fi
+
+dnl Xmllint is used in the rules to build the documentation. It is not actually necessary,
+dnl but is used for post-build consistency checks. Thus, non-developers can live without it.
+dnl However for it to be usefull, it needs to be a certain version and have certain features.
+dnl The macros below check that it the xmllint available is up to scratch. If it isn't
+dnl then a dummy /bin/echo is subsituted instead.
+
+AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
+[AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
+ [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
+ test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
+ ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
+ [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
+
+AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
+
+# Support for GUI.
+AC_ARG_WITH([gui],
+ [AS_HELP_STRING([--without-gui],
+ [Don't build the PSPPIRE GUI (using GTK+)])],
+ [], [with_gui=yes])
+AM_CONDITIONAL([HAVE_GUI],
+ [test "$with_cairo" != no && test "$with_gui" != "no"])
+if test "$with_cairo" != no && test "$with_gui" != "no"; then
+ PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
+ [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.2], [],
+ [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.4.2 or later (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
+ [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
+
+ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
+ [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
+
+ AC_ARG_VAR([GLIB_GENMARSHAL])
+ AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
+ if test "x$GLIB_GENMARSHAL" = x; then
+ PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
+ fi
+
+fi
+
+gl_NEXT_HEADERS([gtk/gtk.h])
+
+dnl Checks needed for psql reader
+
+dnl The 8.x series postgres tarballs installs with a default prefix of
+dnl /usr/local/pgsql whereas, OSes (such as debian) install into /usr .
+
+dnl If the libpq.so file is in a non standard path, (one which the linker
+dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
+dnl However, if the system happens to have more than one version of other
+dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
+dnl /usr and /usr/local) then the wrong one may get linked.
+
+dnl To overcome this, we first check for libpq in the standard places, and
+dnl only set PG_LDFLAGS if it's not found.
+
+
+AC_ARG_WITH(
+ libpq,
+ [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
+AC_ARG_VAR([PG_CONFIG],
+ [Full pathname of the pg_config program shipped with Postgresql])
+AC_PATH_PROG([PG_CONFIG], [pg_config], [],
+ [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
+
+if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
+ AC_SUBST(PG_CONFIG)
+ PG_CFLAGS=-I`$PG_CONFIG --includedir`
+ AC_SUBST(PG_CFLAGS)
+
+ AC_CHECK_LIB([pq], [PQexec],
+ [:],
+ [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
+ AC_SUBST(PG_LDFLAGS)