pintos-os.org Git - openvswitch/blob - tests/flowgen.pl

   1 #! /usr/bin/perl
   2
   3 # Copyright (c) 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 use strict;
  18 use warnings;
  19
  20 open(FLOWS, ">&=3");# or die "failed to open fd 3 for writing: $!\n";
  21 open(PACKETS, ">&=4");# or die "failed to open fd 4 for writing: $!\n";
  22
  23 # Print pcap file header.
  24 print PACKETS pack('NnnNNNN',
  25                    0xa1b2c3d4,  # magic number
  26                    2,           # major version
  27                    4,           # minor version
  28                    0,           # time zone offset
  29                    0,           # time stamp accuracy
  30                    1518,        # snaplen
  31                    1);          # Ethernet
  32
  33 output(DL_HEADER => '802.2');
  34
  35 for my $dl_header (qw(802.2+SNAP Ethernet)) {
  36     my %a = (DL_HEADER => $dl_header);
  37     for my $dl_vlan (qw(none zero nonzero)) {
  38         my %b = (%a, DL_VLAN => $dl_vlan);
  39
  40         # Non-IP case.
  41         output(%b, DL_TYPE => 'non-ip');
  42
  43         for my $ip_options (qw(no yes)) {
  44             my %c = (%b, DL_TYPE => 'ip', IP_OPTIONS => $ip_options);
  45             for my $ip_fragment (qw(no first middle last)) {
  46                 my %d = (%c, IP_FRAGMENT => $ip_fragment);
  47                 for my $tp_proto (qw(TCP TCP+options UDP ICMP other)) {
  48                     output(%d, TP_PROTO => $tp_proto);
  49                 }
  50             }
  51         }
  52     }
  53 }
  54
  55 sub output {
  56     my (%attrs) = @_;
  57
  58     # Compose flow.
  59     my (%flow);
  60     $flow{DL_SRC} = "00:02:e3:0f:80:a4";
  61     $flow{DL_DST} = "00:1a:92:40:ac:05";
  62     $flow{NW_PROTO} = 0;
  63     $flow{NW_TOS} = 0;
  64     $flow{NW_SRC} = '0.0.0.0';
  65     $flow{NW_DST} = '0.0.0.0';
  66     $flow{TP_SRC} = 0;
  67     $flow{TP_DST} = 0;
  68     if (defined($attrs{DL_VLAN})) {
  69         my (%vlan_map) = ('none' => 0xffff,
  70                           'zero' => 0,
  71                           'nonzero' => 0x0123);
  72         $flow{DL_VLAN} = $vlan_map{$attrs{DL_VLAN}};
  73     } else {
  74         $flow{DL_VLAN} = 0xffff; # OFP_VLAN_NONE
  75     }
  76     if ($attrs{DL_HEADER} eq '802.2') {
  77         $flow{DL_TYPE} = 0x5ff; # OFP_DL_TYPE_NOT_ETH_TYPE
  78     } elsif ($attrs{DL_TYPE} eq 'ip') {
  79         $flow{DL_TYPE} = 0x0800; # ETH_TYPE_IP
  80         $flow{NW_SRC} = '10.0.2.15';
  81         $flow{NW_DST} = '192.168.1.20';
  82         $flow{NW_TOS} = 44;
  83         if ($attrs{TP_PROTO} eq 'other') {
  84             $flow{NW_PROTO} = 42;
  85         } elsif ($attrs{TP_PROTO} eq 'TCP' ||
  86                  $attrs{TP_PROTO} eq 'TCP+options') {
  87             $flow{NW_PROTO} = 6; # IPPROTO_TCP
  88             $flow{TP_SRC} = 6667;
  89             $flow{TP_DST} = 9998;
  90         } elsif ($attrs{TP_PROTO} eq 'UDP') {
  91             $flow{NW_PROTO} = 17; # IPPROTO_UDP
  92             $flow{TP_SRC} = 1112;
  93             $flow{TP_DST} = 2223;
  94         } elsif ($attrs{TP_PROTO} eq 'ICMP') {
  95             $flow{NW_PROTO} = 1; # IPPROTO_ICMP
  96             $flow{TP_SRC} = 8;   # echo request
  97             $flow{TP_DST} = 0;   # code
  98         } else {
  99             die;
 100         }
 101         if ($attrs{IP_FRAGMENT} ne 'no') {
 102             $flow{TP_SRC} = $flow{TP_DST} = 0;
 103         }
 104     } elsif ($attrs{DL_TYPE} eq 'non-ip') {
 105         $flow{DL_TYPE} = 0x5678;
 106     } else {
 107         die;
 108     }
 109
 110     # Compose packet.
 111     my $packet = '';
 112     $packet .= pack_ethaddr($flow{DL_DST});
 113     $packet .= pack_ethaddr($flow{DL_SRC});
 114     if ($flow{DL_VLAN} != 0xffff) {
 115         $packet .= pack('nn', 0x8100, $flow{DL_VLAN});
 116     }
 117     my $len_ofs = length($packet);
 118     $packet .= pack('n', 0) if $attrs{DL_HEADER} =~ /^802.2/;
 119     if ($attrs{DL_HEADER} eq '802.2') {
 120         $packet .= pack('CCC', 0x42, 0x42, 0x03); # LLC for 802.1D STP.
 121     } else {
 122         if ($attrs{DL_HEADER} eq '802.2+SNAP') {
 123             $packet .= pack('CCC', 0xaa, 0xaa, 0x03); # LLC for SNAP.
 124             $packet .= pack('CCC', 0, 0, 0);          # SNAP OUI.
 125         }
 126         $packet .= pack('n', $flow{DL_TYPE});
 127         if ($attrs{DL_TYPE} eq 'ip') {
 128             my $ip = pack('CCnnnCCnNN',
 129                           (4 << 4) | 5,    # version, hdrlen
 130                           $flow{NW_TOS},   # type of service
 131                           0,               # total length (filled in later)
 132                           65432,           # id
 133                           0,               # frag offset
 134                           64,              # ttl
 135                           $flow{NW_PROTO}, # protocol
 136                           0,               # checksum
 137                           0x0a00020f,      # source
 138                           0xc0a80114);     # dest
 139             if ($attrs{IP_OPTIONS} eq 'yes') {
 140                 substr($ip, 0, 1) = pack('C', (4 << 4) | 8);
 141                 $ip .= pack('CCnnnCCCx',
 142                             130,       # type
 143                             11,        # length
 144                             0x6bc5,    # top secret
 145                             0xabcd,
 146                             0x1234,
 147                             1,
 148                             2,
 149                             3);
 150             }
 151             if ($attrs{IP_FRAGMENT} ne 'no') {
 152                 my (%frag_map) = ('first' => 0x2000, # more frags, ofs 0
 153                                   'middle' => 0x2111, # more frags, ofs 0x888
 154                                   'last' => 0x0222); # last frag, ofs 0x1110
 155                 substr($ip, 6, 2)
 156                   = pack('n', $frag_map{$attrs{IP_FRAGMENT}});
 157             }
 158
 159             if ($attrs{TP_PROTO} =~ '^TCP') {
 160                 my $tcp = pack('nnNNnnnn',
 161                                $flow{TP_SRC},           # source port
 162                                $flow{TP_DST},           # dest port
 163                                87123455,                # seqno
 164                                712378912,               # ackno
 165                                (5 << 12) | 0x02 | 0x10, # hdrlen, SYN, ACK
 166                                5823,                    # window size
 167                                18923,                   # checksum
 168                                12893);                  # urgent pointer
 169                 if ($attrs{TP_PROTO} eq 'TCP+options') {
 170                     substr($tcp, 12, 2) = pack('n', (6 << 12) | 0x02 | 0x10);
 171                     $tcp .= pack('CCn', 2, 4, 1975); # MSS option
 172                 }
 173                 $tcp .= 'payload';
 174                 $ip .= $tcp;
 175             } elsif ($attrs{TP_PROTO} eq 'UDP') {
 176                 my $len = 15;
 177                 my $udp = pack('nnnn', $flow{TP_SRC}, $flow{TP_DST}, $len, 0);
 178                 $udp .= chr($len) while length($udp) < $len;
 179                 $ip .= $udp;
 180             } elsif ($attrs{TP_PROTO} eq 'ICMP') {
 181                 $ip .= pack('CCnnn',
 182                             8,    # echo request
 183                             0,    # code
 184                             0,    # checksum
 185                             736,  # identifier
 186                             931); # sequence number
 187             } elsif ($attrs{TP_PROTO} eq 'other') {
 188                 $ip .= 'other header';
 189             } else {
 190                 die;
 191             }
 192
 193             substr($ip, 2, 2) = pack('n', length($ip));
 194             $packet .= $ip;
 195         }
 196     }
 197     if ($attrs{DL_HEADER} =~ /^802.2/) {
 198         my $len = length ($packet);
 199         $len -= 4 if $flow{DL_VLAN} != 0xffff;
 200         substr($packet, $len_ofs, 2) = pack('n', $len);
 201     }
 202
 203     print join(' ', map("$_=$attrs{$_}", keys(%attrs))), "\n";
 204     print join(' ', map("$_=$flow{$_}", keys(%flow))), "\n";
 205     print "\n";
 206
 207     print FLOWS pack('Nn',
 208                      0,         # wildcards
 209                      1);        # in_port
 210     print FLOWS pack_ethaddr($flow{DL_SRC});
 211     print FLOWS pack_ethaddr($flow{DL_DST});
 212     print FLOWS pack('nCxnCCxxNNnn',
 213                      $flow{DL_VLAN},
 214                      0,          # DL_VLAN_PCP
 215                      $flow{DL_TYPE},
 216                      $flow{NW_TOS},
 217                      $flow{NW_PROTO},
 218                      inet_aton($flow{NW_SRC}),
 219                      inet_aton($flow{NW_DST}),
 220                      $flow{TP_SRC},
 221                      $flow{TP_DST});
 222
 223     print PACKETS pack('NNNN',
 224                        0,                # timestamp seconds
 225                        0,                # timestamp microseconds
 226                        length($packet),  # bytes saved
 227                        length($packet)), # total length
 228                   $packet;
 229 }
 230
 231 sub pack_ethaddr {
 232     local ($_) = @_;
 233     my $xx = '([0-9a-fA-F][0-9a-fA-F])';
 234     my (@octets) = /$xx:$xx:$xx:$xx:$xx:$xx/;
 235     @octets == 6 or die $_;
 236     my ($out) = '';
 237     $out .= pack('C', hex($_)) foreach @octets;
 238     return $out;
 239 }
 240
 241 sub inet_aton {
 242     local ($_) = @_;
 243     my ($a, $b, $c, $d) = /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/;
 244     defined $d or die $_;
 245     return ($a << 24) | ($b << 16) | ($c << 8) | $d;
 246 }