pintos-os.org Git - openvswitch/blob - acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_CHECK_LINUX26
  18 dnl
  19 dnl Configure linux kernel source tree
  20 AC_DEFUN([OVS_CHECK_LINUX26], [
  21   AC_ARG_WITH([l26],
  22               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  23                               [Specify the linux 2.6 kernel build directory])],
  24               [KBUILD26="$withval"], [KBUILD26=])dnl
  25   AC_ARG_WITH([l26-source],
  26               [AC_HELP_STRING([--with-l26-source=/path/to/linux-2.6-source],
  27                               [Specify the linux 2.6 kernel source directory
  28                                (usually figured out automatically from build
  29                                directory)])],
  30               [KSRC26="$withval"], [KSRC26=])dnl
  31   if test -n "$KBUILD26"; then
  32     KBUILD26=`eval echo "$KBUILD26"`
  33     case $KBUILD26 in
  34         /*) ;;
  35         *) KBUILD26=`pwd`/$KBUILD26 ;;
  36     esac
  37
  38     # The build directory is what the user provided.
  39     # Make sure that it exists.
  40     AC_MSG_CHECKING([for Linux 2.6 build directory])
  41     if test -d "$KBUILD26"; then
  42         AC_MSG_RESULT([$KBUILD26])
  43         AC_SUBST(KBUILD26)
  44     else
  45         AC_MSG_RESULT([no])
  46         AC_ERROR([source dir $KBUILD26 doesn't exist])
  47     fi
  48
  49     # Debian breaks kernel headers into "source" header and "build" headers.
  50     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  51     # Use heuristics to find the source headers.
  52     AC_MSG_CHECKING([for Linux 2.6 source directory])
  53     if test -n "$KSRC26"; then
  54       KSRC26=`eval echo "$KSRC26"`
  55       case $KSRC26 in
  56           /*) ;;
  57           *) KSRC26=`pwd`/$KSRC26 ;;
  58       esac
  59       if test ! -e $KSRC26/include/linux/kernel.h; then
  60         AC_MSG_ERROR([$KSRC26 is not a kernel source directory)])
  61       fi
  62     else
  63       KSRC26=$KBUILD26
  64       if test ! -e $KSRC26/include/linux/kernel.h; then
  65         case `echo "$KBUILD26" | sed 's,/*$,,'` in # (
  66           */build)
  67             KSRC26=`echo "$KBUILD26" | sed 's,/build/*$,/source,'`
  68             ;; # (
  69           *)
  70             KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  71             ;;
  72         esac
  73       fi
  74       if test ! -e $KSRC26/include/linux/kernel.h; then
  75         AC_MSG_ERROR([cannot find source directory (please use --with-l26-source)])
  76       fi
  77     fi
  78     AC_MSG_RESULT([$KSRC26])
  79
  80     AC_MSG_CHECKING([for kernel version])
  81     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  82     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  83     if test -z "$patchlevel" || test -z "$sublevel"; then
  84        AC_ERROR([cannot determine kernel version])
  85     fi
  86     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  87     if test "2.$patchlevel" != '2.6'; then
  88        if test "$BUILD26" = "$KSRC26"; then
  89          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
  90        else
  91          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
  92        fi
  93     fi
  94     if test ! -e "$KBUILD26"/include/linux/version.h || \
  95        (test ! -e "$KBUILD26"/include/linux/autoconf.h && \
  96         test ! -e "$KBUILD26"/include/generated/autoconf.h); then
  97         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
  98     fi
  99     OVS_CHECK_LINUX26_COMPAT
 100   elif test -n "$KSRC26"; then
 101     AC_MSG_ERROR([--with-l26-source may not be specified without --with-l26])
 102   fi
 103   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
 104 ])
 105
 106 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 107 dnl
 108 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 109 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 110 dnl <REGEX> translated to uppercase.
 111 AC_DEFUN([OVS_GREP_IFELSE], [
 112   AC_MSG_CHECKING([whether $2 matches in $1])
 113   if test -f $1; then
 114     grep '$2' $1 >/dev/null 2>&1
 115     status=$?
 116     case $status in
 117       0)
 118         AC_MSG_RESULT([yes])
 119         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 120         ;;
 121       1)
 122         AC_MSG_RESULT([no])
 123         $4
 124         ;;
 125       *)
 126         AC_MSG_ERROR([grep exited with status $status])
 127         ;;
 128     esac
 129   else
 130     AC_MSG_RESULT([file not found])
 131     $4
 132   fi
 133 ])
 134
 135 dnl OVS_DEFINE(NAME)
 136 dnl
 137 dnl Defines NAME to 1 in kcompat.h.
 138 AC_DEFUN([OVS_DEFINE], [
 139   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 140 ])
 141
 142 AC_DEFUN([OVS_CHECK_LOG2_H], [
 143   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 144   if test -e $KSRC26/include/linux/log2.h; then
 145     AC_MSG_RESULT([yes])
 146     OVS_DEFINE([HAVE_LOG2_H])
 147   else
 148     AC_MSG_RESULT([no])
 149   fi
 150 ])
 151
 152 dnl OVS_CHECK_LINUX26_COMPAT
 153 dnl
 154 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 155 dnl the directory in $KBUILD26.
 156 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 157   rm -f datapath/linux-2.6/kcompat.h.new
 158   mkdir -p datapath/linux-2.6
 159   : > datapath/linux-2.6/kcompat.h.new
 160
 161   OVS_GREP_IFELSE([$KSRC26/arch/x86/include/asm/checksum_32.h], [src_err,],
 162                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 163
 164   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST])
 165
 166   OVS_GREP_IFELSE([$KSRC26/include/linux/in.h], [ipv4_is_multicast])
 167
 168   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_disable_lro])
 169   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_get_stats])
 170
 171   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 172   # is necessary because some versions of this header remove the
 173   # member but retain the kerneldoc comment that describes it (which
 174   # starts with @).  The brackets must be doubled because of m4
 175   # quoting rules.
 176   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 177                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 178   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 179                   [OVS_DEFINE([HAVE_MAC_RAW])])
 180   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_dst(],
 181                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 182   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 183                   [skb_copy_from_linear_data_offset])
 184   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow_head])
 185   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 186                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 187   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_warn_if_lro],
 188                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 189
 190   OVS_GREP_IFELSE([$KSRC26/include/linux/string.h], [kmemdup], [],
 191                   [OVS_GREP_IFELSE([$KSRC26/include/linux/slab.h], [kmemdup])])
 192
 193   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [bool],
 194                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 195   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [__wsum],
 196                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 197
 198   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold])
 199
 200   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING])
 201   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_get_be16])
 202
 203   OVS_CHECK_LOG2_H
 204
 205   if cmp -s datapath/linux-2.6/kcompat.h.new \
 206             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 207     rm datapath/linux-2.6/kcompat.h.new
 208   else
 209     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 210   fi
 211 ])
 212
 213 dnl Checks for net/if_packet.h.
 214 AC_DEFUN([OVS_CHECK_IF_PACKET],
 215   [AC_CHECK_HEADER([net/if_packet.h],
 216                    [HAVE_IF_PACKET=yes],
 217                    [HAVE_IF_PACKET=no])
 218    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 219    if test "$HAVE_IF_PACKET" = yes; then
 220       AC_DEFINE([HAVE_IF_PACKET], [1],
 221                 [Define to 1 if net/if_packet.h is available.])
 222    fi])
 223
 224 dnl Checks for buggy strtok_r.
 225 dnl
 226 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 227 dnl with optimization that can cause segfaults:
 228 dnl
 229 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 230 AC_DEFUN([OVS_CHECK_STRTOK_R],
 231   [AC_CACHE_CHECK(
 232      [whether strtok_r macro segfaults on some inputs],
 233      [ovs_cv_strtok_r_bug],
 234      [AC_RUN_IFELSE(
 235         [AC_LANG_PROGRAM([#include <stdio.h>
 236                           #include <string.h>
 237                          ],
 238                          [[char string[] = ":::";
 239                            char *save_ptr = (char *) 0xc0ffee;
 240                            char *token1, *token2;
 241                            token1 = strtok_r(string, ":", &save_ptr);
 242                            token2 = strtok_r(NULL, ":", &save_ptr);
 243                            freopen ("/dev/null", "w", stdout);
 244                            printf ("%s %s\n", token1, token2);
 245                            return 0;
 246                           ]])],
 247         [ovs_cv_strtok_r_bug=no],
 248         [ovs_cv_strtok_r_bug=yes],
 249         [ovs_cv_strtok_r_bug=yes])])
 250    if test $ovs_cv_strtok_r_bug = yes; then
 251      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 252                [Define if strtok_r macro segfaults on some inputs])
 253    fi
 254 ])
 255
 256 dnl ----------------------------------------------------------------------
 257 dnl These macros are from GNU PSPP, with the following original license:
 258 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 259 dnl This file is free software; the Free Software Foundation
 260 dnl gives unlimited permission to copy and/or distribute it,
 261 dnl with or without modifications, as long as this notice is preserved.
 262
 263 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 264 dnl Check whether the given C compiler OPTION is accepted.
 265 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 266 AC_DEFUN([OVS_CHECK_CC_OPTION],
 267 [
 268   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 269   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 270     [ovs_save_CFLAGS="$CFLAGS"
 271      CFLAGS="$CFLAGS $1"
 272      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 273      CFLAGS="$ovs_save_CFLAGS"])
 274   if test $ovs_cv_name = yes; then
 275     m4_if([$2], [], [:], [$2])
 276   else
 277     m4_if([$3], [], [:], [$3])
 278   fi
 279 ])
 280
 281 dnl OVS_ENABLE_OPTION([OPTION])
 282 dnl Check whether the given C compiler OPTION is accepted.
 283 dnl If so, add it to WARNING_FLAGS.
 284 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 285 AC_DEFUN([OVS_ENABLE_OPTION],
 286   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 287    AC_SUBST([WARNING_FLAGS])])
 288
 289 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 290 dnl Check whether the given C compiler OPTION is accepted.
 291 dnl If so, enable the given Automake CONDITIONAL.
 292
 293 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 294 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 295   [OVS_CHECK_CC_OPTION(
 296     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 297    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 298 dnl ----------------------------------------------------------------------