pintos-os.org Git - openvswitch/blob - m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (lcov) coverage=true lcov=true ;;
  26         (yes) coverage=true lcov=false ;;
  27         (no)  coverage=false lcov=false ;;
  28         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  29       esac],
  30      [coverage=false lcov=false])
  31    if $coverage; then
  32      CFLAGS="$CFLAGS -O0 --coverage"
  33      LDFLAGS="$LDFLAGS --coverage"
  34    fi
  35    if $lcov; then
  36      if lcov --version >/dev/null 2>&1; then :; else
  37        AC_MSG_ERROR([--enable-coverage=lcov was specified but lcov is not in \$PATH])
  38      fi
  39    fi
  40    AC_SUBST([LCOV], [$lcov])])
  41
  42 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  43 AC_DEFUN([OVS_CHECK_NDEBUG],
  44   [AC_ARG_ENABLE(
  45      [ndebug],
  46      [AC_HELP_STRING([--enable-ndebug],
  47                      [Disable debugging features for max performance])],
  48      [case "${enableval}" in
  49         (yes) ndebug=true ;;
  50         (no)  ndebug=false ;;
  51         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  52       esac],
  53      [ndebug=false])
  54    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  55
  56 dnl Checks for Netlink support.
  57 AC_DEFUN([OVS_CHECK_NETLINK],
  58   [AC_CHECK_HEADER([linux/netlink.h],
  59                    [HAVE_NETLINK=yes],
  60                    [HAVE_NETLINK=no],
  61                    [#include <sys/socket.h>
  62    #include <linux/types.h>
  63    ])
  64    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  65    if test "$HAVE_NETLINK" = yes; then
  66       AC_DEFINE([HAVE_NETLINK], [1],
  67                 [Define to 1 if Netlink protocol is available.])
  68    fi])
  69
  70 dnl Checks for OpenSSL, if --enable-ssl is passed in.
  71 AC_DEFUN([OVS_CHECK_OPENSSL],
  72   [AC_ARG_ENABLE(
  73      [ssl],
  74      [AC_HELP_STRING([--enable-ssl],
  75                      [Enable ssl support (requires libssl)])],
  76      [case "${enableval}" in
  77         (yes) ssl=true ;;
  78         (no)  ssl=false ;;
  79         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  80       esac],
  81      [ssl=false])
  82
  83    if test "$ssl" = true; then
  84    dnl Make sure that pkg-config is installed.
  85    m4_pattern_forbid([PKG_CHECK_MODULES])
  86    PKG_CHECK_MODULES([SSL], [libssl],
  87      [HAVE_OPENSSL=yes],
  88      [HAVE_OPENSSL=no
  89       AC_MSG_WARN([Cannot find libssl:
  90
  91    $SSL_PKG_ERRORS
  92
  93    OpenFlow connections over SSL will not be supported.])])
  94
  95    fi
  96    AC_SUBST([HAVE_OPENSSL])
  97    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
  98    if test "$HAVE_OPENSSL" = yes; then
  99       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
 100    fi])
 101
 102 dnl Checks for libraries needed by lib/socket-util.c.
 103 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 104   [AC_CHECK_LIB([socket], [connect])
 105    AC_SEARCH_LIBS([gethostbyname], [resolv], [RESOLVER_LIBS=-lresolv])])
 106
 107 dnl Checks for the directory in which to store the PKI.
 108 AC_DEFUN([OVS_CHECK_PKIDIR],
 109   [AC_ARG_WITH(
 110      [pkidir],
 111      AC_HELP_STRING([--with-pkidir=DIR],
 112                     [PKI hierarchy directory [[DATADIR/openvswitch/pki]]]),
 113      [PKIDIR=$withval],
 114      [PKIDIR='${pkgdatadir}/pki'])
 115    AC_SUBST([PKIDIR])])
 116
 117 dnl Checks for the directory in which to store pidfiles.
 118 AC_DEFUN([OVS_CHECK_RUNDIR],
 119   [AC_ARG_WITH(
 120      [rundir],
 121      AC_HELP_STRING([--with-rundir=DIR],
 122                     [directory used for pidfiles [[LOCALSTATEDIR/run]]]),
 123      [RUNDIR=$withval],
 124      [RUNDIR='${localstatedir}/run'])
 125    AC_SUBST([RUNDIR])])
 126
 127 dnl Checks for the directory in which to store logs.
 128 AC_DEFUN([OVS_CHECK_LOGDIR],
 129   [AC_ARG_WITH(
 130      [logdir],
 131      AC_HELP_STRING([--with-logdir=DIR],
 132                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 133      [LOGDIR=$withval],
 134      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 135    AC_SUBST([LOGDIR])])
 136
 137 dnl Checks for __malloc_hook, etc., supported by glibc.
 138 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 139   [AC_CACHE_CHECK(
 140     [whether libc supports hooks for malloc and related functions],
 141     [ovs_cv_malloc_hooks],
 142     [AC_COMPILE_IFELSE(
 143       [AC_LANG_PROGRAM(
 144          [#include <malloc.h>
 145          ],
 146          [(void) __malloc_hook;
 147           (void) __realloc_hook;
 148           (void) __free_hook;])],
 149       [ovs_cv_malloc_hooks=yes],
 150       [ovs_cv_malloc_hooks=no])])
 151    if test $ovs_cv_malloc_hooks = yes; then
 152      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 153                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 154                 __free_hook in <malloc.h>.])
 155    fi])
 156
 157 dnl Checks for valgrind/valgrind.h.
 158 AC_DEFUN([OVS_CHECK_VALGRIND],
 159   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 160
 161 dnl Searches for a directory to put lockfiles for tty devices.
 162 dnl Defines C preprocessor variable TTY_LOCK_DIR to a quoted string
 163 dnl for that directory.
 164 AC_DEFUN([OVS_CHECK_TTY_LOCK_DIR],
 165   [AC_CACHE_CHECK([directory used for serial device lockfiles],
 166                   [ovs_cv_path_tty_locks],
 167                   [# This list of candidate directories is from minicom.
 168                    ovs_cv_path_tty_locks=none
 169                    for dir in /etc/locks /var/lock /usr/spool/locks \
 170                               /var/spool/locks /var/spool/lock \
 171                               /usr/spool/uucp /var/spool/uucp /var/run; do
 172                      if test -d $dir; then
 173                        ovs_cv_path_tty_locks=$dir
 174                        break
 175                      fi
 176                    done])
 177    if test "$ovs_cv_path_tty_locks" = none; then
 178      AC_MSG_ERROR([cannot find a directory for tty locks])
 179    fi
 180    AC_DEFINE_UNQUOTED([TTY_LOCK_DIR], "$ovs_cv_path_tty_locks",
 181                       [Directory used for serial device lockfiles])])
 182
 183 dnl The following check is adapted from GNU PSPP.
 184 dnl It searches for the ncurses library.  If it finds it, it sets
 185 dnl HAVE_CURSES to yes and sets NCURSES_LIBS and NCURSES_CFLAGS
 186 dnl appropriate.  Otherwise, it sets HAVE_CURSES to no.
 187 AC_DEFUN([OVS_CHECK_CURSES],
 188   [if test "$cross_compiling" != yes; then
 189      AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 190    fi
 191    if test "$NCURSES_CONFIG" = ""; then
 192      AC_SEARCH_LIBS([tgetent], [ncurses],
 193          [AC_CHECK_HEADERS([term.h curses.h],
 194                            [HAVE_CURSES=yes],
 195                            [HAVE_CURSES=no])])
 196    else
 197      save_cflags=$CFLAGS
 198      CFLAGS="$CFLAGS $($NCURSES_CONFIG --cflags)"
 199      AC_CHECK_HEADERS([term.h curses.h],
 200                       [HAVE_CURSES=yes],
 201                       [HAVE_CURSES=no])
 202      CFLAGS=$save_cflags
 203      if test "$HAVE_CURSES" = yes; then
 204        NCURSES_LIBS=$($NCURSES_CONFIG --libs)
 205        NCURSES_CFLAGS=$($NCURSES_CONFIG --cflags)
 206        AC_SUBST(NCURSES_CFLAGS)
 207        AC_SUBST(NCURSES_LIBS)
 208      fi
 209    fi
 210    AM_CONDITIONAL([HAVE_CURSES], [test "$HAVE_CURSES" = yes])])
 211
 212 dnl Checks for linux/vt.h.
 213 AC_DEFUN([OVS_CHECK_LINUX_VT_H],
 214   [AC_CHECK_HEADER([linux/vt.h],
 215                    [HAVE_LINUX_VT_H=yes],
 216                    [HAVE_LINUX_VT_H=no])
 217    AM_CONDITIONAL([HAVE_LINUX_VT_H], [test "$HAVE_LINUX_VT_H" = yes])
 218    if test "$HAVE_LINUX_VT_H" = yes; then
 219       AC_DEFINE([HAVE_LINUX_VT_H], [1],
 220                 [Define to 1 if linux/vt.h is available.])
 221    fi])
 222
 223 dnl Checks for libpcre.
 224 AC_DEFUN([OVS_CHECK_PCRE],
 225   [dnl Make sure that pkg-config is installed.
 226    m4_pattern_forbid([PKG_CHECK_MODULES])
 227    PKG_CHECK_MODULES([PCRE], [libpcre >= 7.2], [HAVE_PCRE=yes], [HAVE_PCRE=no])
 228    AM_CONDITIONAL([HAVE_PCRE], [test "$HAVE_PCRE" = yes])
 229    if test "$HAVE_PCRE" = yes; then
 230       AC_DEFINE([HAVE_PCRE], [1], [Define to 1 if libpcre is installed.])
 231    fi])
 232
 233 dnl Checks for Python 2.x, x >= 4.
 234 AC_DEFUN([OVS_CHECK_PYTHON],
 235   [AC_CACHE_CHECK(
 236      [for Python 2.x for x >= 4],
 237      [ovs_cv_python],
 238      [if test -n "$PYTHON"; then
 239         ovs_cv_python=$PYTHON
 240       else
 241         ovs_cv_python=no
 242         for binary in python python2.4 python2.5; do
 243           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 244           for dir in $PATH; do
 245             IFS=$ovs_save_IFS
 246             test -z "$dir" && dir=.
 247             if test -x $dir/$binary && $dir/$binary -c 'import sys
 248 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 249     sys.exit(0)
 250 else:
 251     sys.exit(1)'; then
 252               ovs_cv_python=$dir/$binary
 253               break 2
 254             fi
 255           done
 256         done
 257       fi])
 258    AM_MISSING_PROG([PYTHON], [python])
 259    if test $ovs_cv_python != no; then
 260      PYTHON=$ovs_cv_python
 261    fi])