System and Portable File I/O
****************************

The commands in this chapter read, write, and examine system files and portable files.

APPLY DICTIONARY
================

     APPLY DICTIONARY FROM={'file-name',file_handle}.

APPLY DICTIONARY applies the variable labels, value labels, and missing values taken from a file to corresponding variables in the active dataset.  In some cases it also updates the weighting variable.

Specify a system file, portable file, or scratch file with a file name string or as a file handle (see File Handles).  The dictionary in the file will be read, but it will not replace the active dataset dictionary. The file's data will not be read.

Only variables with names that exist in both the active dataset and the system file are considered.  Variables with the same name but different types (numeric, string) will cause an error message.  Otherwise, the system file variables' attributes will replace those in their matching active dataset variables:

  * If a system file variable has a variable label, then it will replace the variable label of the active dataset variable.  If the system file variable does not have a variable label, then the active dataset variable's variable label, if any, will be retained.

  * If the system file variable has custom attributes (see VARIABLE ATTRIBUTE), then those attributes replace the active dataset variable's custom attributes.  If the system file variable does not have custom attributes, then the active dataset variable's custom attributes, if any, will be retained.

  * If the active dataset variable is numeric or short string, then value labels and missing values, if any, will be copied to the active dataset variable.  If the system file variable does not have value labels or missing values, then those in the active dataset variable, if any, will not be disturbed.

In addition to properties of variables, some properties of the active file dictionary as a whole are updated:

  * If the system file has custom attributes (see DATAFILE ATTRIBUTE), then those attributes replace the active dataset variable's custom attributes.

  * If the active dataset has a weighting variable (see WEIGHT), and the system file does not, or if the weighting variable in the system file does not exist in the active dataset, then the active dataset weighting variable, if any, is retained.  Otherwise, the weighting variable in the system file becomes the active dataset weighting variable.

APPLY DICTIONARY takes effect immediately.  It does not read the active dataset.  The system file is not modified.

EXPORT
======

     EXPORT
             /OUTFILE='file-name'
             /UNSELECTED={RETAIN,DELETE}
             /DIGITS=n
             /DROP=var_list
             /KEEP=var_list
             /RENAME=(src_names=target_names)...
             /TYPE={COMM,TAPE}
             /MAP

The EXPORT procedure writes the active dataset's dictionary and data to a specified portable file or scratch file.

By default, cases excluded with FILTER are written to the file.  These can be excluded by specifying DELETE on the UNSELECTED subcommand.  Specifying RETAIN makes the default explicit.

Portable files express real numbers in base 30.  Integers are always expressed to the maximum precision needed to make them exact. Non-integers are, by default, expressed to the machine's maximum natural precision (approximately 15 decimal digits on many machines). If many numbers require this many digits, the portable file may significantly increase in size.  As an alternative, the DIGITS subcommand may be used to specify the number of decimal digits of precision to write.  DIGITS applies only to non-integers.

The OUTFILE subcommand, which is the only required subcommand, specifies the portable file or scratch file to be written as a file name string or a file handle (see File Handles).

DROP, KEEP, and RENAME follow the same format as the SAVE procedure (see SAVE).

The TYPE subcommand specifies the character set for use in the portable file.  Its value is currently not used.

The MAP subcommand is currently ignored.

EXPORT is a procedure.  It causes the active dataset to be read.

GET
===

     GET
             /FILE={'file-name',file_handle}
             /DROP=var_list
             /KEEP=var_list
             /RENAME=(src_names=target_names)...

GET clears the current dictionary and active dataset and replaces them with the dictionary and data from a specified file.

The FILE subcommand is the only required subcommand.  Specify the system file, portable file, or scratch file to be read as a string file name or a file handle (see File Handles).

By default, all the variables in a file are read.  The DROP subcommand can be used to specify a list of variables that are not to be read.  By contrast, the KEEP subcommand can be used to specify variable that are to be read, with all other variables not read.

Normally variables in a file retain the names that they were saved under.  Use the RENAME subcommand to change these names.  Specify, within parentheses, a list of variable names followed by an equals sign (=) and the names that they should be renamed to.  Multiple parenthesized groups of variable names can be included on a single RENAME subcommand.  Variables' names may be swapped using a RENAME subcommand of the form /RENAME=(A B=B A).

Alternate syntax for the RENAME subcommand allows the parentheses to be eliminated.  When this is done, only a single variable may be renamed at once.  For instance, /RENAME=A=B.  This alternate syntax is deprecated.

DROP, KEEP, and RENAME are executed in left-to-right order. Each may be present any number of times.  GET never modifies a file on disk.  Only the active dataset read from the file is affected by these subcommands.

GET does not cause the data to be read, only the dictionary.  The data is read later, when a procedure is executed.

Use of GET to read a portable file or scratch file is a PSPP extension.

GET DATA
========

     GET DATA
             /TYPE={GNM,PSQL,TXT}
             ...additional subcommands depending on TYPE...

The GET DATA command is used to read files and other data sources created by other applications.  When this command is executed, the current dictionary and active dataset are replaced with variables and data read from the specified source.

The TYPE subcommand is mandatory and must be the first subcommand specified.  It determines the type of the file or source to read. PSPP currently supports the following file types:

GNM
     Spreadsheet files created by Gnumeric (http://gnumeric.org).

PSQL
     Relations from PostgreSQL databases (http://postgresql.org).

TXT
     Textual data files in columnar and delimited formats.

Each supported file type has additional subcommands, explained in separate sections below.

Gnumeric Spreadsheet Files
--------------------------

     GET DATA /TYPE=GNM
             /FILE={'file-name'}
             /SHEET={NAME 'sheet-name', INDEX n}
             /CELLRANGE={RANGE 'range', FULL}
             /READNAMES={ON, OFF}
             /ASSUMEDVARWIDTH=n.

To use GET DATA to read a spreadsheet file created by Gnumeric (http://gnumeric.org), specify TYPE=GNM to indicate the file's format and use FILE to indicate the Gnumeric file to be read.  All other subcommands are optional.

The format of each variable is determined by the format of the spreadsheet cell containing the first datum for the variable. If this cell is of string (text) format, then the width of the variable is determined from the length of the string it contains, unless the ASSUMEDVARWIDTH subcommand is given.

The FILE subcommand is mandatory. Specify the name of the file to be read.

The SHEET subcommand specifies the sheet within the spreadsheet file to read. There are two forms of the SHEET subcommand. In the first form, /SHEET=name SHEET-NAME, the string SHEET-NAME is the name of the sheet to read. In the second form, /SHEET=index IDX, IDX is a integer which is the index of the sheet to read. The first sheet has the index 1. If the SHEET subcommand is omitted, then the command will read the first sheet in the file.

The CELLRANGE subcommand specifies the range of cells within the sheet to read. If the subcommand is given as /CELLRANGE=FULL, then the entire sheet  is read. To read only part of a sheet, use the form /CELLRANGE=range 'TOP-LEFT-CELL:BOTTOM-RIGHT-CELL'. For example, the subcommand /CELLRANGE=range 'C3:P19' reads columns C--P, and rows 3--19 inclusive. If no CELLRANGE subcommand is given, then the entire sheet is read.

If /READNAMES=ON is specified, then the contents of cells of the first row are used as the names of the variables in which to store the data from subsequent rows. If the READNAMES command is omitted, or if /READNAMES=OFF is used, then the variables  receive automatically assigned names.

The ASSUMEDVARWIDTH subcommand specifies the maximum width of string variables read  from the file. If omitted, the default value is determined from the length of the string in the first spreadsheet cell for each variable.

Postgres Database Queries
-------------------------

     GET DATA /TYPE=PSQL
              /CONNECT={connection info}
              /SQL={query}
              [/ASSUMEDVARWIDTH=n]
              [/UNENCRYPTED]
              [/BSIZE=n].

The PSQL type is used to import data from a postgres database server. The server may be located locally or remotely. Variables are automatically created based on the table column names or the names specified in the SQL query. Postgres data types of high precision, will loose precision when imported into PSPP. Not all the postgres data types are able to be represented in PSPP. If a datum cannot be represented a warning will be issued and that datum will be set to SYSMIS.

The CONNECT subcommand is mandatory. It is a string specifying the parameters of the database server from which the data should be fetched. The format of the string is given in the postgres manual http://www.postgresql.org/docs/8.0/static/libpq.html#LIBPQ-CONNECT.

The SQL subcommand is mandatory. It must be a valid SQL string to retrieve data from the database.

The ASSUMEDVARWIDTH subcommand specifies the maximum width of string variables read  from the database. If omitted, the default value is determined from the length of the string in the first value read for each variable.

The UNENCRYPTED subcommand allows data to be retrieved over an insecure connection. If the connection is not encrypted, and the UNENCRYPTED subcommand is not given, then an error will occur. Whether or not the connection is encrypted depends upon the underlying psql library and the capabilities of the database server.

The BSIZE subcommand serves only to optimise the speed of data transfer. It specifies an upper limit on number of cases to fetch from the database at once. The default value is 4096. If your SQL statement fetches a large number of cases but only a small number of variables, then the data transfer may be faster if you increase this value. Conversely, if the number of variables is large, or if the machine on which PSPP is running has only a small amount of memory, then a smaller value will be better.

The following syntax is an example:

     GET DATA /TYPE=PSQL
          /CONNECT='host=example.com port=5432 dbname=product user=fred passwd=xxxx'
          /SQL='select * from manufacturer'.

Textual Data Files
------------------

     GET DATA /TYPE=TXT
             /FILE={'file-name',file_handle}
             [/ARRANGEMENT={DELIMITED,FIXED}]
             [/FIRSTCASE={first_case}]
             [/IMPORTCASE={ALL,FIRST max_cases,PERCENT percent}]
             ...additional subcommands depending on ARRANGEMENT...

When TYPE=TXT is specified, GET DATA reads data in a delimited or fixed columnar format, much like DATA LIST (see DATA LIST).

The FILE subcommand is mandatory.  Specify the file to be read as a string file name or (for textual data only) a file handle (see File Handles).

The ARRANGEMENT subcommand determines the file's basic format. DELIMITED, the default setting, specifies that fields in the input data are separated by spaces, tabs, or other user-specified delimiters.  FIXED specifies that fields in the input data appear at particular fixed column positions within records of a case.

By default, cases are read from the input file starting from the first line.  To skip lines at the beginning of an input file, set FIRSTCASE to the number of the first line to read: 2 to skip the first line, 3 to skip the first two lines, and so on.

IMPORTCASE can be used to limit the number of cases read from the input file.  With the default setting, ALL, all cases in the file are read.  Specify FIRST max_cases to read at most max_cases cases from the file.  Use PERCENT percent to read only percent percent, approximately, of the cases contained in the file.  (The percentage is approximate, because there is no way to accurately count the number of cases in the file without reading the entire file.  The number of cases in some kinds of unusual files cannot be estimated; PSPP will read all cases in such files.)

FIRSTCASE and IMPORTCASE may be used with delimited and fixed-format data.  The remaining subcommands, which apply only to one of the two  file arrangements, are described below.

Reading Delimited Data
......................

     GET DATA /TYPE=TXT
             /FILE={'file-name',file_handle}
             [/ARRANGEMENT={DELIMITED,FIXED}]
             [/FIRSTCASE={first_case}]
             [/IMPORTCASE={ALL,FIRST max_cases,PERCENT percent}]

             /DELIMITERS="delimiters"
             [/QUALIFIER="quotes" [/ESCAPE]]
             [/DELCASE={LINE,VARIABLES n_variables}]
             /VARIABLES=del_var [del_var]...
     where each del_var takes the form:
             variable format

The GET DATA command with TYPE=TXT and ARRANGEMENT=DELIMITED reads input data from text files in delimited format, where fields are separated by a set of user-specified delimiters.  Its capabilities are similar to those of DATA LIST FREE (see DATA LIST FREE), with a few enhancements.

The required FILE subcommand and optional FIRSTCASE and IMPORTCASE subcommands are described above (see GET DATA /TYPE=TXT).

DELIMITERS, which is required, specifies the set of characters that may separate fields.  Each character in the string specified on DELIMITERS separates one field from the next.  The end of a line also separates fields, regardless of DELIMITERS.  Two consecutive delimiters in the input yield an empty field, as does a delimiter at the end of a line.  A space character as a delimiter is an exception: consecutive spaces do not yield an empty field and neither does any number of spaces at the end of a line.

To use a tab as a delimiter, specify \t at the beginning of the DELIMITERS string.  To use a backslash as a delimiter, specify \\ as the first delimiter or, if a tab should also be a delimiter, immediately following \t.  To read a data file in which each field appears on a separate line, specify the empty string for DELIMITERS.

The optional QUALIFIER subcommand names one or more characters that can be used to quote values within fields in the input.  A field that begins with one of the specified quote characters ends at the next matching quote.  Intervening delimiters become part of the field, instead of terminating it.  The ability to specify more than one quote character is a PSPP extension.

By default, a character specified on QUALIFIER cannot itself be embedded within a field that it quotes, because the quote character always terminates the quoted field.  With ESCAPE, however, a doubled quote character within a quoted field inserts a single instance of the quote into the field.  For example, if ' is specified on QUALIFIER, then without ESCAPE 'a''b' specifies a pair of fields that contain a and b, but with ESCAPE it specifies a single field that contains a'b.  ESCAPE is a PSPP extension.

The DELCASE subcommand controls how data may be broken across lines in the data file.  With LINE, the default setting, each line must contain all the data for exactly one case.  For additional flexibility, to allow a single case to be split among lines or multiple cases to be contained on a single line, specify VARIABLES n_variables, where n_variables is the number of variables per case.

The VARIABLES subcommand is required and must be the last subcommand. Specify the name of each variable and its input format (see Input and Output Formats) in the order they should be read from the input file.

Examples
........

On a Unix-like system, the /etc/passwd file has a format similar to this:

     root:$1$nyeSP5gD$pDq/:0:0:,,,:/root:/bin/bash
     blp:$1$BrP/pFg4$g7OG:1000:1000:Ben Pfaff,,,:/home/blp:/bin/bash
     john:$1$JBuq/Fioq$g4A:1001:1001:John Darrington,,,:/home/john:/bin/bash
     jhs:$1$D3li4hPL$88X1:1002:1002:Jason Stover,,,:/home/jhs:/bin/csh

The following syntax reads a file in the format used by /etc/passwd:

     GET DATA /TYPE=TXT /FILE='/etc/passwd' /DELIMITERS=':'
             /VARIABLES=username A20
                        password A40
                        uid F10
                        gid F10
                        gecos A40
                        home A40
                        shell A40.

Consider the following data on used cars:

     model   year    mileage price   type    age
     Civic   2002    29883   15900   Si      2
     Civic   2003    13415   15900   EX      1
     Civic   1992    107000  3800    n/a     12
     Accord  2002    26613   17900   EX      1

The following syntax can be used to read the used car data:

     GET DATA /TYPE=TXT /FILE='cars.data' /DELIMITERS=' ' /FIRSTCASE=2
             /VARIABLES=model A8
                        year F4
                        mileage F6
                        price F5
                        type A4
                        age F2.

Consider the following information on animals in a pet store:

     'Pet''s Name', "Age", "Color", "Date Received", "Price", "Height", "Type"
     , (Years), , , (Dollars), ,
     "Rover", 4.5, Brown, "12 Feb 2004", 80, '1''4"', "Dog"
     "Charlie", , Gold, "5 Apr 2007", 12.3, "3""", "Fish"
     "Molly", 2, Black, "12 Dec 2006", 25, '5"', "Cat"
     "Gilly", , White, "10 Apr 2007", 10, "3""", "Guinea Pig"

The following syntax can be used to read the pet store data:

     GET DATA /TYPE=TXT /FILE='pets.data' /DELIMITERS=', ' /QUALIFIER='''"' /ESCAPE
             /FIRSTCASE=3
             /VARIABLES=name A10
                        age F3.1
                        color A5
                        received EDATE10
                        price F5.2
                        height a5
                        type a10.

Reading Fixed Columnar Data
...........................

     GET DATA /TYPE=TXT
             /FILE={'file-name',file_handle}
             [/ARRANGEMENT={DELIMITED,FIXED}]
             [/FIRSTCASE={first_case}]
             [/IMPORTCASE={ALL,FIRST max_cases,PERCENT percent}]

             [/FIXCASE=n]
             /VARIABLES fixed_var [fixed_var]...
                 [/rec# fixed_var [fixed_var]...]...
     where each fixed_var takes the form:
             variable start-end format

The GET DATA command with TYPE=TXT and ARRANGEMENT=FIXED reads input data from text files in fixed format, where each field is located in particular fixed column positions within records of a case.  Its capabilities are similar to those of DATA LIST FIXED (see DATA LIST FIXED), with a few enhancements.

The required FILE subcommand and optional FIRSTCASE and IMPORTCASE subcommands are described above (see GET DATA /TYPE=TXT).

The optional FIXCASE subcommand may be used to specify the positive integer number of input lines that make up each case.  The default value is 1.

The VARIABLES subcommand, which is required, specifies the positions at which each variable can be found.  For each variable, specify its name, followed by its start and end column separated by - (e.g. 0-9), followed by the input format type (e.g. F).  For this command, columns are numbered starting from 0 at the left column.  Introduce the variables in the second and later lines of a case by a slash followed by the number of the line within the case, e.g. /2 for the second line.

Examples
........

Consider the following data on used cars:

     model   year    mileage price   type    age
     Civic   2002    29883   15900   Si      2
     Civic   2003    13415   15900   EX      1
     Civic   1992    107000  3800    n/a     12
     Accord  2002    26613   17900   EX      1

The following syntax can be used to read the used car data:

     GET DATA /TYPE=TXT /FILE='cars.data' /ARRANGEMENT=FIXED /FIRSTCASE=2
             /VARIABLES=model 0-7 A
                        year 8-15 F
                        mileage 16-23 F
                        price 24-31 F
                        type 32-40 A
                        age 40-47 F.

IMPORT
======

     IMPORT
             /FILE='file-name'
             /TYPE={COMM,TAPE}
             /DROP=var_list
             /KEEP=var_list
             /RENAME=(src_names=target_names)...

The IMPORT transformation clears the active dataset dictionary and data and replaces them with a dictionary and data from a system, portable file, or scratch file.

The FILE subcommand, which is the only required subcommand, specifies the portable file to be read as a file name string or a file handle (see File Handles).

The TYPE subcommand is currently not used.

DROP, KEEP, and RENAME follow the syntax used by GET (see GET).

IMPORT does not cause the data to be read, only the dictionary.  The data is read later, when a procedure is executed.

Use of IMPORT to read a system file or scratch file is a PSPP extension.

SAVE
====

     SAVE
             /OUTFILE={'file-name',file_handle}
             /UNSELECTED={RETAIN,DELETE}
             /{COMPRESSED,UNCOMPRESSED}
             /PERMISSIONS={WRITEABLE,READONLY}
             /DROP=var_list
             /KEEP=var_list
             /VERSION=version
             /RENAME=(src_names=target_names)...
             /NAMES
             /MAP

The SAVE procedure causes the dictionary and data in the active dataset to be written to a system file or scratch file.

OUTFILE is the only required subcommand.  Specify the system file or scratch file to be written as a string file name or a file handle (see File Handles).

By default, cases excluded with FILTER are written to the system file. These can be excluded by specifying DELETE on the UNSELECTED subcommand.  Specifying RETAIN makes the default explicit.

The COMPRESS and UNCOMPRESS subcommand determine whether the saved system file is compressed.  By default, system files are compressed. This default can be changed with the SET command (see SET).

The PERMISSIONS subcommand specifies permissions for the new system file.  WRITEABLE, the default, creates the file with read and write permission.  READONLY creates the file for read-only access.

By default, all the variables in the active dataset dictionary are written to the system file.  The DROP subcommand can be used to specify a list of variables not to be written.  In contrast, KEEP specifies variables to be written, with all variables not specified not written.

Normally variables are saved to a system file under the same names they have in the active dataset.  Use the RENAME subcommand to change these names. Specify, within parentheses, a list of variable names followed by an equals sign (=) and the names that they should be renamed to. Multiple parenthesized groups of variable names can be included on a single RENAME subcommand.  Variables' names may be swapped using a RENAME subcommand of the form /RENAME=(A B=B A).

Alternate syntax for the RENAME subcommand allows the parentheses to be eliminated.  When this is done, only a single variable may be renamed at once.  For instance, /RENAME=A=B.  This alternate syntax is deprecated.

DROP, KEEP, and RENAME are performed in left-to-right order.  They each may be present any number of times.  SAVE never modifies the active dataset.  DROP, KEEP, and RENAME only affect the system file written to disk.

The VERSION subcommand specifies the version of the file format. Valid versions are 2 and 3.  The default version is 3.  In version 2 system files, variable names longer than 8 bytes will be truncated.  The two versions are otherwise identical.

The NAMES and MAP subcommands are currently ignored.

SAVE causes the data to be read.  It is a procedure.

SAVE TRANSLATE
==============

     SAVE TRANSLATE
             /OUTFILE={'file-name',file_handle}
             /TYPE={CSV,TAB}
             [/REPLACE]
             [/MISSING={IGNORE,RECODE}]

             [/DROP=var_list]
             [/KEEP=var_list]
             [/RENAME=(src_names=target_names)...]
             [/UNSELECTED={RETAIN,DELETE}]
             [/MAP]

             ...additional subcommands depending on TYPE...

The SAVE TRANSLATE command is used to save data into various formats understood by other applications.

The OUTFILE and TYPE subcommands are mandatory.  OUTFILE specifies the file to be written, as a string file name or a file handle (see File Handles).  TYPE determines the type of the file or source to read.  It must be one of the following:

CSV
     Comma-separated value format,

TAB
     Tab-delimited format.

By default, SAVE TRANSLATE will not overwrite an existing file.  Use REPLACE to force an existing file to be overwritten.

With MISSING=IGNORE, the default, SAVE TRANSLATE treats user-missing values as if they were not missing.  Specify MISSING=RECODE to output numeric user-missing values like system-missing values and string user-missing values as all spaces.

By default, all the variables in the active dataset dictionary are saved to the system file, but DROP or KEEP can select a subset of variable to save.  The RENAME subcommand can also be used to change the names under which variables are saved.  UNSELECTED determines whether cases filtered out by the FILTER command are written to the output file. These subcommands have the same syntax and meaning as on the SAVE command (see SAVE).

Each supported file type has additional subcommands, explained in separate sections below.

SAVE TRANSLATE causes the data to be read.  It is a procedure.

Writing Comma- and Tab-Separated Data Files
-------------------------------------------

     SAVE TRANSLATE
             /OUTFILE={'file-name',file_handle}
             /TYPE=CSV
             [/REPLACE]
             [/MISSING={IGNORE,RECODE}]

             [/DROP=var_list]
             [/KEEP=var_list]
             [/RENAME=(src_names=target_names)...]
             [/UNSELECTED={RETAIN,DELETE}]

             [/FIELDNAMES]
             [/CELLS={VALUES,LABELS}]
             [/TEXTOPTIONS DELIMITER='delimiter']
             [/TEXTOPTIONS QUALIFIER='qualifier']
             [/TEXTOPTIONS DECIMAL={DOT,COMMA}]
             [/TEXTOPTIONS FORMAT={PLAIN,VARIABLE}]

The SAVE TRANSLATE command with TYPE=CSV or TYPE=TAB writes data in a comma- or tab-separated value format similar to that described by RFC 4180.  Each variable becomes one output column, and each case becomes one line of output.  If FIELDNAMES is specified, an additional line at the top of the output file lists variable names.

The CELLS and TEXTOPTIONS FORMAT settings determine how values are written to the output file:

CELLS=VALUES FORMAT=PLAIN (the default settings)
     Writes variables to the output in ``plain'' formats that ignore the details of variable formats.  Numeric values are written as plain decimal numbers with enough digits to indicate their exact values in machine representation.  Numeric values include e followed by an exponent if the exponent value would be less than -4 or greater than 16.  Dates are written in MM/DD/YYYY format and times in HH:MM:SS format.  WKDAY and MONTH values are written as decimal numbers.

     Numeric values use, by default, the decimal point character set with SET DECIMAL (see SET DECIMAL).  Use DECIMAL=DOT or DECIMAL=COMMA to force a particular decimal point character.

CELLS=VALUES FORMAT=VARIABLE
     Writes variables using their print formats.  Leading and trailing spaces are removed from numeric values, and trailing spaces are removed from string values.

CELLS=LABEL FORMAT=PLAIN
CELLS=LABEL FORMAT=VARIABLE
     Writes value labels where they exist, and otherwise writes the values themselves as described above.

Regardless of CELLS and TEXTOPTIONS FORMAT, numeric system-missing values are output as a single space.

For TYPE=TAB, tab characters delimit values.  For TYPE=CSV, the TEXTOPTIONS DELIMITER and DECIMAL settings determine the character that separate values within a line.  If DELIMITER is specified, then the specified string separate values.  If DELIMITER is not specified, then the default is a comma with DECIMAL=DOT or a semicolon with DECIMAL=COMMA.  If DECIMAL is not given either, it is implied by the decimal point character set with SET DECIMAL (see SET DECIMAL).

The TEXTOPTIONS QUALIFIER setting specifies a character that is output before and after a value that contains the delimiter character or the qualifier character.  The default is a double quote (@).  A qualifier character that appears within a value is doubled.

SYSFILE INFO
============

     SYSFILE INFO FILE='file-name'.

SYSFILE INFO reads the dictionary in a system file and displays the information in its dictionary.

Specify a file name or file handle.  SYSFILE INFO reads that file as a system file and displays information on its dictionary.

SYSFILE INFO does not affect the current active dataset.

XEXPORT
=======

     XEXPORT
             /OUTFILE='file-name'
             /DIGITS=n
             /DROP=var_list
             /KEEP=var_list
             /RENAME=(src_names=target_names)...
             /TYPE={COMM,TAPE}
             /MAP

The EXPORT transformation writes the active dataset dictionary and data to a specified portable file.

This transformation is a PSPP extension.

It is similar to the EXPORT procedure, with two differences:

  * XEXPORT is a transformation, not a procedure.  It is executed when the data is read by a procedure or procedure-like command.

  * XEXPORT does not support the UNSELECTED subcommand.

See EXPORT, for more information.

XSAVE
=====

     XSAVE
             /OUTFILE='file-name'
             /{COMPRESSED,UNCOMPRESSED}
             /PERMISSIONS={WRITEABLE,READONLY}
             /DROP=var_list
             /KEEP=var_list
             /VERSION=version
             /RENAME=(src_names=target_names)...
             /NAMES
             /MAP

The XSAVE transformation writes the active dataset's dictionary and data to a system file or scratch file.  It is similar to the SAVE procedure, with two differences:

  * XSAVE is a transformation, not a procedure.  It is executed when the data is read by a procedure or procedure-like command.

  * XSAVE does not support the UNSELECTED subcommand.

See SAVE, for more information.