configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.5], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Internationalization macros.
  36 AC_PROVIDE([AM_PO_SUBDIRS])     # PSPP provides its own po/ support.
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 AM_GNU_GETTEXT_VERSION([0.17])
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  77     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  78
  79   AC_ARG_VAR([GLIB_GENMARSHAL])
  80   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  81   if test "x$GLIB_GENMARSHAL" = x; then
  82     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  83   fi
  84 fi
  85
  86 dnl Checks needed for psql reader
  87
  88 dnl The 8.x series postgres tarballs installs with a default prefix of
  89 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  90
  91 dnl If the libpq.so file is in a non standard path, (one which the linker
  92 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  93 dnl However, if the system happens to have more than one version of other
  94 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  95 dnl /usr and /usr/local) then the wrong one may get linked.
  96
  97 dnl To overcome this, we first check for libpq in the standard places, and
  98 dnl only set PG_LDFLAGS if it's not found.
  99
 100
 101 AC_ARG_WITH(
 102   libpq,
 103   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 104 AC_ARG_VAR([PG_CONFIG],
 105            [Full pathname of the pg_config program shipped with Postgresql])
 106 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 107              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 108
 109 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 110   AC_SUBST(PG_CONFIG)
 111   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 112   AC_SUBST(PG_CFLAGS)
 113
 114   AC_CHECK_LIB([pq], [PQexec],
 115      [:],
 116      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 117   AC_SUBST(PG_LDFLAGS)
 118
 119   PG_LIBS=-lpq
 120   AC_SUBST(PG_LIBS)
 121
 122   PKG_CHECK_EXISTS(libssl,
 123         AC_DEFINE([USE_SSL],1,
 124                    [Define to 1 if the openssl library is present.])
 125            ,)
 126
 127   # Now verify that we can actually link against libpq.  If we are
 128   # cross-compiling and picked up a host libpq, or if libpq is just
 129   # badly installed, this will fail.
 130   AC_CACHE_CHECK(
 131     [whether -lpq links successfully],
 132     [pspp_cv_have_libpq],
 133     [save_CPPFLAGS=$CPPFLAGS
 134      save_LIBS=$LIBS
 135      save_LDFLAGS=$LDFLAGS
 136      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 137      LIBS="$PG_LIBS $LIBS"
 138      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 139      AC_LINK_IFELSE(
 140        [AC_LANG_PROGRAM(
 141          [#include <libpq-fe.h>
 142          ], [PQfinish (0);])],
 143        [pspp_cv_have_libpq=yes],
 144        [pspp_cv_have_libpq=no])
 145      CPPFLAGS=$save_CPPFLAGS
 146      LIBS=$save_LIBS
 147      LDFLAGS=$save_LDFLAGS])
 148
 149   if test $pspp_cv_have_libpq = yes; then
 150     AC_DEFINE([PSQL_SUPPORT], [1],
 151       [Define to 1 if building in support for reading from postgres
 152        databases.])
 153   else
 154     PG_CONFIG=
 155     PG_CFLAGS=
 156     PG_LDFLAGS=
 157     PG_LIBS=
 158   fi
 159 else
 160   pspp_cv_have_libpq=no
 161 fi
 162 AM_CONDITIONAL(PSQL_SUPPORT, test $pspp_cv_have_libpq = yes)
 163
 164 dnl Check for libxml2
 165 PKG_CHECK_MODULES(
 166   [LIBXML2], [libxml-2.0],
 167   [HAVE_LIBXML2=yes],
 168   [HAVE_LIBXML2=no
 169    PSPP_OPTIONAL_PREREQ([libxml2])])
 170
 171 dnl Check for zlib.
 172 AC_SEARCH_LIBS(
 173   [gzopen], [z],
 174   [HAVE_ZLIB=yes],
 175   [HAVE_ZLIB=no
 176    PSPP_OPTIONAL_PREREQ([zlib])])
 177 AC_CHECK_HEADERS(
 178   [zlib.h],
 179   [],
 180   [HAVE_ZLIB=no
 181    PSPP_OPTIONAL_PREREQ([zlib])])
 182
 183 dnl Avoid interference between zlib's crc32() function and gnulib's
 184 dnl crc32() function, which have different signatures.  PSPP calls
 185 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 186 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 187 dnl crc32(), then zlib will call gnulib's version instead of its own,
 188 dnl causing failures.  (This can happen even if zlib isn't detected
 189 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 190 dnl sometimes use zlib themselves.)
 191 AC_DEFINE(
 192   [crc32], [gl_crc32],
 193   [Avoid making zlib call gnulib's crc32() instead of its own.])
 194
 195 dnl Gnumeric support requires libxml2 and zlib.
 196 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 197   GNM_SUPPORT=yes
 198   AC_DEFINE(
 199     [GNM_SUPPORT], [1],
 200     [Define to 1 if building in support for reading Gnumeric files.])
 201 else
 202   GNM_SUPPORT=no
 203 fi
 204 AM_CONDITIONAL([GNM_SUPPORT], [test $GNM_SUPPORT = yes])
 205
 206 dnl ODT support requires libxml2.
 207 if test $HAVE_LIBXML2 = yes; then
 208   AC_DEFINE(
 209     [ODT_SUPPORT], [1],
 210     [Define to 1 if building in support for writing ODT files.])
 211 fi
 212 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 213
 214 AC_ARG_WITH(
 215   gui_tools,
 216   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 217 if test x"$with_gui_tools" = x"yes" ; then
 218         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 219 fi
 220 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 221
 222 AC_ARG_WITH(
 223   [perl-module],
 224   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 225   [case $with_perl_module in # (
 226      yes|no) ;; # (
 227      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 228    esac
 229    WITH_PERL_MODULE=$with_perl_module],
 230   [if test x"$cross_compiling" != x"yes"; then
 231      WITH_PERL_MODULE=yes
 232    else
 233      WITH_PERL_MODULE=no
 234    fi])
 235 AC_SUBST([WITH_PERL_MODULE])
 236 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 237
 238 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 239 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [], [PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])])
 240
 241 PSPP_GSL_NEEDS_FGNU89_INLINE
 242
 243 dnl Recent versions of GNU ncurses install the curses header files into
 244 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 245 dnl enables us to discover where they are. Earlier versions don't have
 246 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 247 dnl we'll trust it to find the right information.  Otherwise, we'll
 248 dnl try to discover it ourselves.
 249 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 250 dnl to ncurses8-config !!!
 251 AC_ARG_WITH(
 252   libncurses,
 253   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 254
 255 if test x"$with_libncurses" != x"no" ; then
 256   if test x"$cross_compiling" != x"yes" ; then
 257           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 258   fi
 259   if test x"$NCURSES_CONFIG" = x ; then
 260           AC_SEARCH_LIBS([tgetent], [ncurses],
 261               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 262   else
 263           old_cflags=$CFLAGS
 264           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 265           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 266           CFLAGS=$old_cflags
 267           if test x"$curses_available" = x"yes" ; then
 268            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 269            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 270            AC_SUBST(NCURSES_CFLAGS)
 271            AC_SUBST(NCURSES_LIBS)
 272           fi
 273   fi
 274   if test x"$curses_available" = x"yes" ; then
 275           AC_DEFINE([LIBNCURSES_USABLE], 1,
 276               [Define to 1 if the libncurses is both present and usable.])
 277   fi
 278   AC_CHECK_HEADERS([termcap.h])
 279 fi
 280
 281 PSPP_READLINE
 282
 283 dnl Checks for header files.
 284 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 285
 286 # For gnulib.
 287 gl_INIT
 288
 289 AC_C_INLINE
 290
 291 AC_CHECK_SIZEOF(double)
 292
 293 AC_C_BIGENDIAN
 294
 295 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 296
 297 AC_PROG_LN_S
 298
 299 AC_ARG_ENABLE(
 300   debug,
 301   [AS_HELP_STRING([--enable-debug],
 302                   [Turn on diagnostic features in the program])])
 303 if test x"$enable_debug" = x"yes"  ; then
 304   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 305 fi
 306
 307 # iconv is required
 308 if test "$am_cv_func_iconv" != "yes"; then
 309    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 310 fi
 311
 312 dnl Required by the gnulib 'relocatable-prog' module.
 313 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 314 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 315 RELOCATABLE_STRIP=:
 316
 317 PSPP_CHECK_PREREQS
 318
 319 AC_CONFIG_FILES(
 320   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 321
 322 AC_OUTPUT
 323 echo "PSPP configured successfully."
 324
 325 dnl configure.ac ends here