pintos-os.org Git - pspp/blob - m4/asinl.m4

   1 # asinl.m4 serial 3
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ASINL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare asinl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   ASINL_LIBM=
  14   AC_CACHE_CHECK([whether asinl() can be used without linking with libm],
  15     [gl_cv_func_asinl_no_libm],
  16     [
  17       AC_LINK_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#ifndef __NO_MATH_INLINES
  20              # define __NO_MATH_INLINES 1 /* for glibc */
  21              #endif
  22              #include <math.h>
  23              long double x;]],
  24            [[return asinl (x) > 1;]])],
  25         [gl_cv_func_asinl_no_libm=yes],
  26         [gl_cv_func_asinl_no_libm=no])
  27     ])
  28   if test $gl_cv_func_asinl_no_libm = no; then
  29     AC_CACHE_CHECK([whether asinl() can be used with libm],
  30       [gl_cv_func_asinl_in_libm],
  31       [
  32         save_LIBS="$LIBS"
  33         LIBS="$LIBS -lm"
  34         AC_LINK_IFELSE(
  35           [AC_LANG_PROGRAM(
  36              [[#ifndef __NO_MATH_INLINES
  37                # define __NO_MATH_INLINES 1 /* for glibc */
  38                #endif
  39                #include <math.h>
  40                long double x;]],
  41              [[return asinl (x) > 1;]])],
  42           [gl_cv_func_asinl_in_libm=yes],
  43           [gl_cv_func_asinl_in_libm=no])
  44         LIBS="$save_LIBS"
  45       ])
  46     if test $gl_cv_func_asinl_in_libm = yes; then
  47       ASINL_LIBM=-lm
  48     fi
  49   fi
  50   if test $gl_cv_func_asinl_no_libm = yes \
  51      || test $gl_cv_func_asinl_in_libm = yes; then
  52     dnl Also check whether it's declared.
  53     dnl MacOS X 10.3 has asinl() in libc but doesn't declare it in <math.h>.
  54     AC_CHECK_DECL([asinl], , [HAVE_DECL_ASINL=0], [#include <math.h>])
  55   else
  56     HAVE_DECL_ASINL=0
  57     HAVE_ASINL=0
  58     AC_LIBOBJ([asinl])
  59     AC_REQUIRE([gl_FUNC_SQRTL])
  60     dnl Append $SQRTL_LIBM to ASINL_LIBM, avoiding gratuitous duplicates.
  61     case " $ASINL_LIBM " in
  62       *" $SQRTL_LIBM "*) ;;
  63       *) ASINL_LIBM="$ASINL_LIBM $SQRTL_LIBM" ;;
  64     esac
  65   fi
  66   AC_SUBST([ASINL_LIBM])
  67 ])